CheckBox QML Type

オン／オフを切り替えられるチェックボタン。詳細...

• 継承されたメンバーを含む、すべてのメンバーの一覧

プロパティ

• checkState : enumeration
• nextCheckState : function (since QtQuick.Controls 2.4 (Qt 5.11))
• tristate : bool

詳細説明

CheckBoxは、オン（チェック済み）またはオフ（チェックなし）に切り替え可能なオプションボタンを表します。チェックボックスは通常、一連の選択肢の中から1つまたは複数の選択肢を選択するために使用されます。リストのように選択肢の数が多くなる場合は、代わりにCheckDelegate の使用を検討してください。

CheckBoxは、AbstractButton からAPIを継承しています。例えば、チェックボックスの状態はchecked プロパティで設定できます。

チェック済みおよび未チェックの状態に加えて、3 つ目の状態として「部分的にチェック済み」があります。この状態は、tristate プロパティを使用して有効にできます。この状態は、通常はチェックボックスに影響を与える他の状態が原因で、通常のチェック済み／未チェックの状態を判断できないことを示します。たとえば、ツリービューで複数の子ノードが選択されている場合などに、この状態が役立ちます。

ColumnLayout {
    CheckBox {
        checked: true
        text: qsTr("First")
    }
    CheckBox {
        text: qsTr("Second")
    }
    CheckBox {
        checked: true
        text: qsTr("Third")
    }
}

階層的なチェックボックスグループは、排他性のない `ButtonGroup` を使用して管理できます。

次の例は、子ノードのチェック状態の合計を親チェックボックスのチェック状態に紐付ける方法を示しています。

Column {
    ButtonGroup {
        id: childGroup
        exclusive: false
        checkState: parentBox.checkState
    }

    CheckBox {
        id: parentBox
        text: qsTr("Parent")
        checkState: childGroup.checkState
    }

    CheckBox {
        checked: true
        text: qsTr("Child 1")
        leftPadding: indicator.width
        ButtonGroup.group: childGroup
    }

    CheckBox {
        text: qsTr("Child 2")
        leftPadding: indicator.width
        ButtonGroup.group: childGroup
    }
}

「CheckBox」、「ButtonGroup 」、および「Button」コントロールのカスタマイズも参照してください 。

プロパティのドキュメント

checkState : enumeration

このプロパティは、チェックボックスのチェック状態を保持します。

利用可能な状態：

「 tristate 」および「checked 」も参照してください 。

nextCheckState : function [since QtQuick.Controls 2.4 (Qt 5.11)]

このプロパティには、ユーザーがタッチ、マウス、またはキーボード操作でチェックボックスを直接切り替えた際に、次のチェック状態を決定するために呼び出されるコールバック関数が格納されます。

デフォルトでは、通常のチェックボックスは「Qt.Unchecked 」と「Qt.Checked 」の状態を循環し、3状態のチェックボックスは「Qt.Unchecked 」、「Qt.PartiallyChecked 」、および「Qt.Checked 」の状態を循環します。

nextCheckState コールバック関数を使用すると、デフォルトの挙動を上書きできます。以下の例では、外部条件に応じて「部分的にチェックされた」状態を表示できる 3 状態チェックボックスを実装していますが、ユーザーがインタラクティブにトグル操作を行っても、この「部分的にチェックされた」状態には決して移行しません。

CheckBox {
    tristate: true
    checkState: allChildrenChecked ? Qt.Checked :
                   anyChildChecked ? Qt.PartiallyChecked : Qt.Unchecked

    nextCheckState: function() {
        if (checkState === Qt.Checked)
            return Qt.Unchecked
        else
            return Qt.Checked
    }
}

このプロパティは、QtQuick.Controls 2.4 (Qt 5.11) で導入されました。

tristate : bool

このプロパティは、チェックボックスがトライステートチェックボックスであるかどうかを指定します。

以下のアニメーションでは、最初のチェックボックスが3状態のチェックボックスとなっています：

デフォルトはfalse であり、つまり、チェックボックスには2つの状態しかありません。