Back to Qt.io
Contact Us Blog Download Qt
이 페이지에서

SCXML 신호등 (동적, QML)

동적으로 로드된 상태 머신을 사용하여 신호등을 구현하는 Qt Quick 애플리케이션입니다.

녹색 불이 켜진 신호등

신호등 QML은 동적으로 로드된 상태 머신에서 상태의 활성 속성에 연결하는 방법을 보여줍니다.

UI는 Qt Quick 를 사용하여 생성됩니다.

예제 실행

다음 위치에서 예제를 실행할 수 있습니다.

상태 머신 동적 로드

예제의 빌드 파일에 다음 줄을 추가하여 Qt SCXML 모듈을 링크합니다.

qmake를 사용할 때 .pro 파일에:

QT += qml scxml

cmake를 사용할 경우 CMakeLists.txt 에 추가:

find_package(Qt6 REQUIRED COMPONENTS Core Gui Qml Scxml)
target_link_libraries(trafficlight-qml-dynamic PRIVATE
    Qt6::Core
    Qt6::Gui
    Qt6::Qml
    Qt6::Scxml
)

메인 QML 파일에서 상태 머신을 동적으로 생성합니다:

import QtScxml
import TrafficLightApplication

Window {
    width: lights.width
    height: lights.height
    visible: true

    Lights {
        id: lights
        stateMachine: loader.stateMachine
        // Suppress qmllint warning, dynamic statemachine properties not known at compile-time
        // qmllint disable missing-property
        button.source: stateMachine.working ? "pause.png" : "play.png"
        button.onClicked: stateMachine.submitEvent(stateMachine.working ? "smash" : "repair");
        // qmllint enable missing-property
    }

    StateMachineLoader {
        id: loader
        source: Qt.resolvedUrl("statemachine.scxml")
    }
}

상태 연결

SCXML 파일에서 각 조명에 대한 상태(빨강, 노랑, 초록)를 지정합니다. ` <onentry> ` 요소에서는 해당 상태로 진입할 때 전송할 이벤트와 이벤트 전송 전 지연 시간(초)을 지정합니다. ` <transition> ` 요소에서는 ` target ` 속성으로 지정된 상태로의 전환을 트리거하는 이벤트를 지정합니다:

        <state id="red">
            <onentry>
                <send event="startGoingGreen" delay="3s"/>
            </onentry>
            <transition event="startGoingGreen" target="redGoingGreen"/>
        </state>

        <state id="yellow" initial="greenGoingRed">
            <state id="redGoingGreen">
                <onentry>
                    <send event="goGreen" delay="1s"/>
                </onentry>
                <transition event="goGreen" target="green"/>
            </state>

            <state id="greenGoingRed">
                <onentry>
                    <send event="goRed" delay="1s"/>
                </onentry>
                <transition event="goRed" target="red"/>
            </state>
        </state>

        <state id="green">
            <onentry>
                <send event="startGoingRed" delay="3s"/>
            </onentry>
            <transition event="startGoingRed" target="greenGoingRed"/>
        </state>

상태 간 연결은 다음과 같이 설정합니다:

    states: [
        // Suppress qmllint warning, dynamic statemachine properties not known at compile-time
        // qmllint disable missing-property
        State {
            name: "Red"
            when: lights.stateMachine.red

            PropertyChanges { redLight.opacity: 1 }
        },
        State {
            name: "RedGoingGreen"
            when: lights.stateMachine.redGoingGreen

            PropertyChanges { redLight.opacity: 1 }
            PropertyChanges { yellowLight.opacity: 1 }
        },
        State {
            name: "Yellow"
            when: lights.stateMachine.yellow || lights.stateMachine.blinking

            PropertyChanges { yellowLight.opacity: 1 }
        },
        State {
            name: "Green"
            when: lights.stateMachine.green

            PropertyChanges { greenLight.opacity: 1 }
        }
        // qmllint enable missing-property
    ]

예제 프로젝트 @ code.qt.io

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.