MapQuickItem QML Type

MapQuickItem 유형은 지도(Map)에 임의의 Qt Quick 객체를 표시합니다. 더 보기...

• 상속된 멤버를 포함한 모든 멤버 목록
• MapQuickItem은 QML Maps 플러그인의 일부입니다.

속성

• anchorPoint : point
• autoFadeIn : bool
• coordinate : coordinate
• sourceItem : object
• zoomLevel : real

상세 설명

MapQuickItem 유형은 임의의 Qt Quick 객체를 지정된 위치와 크기로 지도 위에 배치하는 데 사용됩니다. 지도 위에 항목을 떠 있게 배치하는 것과 비교하여, MapQuickItem은 마치 지도 표면 위에 있는 것처럼 지도의 패닝(및 선택적으로 확대/축소)을 따라갑니다.

sourceItem 속성에는 그려질 Qt Quick 항목이 포함되며, 이 항목은 표시 가능한 모든 유형일 수 있습니다.

위치 지정 및 크기 조정

지도 상에서 MapQuickItem의 위치는 coordinate 및 anchorPoint 라는 두 가지 속성에 의해 제어됩니다. coordinate 만 설정된 경우, 해당 항목이 배치될 경도/위도 좌표를 지정합니다. 설정된 좌표는 화면에 표시될 때 포함된 항목의 왼쪽 상단 모서리와 일치하게 됩니다.

anchorPoint 속성을 사용하면 항목이 오프셋될 픽셀 수를 설정함으로써, 좌상단 모서리 이외의 항목의 다른 부분과 좌표를 맞출 수 있습니다. 이를 간단히 이해하려면, anchorPoint 로 지정된 항목 자체의 점이 표시될 때 주어진 coordinate 와 일치하는 점이라는 점을 기억하면 됩니다.

MapQuickItem은 지도에 고정될 뿐만 아니라, 선택적으로 지도의 축척을 따르도록 설정하여 지도를 확대하거나 축소할 때 크기가 변경되도록 할 수 있습니다. 이 동작은 zoomLevel 속성으로 제어됩니다. zoomLevel 가 설정되지 않은 경우의 기본 동작은 항목이 “지도 위”가 아닌 “화면 위”에 그려지므로, 지도의 확대/축소 수준에 관계없이 크기가 동일하게 유지됩니다.

성능

MapQuickItem의 성능은 일반적으로 포함된 Qt Quick 항목 단독의 성능과 비슷한 수준입니다. 추가되는 오버헤드는 원본 항목의 이동 및(경우에 따라) 크기 조정, 그리고 경도 및 위도에서 화면 위치로의 변환으로 인해 발생합니다.

제한 사항

사용 예시

다음 코드 조각은 지도에 마커를 표시하기 위해 Image 객체를 포함하는 MapQuickItem을 보여줍니다. 이 전략은 MapViewer 예제에서 지도 마커를 표시하는 데 사용됩니다.

MapQuickItem {
    id: marker
    anchorPoint.x: image.width/4
    anchorPoint.y: image.height

    HoverHandler {
        id: hoverHandler
    }
    TapHandler {
        id: tapHandler
        acceptedButtons: Qt.RightButton
        gesturePolicy: TapHandler.WithinBounds
        onTapped: {
            mapview.currentMarker = -1
            for (var i = 0; i< mapview.markers.length; i++){
                if (marker == mapview.markers[i]){
                    mapview.currentMarker = i
                    break
                }
            }
            mapview.showMarkerMenu(marker.coordinate)
        }
    }
    DragHandler {
        id: dragHandler
        grabPermissions: PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType
    }

    sourceItem: Image {
        id: image
    }
}

속성 설명

anchorPoint : point

이 속성은 지도상의 좌표와 sourceItem 상의 어느 지점이 일치하도록 할지 결정합니다.

autoFadeIn : bool

이 속성은 매우 낮은 확대/축소 수준에서 지도를 확대할 때 항목이 자동으로 페이드 인되는지 여부를 결정합니다. 기본적으로 이 속성의 값은 ‘ true ’입니다. 이 속성을 ‘ false ’로 설정하면 지도 항목의 불투명도가 항상 ‘ QtQuick::Item::opacity ’ 속성에 지정된 값(기본값은 1.0)을 따르게 됩니다.

coordinate : coordinate

이 속성은 MapQuickItem 의 앵커 좌표를 저장합니다. anchorPoint 로 지정된 sourceItem 상의 점은 지도에 그려질 때 이 좌표와 정렬된 상태를 유지합니다.

아래 이미지에는 anchorPoint 속성의 값을 제외하고는 모두 동일한 3개의 MapQuickItem이 있습니다. 각 항목의 anchorPoint 값은 해당 항목 상단에 표시되어 있습니다.

sourceItem : object

이 속성은 지도에 그려질 소스 항목을 포함합니다.

zoomLevel : real

이 속성은 MapQuickItem 의 콘텐츠 크기 조정 동작을 제어합니다. 특히, 이 속성을 설정함으로써 화면에 그려지는 객체(크기가 화면 픽셀 단위로 지정됨)와 지도 표면에 그려지는 객체(지도의 확대/축소 수준에 따라 크기가 변함) 중에서 선택할 수 있습니다.

이 속성의 기본값은 0.0이며, 이는 객체를 화면 표면에 그리는 것을 의미합니다. 다른 값으로 설정하면 객체는 대신 지도 표면에 그려집니다. 이 값(0이 아닌 경우)은 객체가 1:1 비율(즉, 객체 픽셀과 화면 픽셀이 동일한 크기인 상태)로 표시되는 줌 레벨을 지정합니다. 이보다 낮은 확대/축소 수준에서는 객체가 더 작게 보이고, 더 높은 확대/축소 수준에서는 더 크게 보입니다. 이는 이 속성이 0으로 설정되었을 때와 대조적이며, 이 경우 모든 확대/축소 수준에서 객체의 화면 크기는 동일하게 유지됩니다.