PathAttribute QML Type

Legt fest, wie ein Attribut an einer bestimmten Position in einem Pfad gesetzt wird. Mehr...

• Liste aller Mitglieder, einschließlich geerbter Mitglieder

Eigenschaften

• name : string
• value : real

Ausführliche Beschreibung

Das PathAttribute-Objekt ermöglicht es, Attribute, bestehend aus einem Namen und einem Wert, für verschiedene Punkte entlang eines Pfades festzulegen. Die Attribute werden dem Delegaten als angehängte Eigenschaften (Attached Properties) zur Verfügung gestellt. Der Wert eines Attributs an einem bestimmten Punkt entlang des Pfades wird aus den PathAttributes interpoliert, die diesen Punkt umschließen.

Das folgende Beispiel zeigt einen Pfad, bei dem die Elemente am oberen Ende des Pfads auf 30 % skaliert und mit einer Deckkraft von 50 % dargestellt werden, während sie am unteren Ende auf 100 % skaliert und mit einer Deckkraft von 100 % dargestellt werden. Beachten Sie die Verwendung der angehängten Eigenschaften „ PathView.iconScale“ und „ PathView.iconOpacity“, um die Skalierung und Deckkraft des Delegaten festzulegen.

import QtQuick

Rectangle {
    width: 240; height: 200

    Component {
        id: delegate
        Item {
            width: 80; height: 80
            scale: PathView.iconScale
            opacity: PathView.iconOpacity
            Column {
                Image { anchors.horizontalCenter: nameText.horizontalCenter; width: 64; height: 64; source: icon }
                Text { id: nameText; text: name; font.pointSize: 16 }
            }
        }
    }

    PathView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: delegate
        path: Path {
            startX: 120; startY: 100
            PathAttribute { name: "iconScale"; value: 1.0 }
            PathAttribute { name: "iconOpacity"; value: 1.0 }
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathAttribute { name: "iconScale"; value: 0.3 }
            PathAttribute { name: "iconOpacity"; value: 0.5 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}

Siehe auch Path.

Eigenschaftsdokumentation

name : string

Diese Eigenschaft enthält den Namen des zu ändernden Attributs.

Dieses Attribut steht dem Delegaten als „ PathView.<name>“ zur Verfügung.

Beachten Sie, dass die Verwendung eines vorhandenen Item-Eigenschaftsnamens wie „opacity“ als Attribut zulässig ist. Dies liegt daran, dass Pfadattribute eine neue angehängte Eigenschaft hinzufügen, die in keiner Weise mit bestehenden Eigenschaften in Konflikt steht.

value : real

Diese Eigenschaft enthält den Wert für das Attribut.

Der angegebene Wert kann verwendet werden, um das visuelle Erscheinungsbild eines Elements entlang des Pfades zu beeinflussen. Der folgende Pfad legt beispielsweise ein Attribut namens „itemRotation“ fest, das am Anfang des Pfades den Wert 0 und am Ende des Pfades den Wert 90 hat.

Path {
    startX: 0
    startY: 0
    PathAttribute { name: "itemRotation"; value: 0 }
    PathLine { x: 100; y: 100 }
    PathAttribute { name: "itemRotation"; value: 90 }
}

In unserem Delegaten können wir dann die Eigenschaft „rotation“ an die für dieses Attribut erstellte angehängte Eigenschaft „PathView.itemRotation“ binden.

Rectangle {
    width: 10; height: 10
    rotation: PathView.itemRotation
}

Wenn jedes Element entlang des Pfades positioniert wird, wird es entsprechend gedreht: Ein Element am Anfang des Pfades wird nicht gedreht, ein Element am Ende des Pfades wird um 90 Grad gedreht und ein Element in der Mitte des Pfades wird um 45 Grad gedreht.