PropertyChanges QML Type

描述状态的新属性绑定或值。更多...

• 所有成员的列表，包括继承的成员

属性

• explicit : bool
• restoreEntryValues : bool
• target : QtObject

详细说明

PropertyChanges 用于定义State 中的属性值或绑定。这使得当项目在不同状态之间切换时，其属性值能够随之改变。

要创建一个 PropertyChanges 对象，请像绑定本地属性一样将其绑定到目标项的属性上。这样，您就可以定义新的属性值或绑定。例如：

import QtQuick

Item {
    id: container
    width: 300; height: 300

    Rectangle {
        id: rect
        width: 100; height: 100
        color: "red"

        MouseArea {
           id: mouseArea
           anchors.fill: parent
        }

        states: State {
           name: "resized"; when: mouseArea.pressed
           PropertyChanges {
               rect {
                   color: "blue"
                   height: container.height
               }
           }
        }
    }
}

当鼠标被按下时，Rectangle 将切换至“调整大小”状态。在此状态下，PropertyChanges对象将矩形的颜色设置为蓝色，并将height 的值设置为container.height 的值。

请注意，这会在“resized”状态下自动将rect.height 与container.height 建立绑定。如果不应建立该属性绑定，且仅需将高度设置为状态变化时container.height 的值，请将explicit 属性设置为true 。

PropertyChanges 对象还可以覆盖对象的默认信号处理程序，以实现针对新状态的特定信号处理程序：

PropertyChanges {
    myMouseArea.onClicked: doSomethingDifferent()
}

重置属性值

undefined 值可用于重置某个状态的属性值。在下面的示例中，当myText 切换到widerText状态时，其width 属性会被重置，使文本恢复自然宽度，并将整个字符串显示在单行上。

Rectangle {
    width: 300; height: 200

    Text {
        id: myText
        width: 50
        wrapMode: Text.WordWrap
        text: "a text string that is longer than 50 pixels"

        states: State {
            name: "widerText"
            PropertyChanges { myText.width: undefined }
        }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: myText.state = "widerText"
    }
}

过渡中的即时属性更改

当使用“过渡”来动画化状态变化时，它们会将属性从当前状态的值动画化至新状态中定义的值（由 PropertyChanges 对象定义）。然而，有时希望在Transition 过程中立即设置属性值，而不进行动画；在这种情况下，可以使用PropertyAction 类型来强制立即更改属性。

更多详细信息请参阅PropertyAction 的文档。

另请参阅 “States”示例、Qt Quick States以及 Qt Qml。

属性文档

explicit : bool

如果 `explicit` 设置为 `true`，则绑定将被解释为赋值。该表达式仅会被求值一次，即使依赖关系发生变化，也不会进行任何更新。

在下面的示例中，添加 `explicit` 参数可防止 `myItem.width ` 被绑定到 `parent.width`。相反，它会被赋值为状态变更时 `parent.width ` 的值。

PropertyChanges {
    target: myItem
    explicit: true
    width: parent.width
}

默认情况下，explicit 的值为 false。

restoreEntryValues : bool

该属性用于控制在退出该状态时是否应恢复之前的值。

默认值为true 。将此值设置为false 将创建一个临时状态，该状态会对属性值产生持久影响。

target : QtObject

该属性保存了一个对象，该对象包含待修改的属性。