AnchorChanges QML Type

Legt fest, wie die Anker eines Elements in einem Zustand geändert werden. Mehr...

• Liste aller Mitglieder, einschließlich geerbter Mitglieder

Eigenschaften

• anchors
  • anchors.baseline : AnchorLine
  • anchors.bottom : AnchorLine
  • anchors.horizontalCenter : AnchorLine
  • anchors.left : AnchorLine
  • anchors.right : AnchorLine
  • anchors.top : AnchorLine
  • anchors.verticalCenter : AnchorLine
• target : Item

Ausführliche Beschreibung

Der Typ „AnchorChanges“ wird verwendet, um die Anker eines Elements in einem „ State “ zu ändern.

Mit „AnchorChanges“ können die Ränder eines Elements nicht geändert werden. Verwenden Sie hierfür stattdessen „ PropertyChanges “.

Im folgenden Beispiel ändern wir die oberen und unteren Anker eines Elements mithilfe von „AnchorChanges“ und die oberen und unteren Ankerränder mithilfe von „ PropertyChanges “:

import QtQuick

Rectangle {
    id: window
    width: 120; height: 120
    color: "black"

    Rectangle { id: myRect; width: 50; height: 50; color: "red" }

    states: State {
        name: "reanchored"

        AnchorChanges {
            target: myRect
            anchors.top: window.top
            anchors.bottom: window.bottom
        }
        PropertyChanges {
            target: myRect
            anchors.topMargin: 10
            anchors.bottomMargin: 10
        }
    }

    MouseArea { anchors.fill: parent; onClicked: window.state = "reanchored" }
}

AnchorChanges können mithilfe von „ AnchorAnimation “ animiert werden.

//animate our anchor changes
Transition {
    AnchorAnimation {}
}

Änderungen an den Ankerrändern können mithilfe von „ NumberAnimation “ animiert werden.

Weitere Informationen zu Ankerpunkten finden Sie unter „Anker-Layouts“.

Eigenschaftsdokumentation

anchors group

Diese Eigenschaften ändern die jeweiligen Anker des Elements.

Um einen Anker zurückzusetzen, können Sie „ undefined “ zuweisen:

AnchorChanges {
    target: myItem
    anchors.left: undefined          //remove myItem's left anchor
    anchors.right: otherItem.right
}

target : Item

Diese Eigenschaft enthält die „ Item “, auf die die Änderungen an den Ankerpunkten angewendet werden.