ParentAnimation QML Type

Zeigt Änderungen der übergeordneten Werte animiert an. Mehr...

• Liste aller Mitglieder, einschließlich geerbter Mitglieder

Eigenschaften

• newParent : Item
• target : Item
• via : Item

Ausführliche Beschreibung

ParentAnimation wird verwendet, um eine Änderung des übergeordneten Elements für ein Item zu animieren.

Beispielsweise wird durch das folgende ` ParentChange ` bei einem Klick auf blueRect dieses Element zu einem Kind von redRect. Durch die Einbindung von `ParentAnimation`, die eine während des Übergangs anzuwendende ` NumberAnimation ` definiert, wird sichergestellt, dass das Element beim Wechsel zu seinem neuen übergeordneten Element flüssig animiert wird:

import QtQuick

Item {
    width: 200; height: 100

    Rectangle {
        id: redRect
        width: 100; height: 100
        color: "red"
    }

    Rectangle {
        id: blueRect
        x: redRect.width
        width: 50; height: 50
        color: "blue"

        states: State {
            name: "reparented"
            ParentChange { target: blueRect; parent: redRect; x: 10; y: 10 }
        }

        transitions: Transition {
            ParentAnimation {
                NumberAnimation { properties: "x,y"; duration: 1000 }
            }
        }

        MouseArea { anchors.fill: parent; onClicked: blueRect.state = "reparented" }
    }
}

Eine „ParentAnimation“ kann beliebig viele Animationen enthalten. Diese Animationen werden parallel ausgeführt; um sie nacheinander auszuführen, definieren Sie sie innerhalb eines „ SequentialAnimation “.

In einigen Fällen, beispielsweise bei der Umordnung von Elementen, bei denen das Clipping aktiviert ist, ist es sinnvoll, den Wechsel des übergeordneten Elements über ein anderes Element zu animieren, bei dem das Clipping nicht aktiviert ist. Ein solches Element kann mithilfe der Eigenschaft „ via “ festgelegt werden.

„ParentAnimation“ wird typischerweise innerhalb eines „ Transition “ in Verbindung mit einem „ ParentChange “ verwendet. Bei dieser Verwendung animiert sie alle „ ParentChange “, die während des Zustandswechsels aufgetreten sind. Dies kann überschrieben werden, indem über die Eigenschaft „ target “ ein bestimmtes Zielobjekt festgelegt wird.

Siehe auch „Animation und Übergänge“ unter Qt Quick sowie „Qt Quick -Beispiele – Animation“.

Eigenschaftsdokumentation

newParent : Item

Das neue übergeordnete Element, zu dem die Animation erfolgen soll.

Wenn die „ ParentAnimation “ innerhalb eines „ Transition “ definiert ist, wird dieser Wert standardmäßig auf den Wert gesetzt, der im Endzustand des „ Transition “ definiert ist.

target : Item

Das Element, dessen Zuordnung geändert werden soll.

Wird dieses Element in einem Übergang verwendet und kein Ziel angegeben, werden alle Vorkommen von „ ParentChange “ durch „ ParentAnimation “ animiert.

via : Item

Das Element, dessen übergeordnete Beziehung geändert werden soll. Dies ermöglicht eine unbeschnittene Animation, wenn sowohl das alte als auch das neue übergeordnete Element beschnitten sind.

ParentAnimation {
    target: myItem
    via: topLevelItem
    // ...
}