Rotation QML Type

Permet de faire pivoter un élément. En savoir plus…

• Liste de tous les membres, y compris les membres hérités

Propriétés

• angle : real
• axis
  • axis.x : real
  • axis.y : real
  • axis.z : real
• distanceToPlane : real (since 6.11)
• origin
  • origin.x : real
  • origin.y : real

Description détaillée

Le type Rotation permet de faire pivoter un élément « Item » à l'aide d'une transformation de type rotation.

Il permet d'effectuer une rotation (autour de l'axe z) par rapport à un point arbitraire, et offre également la possibilité de spécifier des rotations de type 3D pour les éléments. Cela permet de mieux contrôler la rotation des éléments que la propriété « rotation ».

L'exemple suivant fait pivoter un rectangle autour de son point intérieur (25, 25) :

Rectangle {
    width: 100; height: 100
    color: "blue"
    transform: Rotation { origin.x: 25; origin.y: 25; angle: 45}
}

Pour les rotations d’éléments de type 3D, vous devez spécifier l’axe de rotation en plus du point d’origine. L’exemple suivant montre diverses rotations de type 3D appliquées à un élément Image.

import QtQuick

Row {
    x: 10; y: 10
    spacing: 10

    Image { source: "images/qt-logo.png" }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 18 }
    }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 36 }
    }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 54 }
    }
    Image {
        source: "images/qt-logo.png"
        transform: Rotation { origin.x: 30; origin.y: 30; axis { x: 0; y: 1; z: 0 } angle: 72 }
    }
}

Voir également l’exemple de contrôle «Dial » et la démo «Qt Quick » – Horloges.

Documentation sur les propriétés

angle : real

L'angle de rotation, en degrés dans le sens des aiguilles d'une montre.

axis group

L'axe autour duquel effectuer la rotation. Pour une rotation simple (2D) autour d'un point, il n'est pas nécessaire de spécifier un axe, car l'axe par défaut est l'axe z (axis { x: 0; y: 0; z: 1 }).

Pour une rotation classique de type 3D, vous devrez généralement spécifier à la fois l'origine et l'axe.

distanceToPlane : real [since 6.11]

Cette propriété définit la distance entre le plan de vue (l'écran virtuel) et l'observateur dans le modèle de projection en perspective.

Une distance plus petite produit un effet de perspective plus marqué, donnant l’impression que l’objet s’éloigne ou s’avance de manière plus spectaculaire lors de la rotation. Une valeur plus grande donne un rendu plus plat, plus orthographique, avec une distorsion de perspective moins visible.

La valeur par défaut est « 1024.0 », ce qui offre une perspective modérée adaptée à la plupart des cas d'utilisation.

Lorsque cette propriété est définie sur ` 0`, aucune projection en perspective n’est appliquée. Dans ce cas, la rotation est effectuée directement dans l’espace 3D à l’aide de la transformation définie par ` QMatrix4x4::rotate()`.

Cette propriété n’affecte que les rotations autour des axes x et y. Les rotations autour de l’axe z (rotations 2D) ne sont pas influencées par cette propriété.

Cette propriété a été introduite dans Qt 6.11.

origin group

Le point d'origine de la rotation (c'est-à-dire le point qui reste fixe par rapport à l'élément parent tandis que le reste de l'élément pivote). Par défaut, l'origine est (0, 0).