Back to Qt.io
Contact Us Blog Download Qt

SignalTransition QML Type

Der SignalTransition-Typ bietet einen Übergang, der auf einem Qt-Signal basiert. Mehr...

Import Statement: import QtQml.StateMachine 6.8
Inherits:

QSignalTransition

Eigenschaften

Detaillierte Beschreibung

SignalTransition ist Teil der Qt State Machine QML API.

Beispielverwendung

import QtQuick
import QtQml.StateMachine as DSM

Rectangle {
    DSM.StateMachine {
        id: stateMachine
        initialState: state
        running: true
        DSM.State {
            id: state
            DSM.SignalTransition {
                targetState: finalState
                signal: button.clicked
                guard: guardButton.checked
            }
        }
        DSM.FinalState {
            id: finalState
        }
        onFinished: Qt.quit()
    }
    Row {
        spacing: 2
        Button {
            id: button
            text: "Finish state"
        }

        Button {
            id: guardButton
            checkable: true
            text: checked ? "Press to block the SignalTransition" : "Press to unblock the SignalTransition"
        }
    }
}

Siehe auch StateMachine, FinalState, und TimeoutTransition.

Dokumentation der Eigenschaft

guard : bool

Guard-Bedingungen beeinflussen das Verhalten eines Zustandsautomaten, indem sie Übergänge nur dann aktivieren, wenn sie zu true ausgewertet werden, und sie deaktivieren, wenn sie zu false ausgewertet werden.

Wenn das mit diesem Signalübergang verbundene Signal ausgegeben wird, wird die Guard-Bedingung ausgewertet. In der Guard-Bedingung können die Argumente des Signals verwendet werden, wie im folgenden Beispiel gezeigt.

import QtQuick
import QtQml.StateMachine as DSM

Rectangle {
    Button {
        anchors.fill: parent
        id: button
        DSM.StateMachine {
            DSM.State {
                DSM.SignalTransition {
                    targetState: finalState
                    signal: button.mysignal
                    // the guard condition uses the mystr string argument from mysignal
                    guard: mystr == "test"
                }
            }
            DSM.FinalState {
                id: finalState
            }
        }
        // define the signal the SignalTransition is connected with
        signal mysignal(mystr: string)
        // on clicking the button emit the signal with a single string argument
        onClicked: button.mysignal("test")
    }
}

Siehe auch signal.


signal : signal

Das Signal, das mit diesem Signalübergang verbunden ist.

import QtQuick
import QtQml.StateMachine as DSM

Rectangle {
    Button {
        anchors.fill: parent
        id: button
        DSM.StateMachine {
            DSM.State {
                DSM.SignalTransition {
                    targetState: finalState
                    signal: button.clicked
                }
            }
            DSM.FinalState {
                id: finalState
            }
        }
    }
}

© 2025 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.