PointLight QML Type

Definiert einen Lichtpunkt in der Szene. Mehr...

• Liste aller Mitglieder, einschließlich geerbter Mitglieder

Eigenschaften

• constantFade : real
• linearFade : real
• quadraticFade : real

Ausführliche Beschreibung

Das Punktlicht kann als eine Kugel beschrieben werden, die Licht mit gleicher Stärke in alle Richtungen vom Zentrum des Lichts ausstrahlt. Dies ist vergleichbar mit der Art und Weise, wie eine Glühbirne Licht ausstrahlt.

Das Drehen oder Skalieren eines Punktlichts hat keine Auswirkung. Das Verschieben eines Punktlichts ändert die Position, von der aus das Licht ausgestrahlt wird.

Standardmäßig nimmt die Intensität eines Punktlichts nach dem inversen Quadratgesetz ab. Die Abschwächung (und der Bereich) kann jedoch mit den Eigenschaften constantFade, linearFade und quadraticFade gesteuert werden. Die Lichtabschwächung wird nach der folgenden Formel berechnet constantFade + distance * (linearFade * 0.01) + distance^2 * (quadraticFade * 0.0001)

Ein einfaches Beispiel: Schattierung einer Kugel auf drei verschiedene Arten

Nehmen wir eine Szene mit einer Kugel vor einem skalierten Rechteck im Hintergrund. Die Standard-Grundfarbe der PrincipledMaterial des Rechtecks ist weiß.

Ohne Lichter und bei deaktivierter lichtbezogener Schattierung für die beiden Meshes ergibt sich folgendes Bild:

import QtQuick
import QtQuick3D
View3D {
    anchors.fill: parent

    PerspectiveCamera { z: 600 }

    Model {
        source: "#Rectangle"
        scale: Qt.vector3d(10, 10, 10)
        z: -100
        materials: PrincipledMaterial {
            lighting: PrincipledMaterial.NoLighting
        }
    }

    Model {
        source: "#Sphere"
        scale: Qt.vector3d(2, 2, 2)
        materials: PrincipledMaterial {
            lighting: PrincipledMaterial.NoLighting
            baseColor: "#40c060"
            roughness: 0.1
        }
    }
}

Das Hinzufügen eines gerichteten Lichts, das standardmäßig in Richtung der Z-Achse strahlt, führt zu folgendem Ergebnis:

import QtQuick
import QtQuick3D
View3D {
    anchors.fill: parent

    PerspectiveCamera { z: 600 }

    DirectionalLight { }

    Model {
        source: "#Rectangle"
        scale: Qt.vector3d(10, 10, 10)
        z: -100
        materials: PrincipledMaterial { }
    }

    Model {
        source: "#Sphere"
        scale: Qt.vector3d(2, 2, 2)
        materials: PrincipledMaterial {
            baseColor: "#40c060"
            roughness: 0.1
        }
    }
}

Ersetzen wir nun DirectionalLight durch:

PointLight {
    z: 300
}

Das weiß gefärbte PointLight wird hier auf der Z-Achse so verschoben, dass es sich auf halbem Weg zwischen der Kamera und dem Zentrum der Szene befindet. Im Gegensatz zu DirectionalLight spielt die Drehung des PointLights keine Rolle, während seine Position von Bedeutung ist. Die abnehmende Intensität ist hier sichtbar, besonders auf dem rechteckigen Netz im Hintergrund.

Weitere Anwendungsbeispiele finden Sie unter Qt Quick 3D - Lights Example.

Siehe auch DirectionalLight, SpotLight, und Shadow Mapping.

Dokumentation der Eigenschaft