ToolTip QML Type

모든 컨트롤에 대한 툴팁을 제공합니다. 더 보기...

• 상속된 멤버를 포함한 모든 멤버 목록

속성

• delay : int
• text : string
• timeout : int

연관 속성

• delay : int
• policy : enumeration (since 6.12)
• text : string
• timeout : int
• toolTip : ToolTip
• visible : bool

방법

• void hide() (since QtQuick.Controls 2.5 (Qt 5.12))
• void show(string text, int timeout) (since QtQuick.Controls 2.5 (Qt 5.12))

첨부된 방법

• void hide()
• void show(string text, int timeout)

상세 설명

도구 설명은 사용자에게 컨트롤의 기능을 알려주는 짧은 텍스트입니다. 일반적으로 상위 컨트롤의 위나 아래에 배치됩니다. 도구 설명 텍스트는 서식이 지정된 리치 텍스트 문자열이면 무엇이든 사용할 수 있습니다.

연결된 툴팁

컨트롤에 툴팁을 설정하는 가장 간단한 방법은 attached 속성을 통해 ` text ` 및 ` visibility `을 지정하는 것입니다. 다음 예제는 이 방법을 보여줍니다:

Button {
    text: qsTr("Save")

    ToolTip.visible: down
    ToolTip.text: qsTr("Save the active project")
}

일반적으로 한 번에 하나의 툴팁만 표시됩니다. 리소스를 절약하기 위해, ToolTip 부착 속성을 사용하는 모든 항목은 동일한 시각적 툴팁 레이블 인스턴스를 공유합니다. 비주얼이 공유되더라도, text, timeout 및 delay 는 각 부착 속성을 사용하는 항목별로 개별적으로 저장됩니다. 그러나 여러 항목이 동시에 공유 툴팁을 표시할 수는 없습니다. 공유 툴팁은 이를 마지막으로 표시한 항목에 대해서만 나타납니다. 공유 툴팁의 위치는 프레임워크에 의해 결정됩니다.

지연 및 타임아웃

툴팁은 일반적으로 특정 외부 이벤트나 사용자 상호작용의 결과로 표시되며, 일정 시간이 지나면 숨겨지는 일시적인 요소입니다. 툴팁이 표시되는 지연 시간과 숨겨지는 타임아웃을 제어할 수 있습니다. 이를 통해 툴팁을 표시하고 숨기는 다양한 전략을 구현할 수 있습니다.

예를 들어, 터치 스크린에서는 버튼을 길게 누르면 툴팁이 표시되는 것이 일반적인 패턴입니다. 다음 예제는 길게 누르는 시간이 일정 시간 동안 지속될 때까지 툴팁 표시를 지연시키는 방법을 보여줍니다. 이 예제에서 툴팁은 버튼을 떼는 즉시 숨겨집니다.

Button {
    text: qsTr("Button")

    ToolTip.visible: pressed
    ToolTip.delay: Application.styleHints.mousePressAndHoldInterval
    ToolTip.text: qsTr("This tool tip is shown after pressing and holding the button down.")
}

반면, 포인터 장치를 사용할 때는 버튼 위에 마우스를 잠시 올려두면 툴팁이 표시되도록 하는 것이 바람직할 수 있습니다. 다음 예제는 버튼 위에 마우스를 1초 동안 올려둔 후 툴팁을 표시하고, 5초의 타임아웃이 지난 후 툴팁을 숨기는 방법을 보여줍니다.

Button {
    text: qsTr("Button")
    hoverEnabled: true

    ToolTip.delay: 1000
    ToolTip.timeout: 5000
    ToolTip.visible: hovered
    ToolTip.text: qsTr("This tool tip is shown after hovering the button for a second.")
}

사용자 정의 툴팁

툴팁 위치를 더 세밀하게 제어해야 하거나 여러 툴팁 인스턴스를 동시에 사용해야 하는 경우, 로컬 툴팁 인스턴스를 생성할 수도 있습니다. 이렇게 하면 툴팁을 사용자 정의할 수 있으며, ‘ Popup ’ API 전체를 사용할 수 있습니다. 다음 예제는 핸들을 드래그할 때 슬라이더의 값을 표시하는 툴팁을 보여줍니다.

Slider {
    id: slider
    value: 0.5

    ToolTip {
        parent: slider.handle
        visible: slider.pressed
        text: slider.value.toFixed(1)
    }
}

‘툴팁 사용자 지정’, ‘팝업 컨트롤’ 및 ‘ closePolicy ’항목도 참조하십시오 .

속성 설명서

delay : int

이 속성은 툴팁이 표시되기까지의 지연 시간(밀리초)을 지정합니다. 지연 시간이 음수인 툴팁은 즉시 표시됩니다. 기본값은 0 입니다.

Delay and Timeout도 참조하십시오 .

text : string

이 속성은 툴팁에 표시되는 텍스트를 저장합니다.

timeout : int

이 속성은 툴팁이 숨겨지기까지의 시간(밀리초)을 지정합니다. 타임아웃 값이 음수인 툴팁은 자동으로 숨겨지지 않습니다. 기본값은 -1 입니다.

Delay and Timeout도 참조하십시오 .

첨부된 속성 설명서

ToolTip.delay : int [attached]

이 첨부 속성은 공유 툴팁의 지연 시간(밀리초)을 저장합니다. 이 속성은 모든 항목에 첨부할 수 있습니다.

policy 가 ToolTip.Manual 인 경우 기본값은 0 이며, 그렇지 않은 경우 QStyleHints::toolTipWakeUpDelay()입니다.

Attached Tool Tips 및 Delay and Timeout도 참조하십시오 .

ToolTip.policy : enumeration [attached, since 6.12]

이 첨부 속성은 shared tool tip instance 의 표시 여부를 자동으로 처리할지 여부를 제어합니다. 이 속성은 ToolTip.visible 가 설정되지 않은 항목에 대해서만 적용됩니다. ToolTip.text 가 설정된 항목만 표시됩니다. 이 속성은 다음 항목 및 그 파생 유형( Control, TextArea, TextField)에 대해서만 적용됩니다. 그 외의 모든 유형에서는 visible 를 수동으로 설정해야 합니다.

또한 이 속성은 공유 툴팁 인스턴스의 delay 및 timeout 속성에 대한 기본값을 결정합니다( ToolTip.visible 이나 ToolTip.text 이 설정되었는지 여부와 무관하게).

이 속성은 연결된 ToolTip 자식 요소로 전달됩니다.

사용 가능한 값:

기본값은 ` ToolTip.Automatic`입니다.

이 속성은 Qt 6.12에서 도입된 공유 툴팁의 기본값을 해제할 수 있는 방법을 제공합니다. 이는 항목과 상호작용하기 전에 visible 속성을 명시적으로 설정하지 않는 레거시 코드에 특히 관련이 있습니다. visible 속성을 선언적으로 설정하고 delay 및 timeout의 새로운 기본값을 수용할 수 있는 애플리케이션의 경우, ` policy `는 필요하지 않습니다.

이 속성은 Qt 6.12에서 도입되었습니다.

Attached Tool Tips도 참조하십시오 .

ToolTip.text : string [attached]

이 첨부 속성에는 공유 툴팁의 텍스트가 저장됩니다. 이 속성은 어떤 항목에나 첨부할 수 있습니다.

Attached Tool Tips도 참조하십시오 .

ToolTip.timeout : int [attached]

이 첨부 속성은 공유 툴팁의 타임아웃(밀리초)을 저장합니다. 이 속성은 어떤 항목이든에 첨부할 수 있습니다.

기본값은 텍스트 길이에 따라 결정되며, 항상 최소 10초 이상으로 설정됩니다.

Attached Tool Tips 및 Delay and Timeout도 참조하십시오 .

ToolTip.toolTip : ToolTip [attached]

이 첨부된 속성은 공유 툴팁 인스턴스를 보관합니다. 이 속성은 어떤 항목이든 첨부할 수 있습니다.

Attached Tool Tips도 참조하십시오 .

ToolTip.visible : bool [attached]

이 첨부 속성은 공유 툴팁이 표시되는지 여부를 나타냅니다. 이 속성은 모든 항목에 첨부할 수 있습니다.

Attached Tool Tips도 참조하십시오 .

메서드 문서

[since QtQuick.Controls 2.5 (Qt 5.12)] void hide()

이 메서드는 툴팁을 숨깁니다.

이 메서드는 QtQuick.Controls 2.5(Qt 5.12)에서 도입되었습니다.

[since QtQuick.Controls 2.5 (Qt 5.12)] void show(string text, int timeout)

이 메서드는 ` text `을 툴팁으로 표시하며, 툴팁의 표시 시간은 ` timeout `(밀리초)로 제한됩니다.

이 메서드는 QtQuick.Controls 2.5(Qt 5.12)에서 도입되었습니다.

첨부된 메서드 문서

[attached] void hide()

이 첨부된 메서드는 공유 툴팁을 숨깁니다. 이 메서드는 어떤 항목에나 적용할 수 있습니다.

Attached Tool Tips도 참조하십시오 .

[attached] void show(string text, int timeout = -1)

이 첨부된 메서드는 text 및 timeout (밀리초)를 사용하여 공유 툴팁을 표시합니다. 이 메서드는 어떤 항목에나 적용할 수 있습니다.

Attached Tool Tips도 참조하십시오 .