KeyNavigation QML Type (Uncreatable)

Unterstützt die Navigation mit den Pfeiltasten. Mehr...

Hinweis: Dies ist ein nicht erstellbarer Typ. Er kann in QML nicht instanziiert werden.

• Liste aller Mitglieder, einschließlich geerbter Mitglieder

Angehängte Eigenschaften

• backtab : Item
• down : Item
• left : Item
• priority : enumeration
• right : Item
• tab : Item
• up : Item

Ausführliche Beschreibung

Tastaturbasierte Benutzeroberflächen ermöglichen in der Regel die Verwendung von Pfeiltasten zur Navigation zwischen Elementen, auf die der Fokus gesetzt werden kann. Der Anbindungstyp „KeyNavigation“ ermöglicht dieses Verhalten, indem er eine bequeme Möglichkeit bietet, das Element anzugeben, das den Fokus erhalten soll, wenn eine Pfeiltaste oder die Tabulatortaste gedrückt wird.

Das folgende Beispiel zeigt die Tastennavigation für ein 2x2-Raster aus Elementen:

import QtQuick

Grid {
    width: 100; height: 100
    columns: 2

    Rectangle {
        id: topLeft
        width: 50; height: 50
        color: focus ? "red" : "lightgray"
        focus: true

        KeyNavigation.right: topRight
        KeyNavigation.down: bottomLeft
    }

    Rectangle {
        id: topRight
        width: 50; height: 50
        color: focus ? "red" : "lightgray"

        KeyNavigation.left: topLeft
        KeyNavigation.down: bottomRight
    }

    Rectangle {
        id: bottomLeft
        width: 50; height: 50
        color: focus ? "red" : "lightgray"

        KeyNavigation.right: bottomRight
        KeyNavigation.up: topLeft
    }

    Rectangle {
        id: bottomRight
        width: 50; height: 50
        color: focus ? "red" : "lightgray"

        KeyNavigation.left: bottomLeft
        KeyNavigation.up: topRight
    }
}

Das Element oben links erhält zunächst den Fokus, indem „ focus “ auf „ true “ gesetzt wird. Wenn eine Pfeiltaste gedrückt wird, wechselt der Fokus zu dem entsprechenden Element, wie es durch den Wert definiert ist, der für die KeyNavigation-Eigenschaften „ left “, „ right “, „ up “ oder „ down “ festgelegt wurde.

Beachten Sie: Wenn ein „KeyNavigation“-Anbindungstyp die Tasten-Druck- und -Loslass-Ereignisse für eine angeforderte Pfeil- oder Tabulatortaste empfängt, wird das Ereignis akzeptiert und nicht weitergegeben.

Standardmäßig empfängt „KeyNavigation“ Tastenereignisse nach dem Element, an das es angehängt ist. Wenn das Element das Tastenereignis akzeptiert, erhält der „KeyNavigation“-Anhangstyp kein Ereignis für diese Taste. Durch Setzen der Eigenschaft „ priority “ auf „ KeyNavigation.BeforeItem “ kann das Ereignis für die Tastennavigation vor dem Element statt danach verwendet werden.

Ist das Element, zu dem der Fokus wechselt, nicht aktiviert oder sichtbar, wird versucht, dieses Element zu überspringen und den Fokus auf das nächste zu setzen. Dies ist möglich, wenn eine Kette von Elementen mit demselben „KeyNavigation“-Handler vorliegt. Sind mehrere Elemente hintereinander nicht aktiviert oder sichtbar, werden diese ebenfalls übersprungen.

„KeyNavigation“ legt implizit die andere Richtung fest, um den Fokus auf dieses Element zurückzusetzen. Wenn Sie also „ left “ auf ein anderes Element setzen, wird „ right “ im „KeyNavigation“-Handler dieses Elements festgelegt, um den Fokus wieder auf dieses Element zu setzen. Wurde jedoch für das KeyNavigation-Objekt dieses Elements „right“ explizit festgelegt, tritt keine Änderung ein. Das bedeutet, dass das obige Beispiel dasselbe Verhalten erzielen könnte, ohne für eines der Elemente „KeyNavigation.right“ oder „KeyNavigation.down“ anzugeben.

Siehe auch Keys attached property.

Dokumentation zu angehängten Eigenschaften

KeyNavigation.backtab : Item [attached]

Diese Eigenschaft gibt das Element an, dem der Fokus zugewiesen werden soll, wenn die Tastenkombination Umschalt+Tab (Backtab) gedrückt wird.

KeyNavigation.down : Item [attached]

Diese Eigenschaft gibt das Element an, dem der Fokus zugewiesen werden soll, wenn die Abwärts-Cursortaste gedrückt wird.

KeyNavigation.left : Item [attached]

Diese Eigenschaft gibt das Element an, dem der Fokus zugewiesen werden soll, wenn die linke Cursortaste gedrückt wird.

KeyNavigation.priority : enumeration [attached]

Diese Eigenschaft legt fest, ob die Schlüssel vor oder nach der eigenen Schlüsselverarbeitung des angehängten Elements verarbeitet werden.

KeyNavigation.right : Item [attached]

Diese Eigenschaft gibt das Element an, dem der Fokus zugewiesen werden soll, wenn die rechte Cursortaste gedrückt wird.

KeyNavigation.tab : Item [attached]

Diese Eigenschaft gibt das Element an, dem beim Drücken der Tabulatortaste der Fokus zugewiesen werden soll.

KeyNavigation.up : Item [attached]

Diese Eigenschaft gibt das Element an, dem der Fokus zugewiesen werden soll, wenn die Aufwärts-Cursortaste gedrückt wird.