Qt Graphs Qt Quick 3Dとの統合

Qt Graphs for 3DはQt Quick 3Dに基づいているため、Qt Quick 3Dシーンをグラフに統合することができる。

シーン環境

グラフでQt Quick 3Dシーン環境を調整するには、グラフのenvironment プロパティでSceneEnvironment またはExtendedSceneEnvironment のいずれかを以下のように定義する：

environment: ExtendedSceneEnvironment {
    aoEnabled: true
    aoDither: true
    ditheringEnabled: true
    lightProbe: Texture {
        textureData: ProceduralSkyTextureData {
            groundBottomColor: "black"
            skyTopColor: "white"
        }
    }
    backgroundMode: SceneEnvironment.SkyBox
    lensFlareEnabled: true
    lensFlareGhostCount: 10
    lensFlareApplyStarburstTexture: true
    lensFlareBloomBias: 0.4
}

サポートされていない機能

アンチエイリアシング・モードやシーン・クリア・カラーの上書きは機能しません。つまり、SceneEnvironment.antialiasingMode とSceneEnvironment.clearColor に値を設定しても何もなりません。ただし、backgroundMode がSceneEnvironment.Color に設定されていない場合、背景は設定の影響を受けます。

シーンの統合

Qt Quick 3Dシーンをグラフに統合するには、グラフのimportScene プロパティを以下の設定でNode に設定します：

importScene: Node {
    Model {
        scale: Qt.vector3d(0.01, 0.01, 0.01)
        source: "#Sphere"
        x: 2.5
        z: 2
        y: 1
        castsReflections: false
        receivesReflections: true
        materials: [
            PrincipledMaterial {
                baseColor: "gold"
                metalness: 1.0
                roughness: 0.1
            }
        ]
        ReflectionProbe {
            boxSize: Qt.vector3d(6, 3, 5)
            boxOffset: Qt.vector3d(-1.5, -1, -1.5)
            parallaxCorrection: true
            quality: ReflectionProbe.High
        }
    }
    Model {
        scale: Qt.vector3d(0.01, 0.01, 0.01)
        source: "#Sphere"
        x: -2.5
        z: -2
        y: 1
        castsReflections: false
        receivesReflections: true
        materials: [
            PrincipledMaterial {
                baseColor: "white"
                metalness: 0.0
                roughness: 0.0
                transmissionFactor: 1.0
                thicknessFactor: 50
            }
        ]
    }
}

グラフのデフォルトの子は対応する系列であるため、Nodes をグラフの子として直接追加しても機能しない。

© 2025 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.