QT_DEPLOY_QML_DIR

一部のターゲットプラットフォーム上でQMLプラグインをデプロイするための、プレフィックスを基準としたサブディレクトリ。

この変数は、QT_DEPLOY_SUPPORT で指定されたスクリプトによって定義されます。これは、インストール時のデプロイ処理、またはビルド後のルールの一部としてのみ使用すべきです。

注：これは 低レベルのデプロイ API 変数であり、qt_generate_deploy_app_script などの高レベルの API コマンドでは対応できない高度なユースケースでのみ使用してください。

この変数は Qt 6.3 で導入されました。

プロジェクトでは、QMLモジュールをデプロイする特定のディレクトリをハードコーディングしないように、デプロイスクリプト内でQT_DEPLOY_QML_DIR を使用する必要があります。

QT_DEPLOY_QML_DIR デフォルト値は `qml` です。QT_DEPLOY_QML_DIR の値を変更するには、QT_DEPLOY_SUPPORT がインクルードされる前に、プロジェクトのデプロイスクリプトで設定してください。

QT_DEPLOY_QML_DIR のパスは、QT_DEPLOY_PREFIXを基準とした相対パスです。

この変数は、macOS アプリバンドルへのデプロイ時には意味を持たないため、そのシナリオでは使用しないでください。 Apple の macOS アプリバンドルに関するガイドラインでは、すべてのプラグインをバンドルコンテンツのPlugIns サブディレクトリにデプロイすることが求められており、その他のバイナリファイル以外のファイルは、一般的にResources サブディレクトリの下に配置する必要があります。したがって、QML モジュールの各部分は、アプリバンドル内の異なる場所にデプロイする必要があります。

例

cmake_minimum_required(VERSION 3.16...3.22)
project(MyThings)

find_package(Qt6 REQUIRED COMPONENTS Quick)
qt_standard_project_setup()

qt_add_executable(MyApp main.cpp)
qt_add_qml_module(MyApp
    URI myapp
    QML_FILES main.qml
)

set(deploy_script "${CMAKE_CURRENT_BINARY_DIR}/deploy_MyApp.cmake")
file(GENERATE OUTPUT ${deploy_script} CONTENT "

set(QT_DEPLOY_QML_DIR \"myqmldir\")

include(\"${QT_DEPLOY_SUPPORT}\")

qt_deploy_qml_imports(
    TARGET MyApp
    PLUGINS_FOUND plugins_found
)
qt_deploy_runtime_dependencies(
    EXECUTABLE \"\${QT_DEPLOY_BIN_DIR}/$<TARGET_FILE_NAME:MyApp>\"
    ADDITIONAL_MODULES \${plugins_found}
)")

install(SCRIPT ${deploy_script})

関連項目： QT_DEPLOY_SUPPORT、QT_DEPLOY_PREFIX、QT_DEPLOY_BIN_DIR、QT_DEPLOY_LIBEXEC_DIR、QT_DEPLOY_LIB_DIR、QT_DEPLOY_PLUGINS_DIR、およびQT_DEPLOY_TRANSLATIONS_DIR も参照してください。

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.