En esta página

SceneEnvironment QML Type

Te permite configurar cómo se representa una escena. Más...

Import Statement: import QtQuick3D
Inherits:

Object3D

Inherited By:

ExtendedSceneEnvironment

Propiedades

Descripción detallada

SceneEnvironment define un conjunto de propiedades globales que determinan cómo debe renderizarse una escena.

Nota: El módulo QtQuick3D.Helpers ofrece un tipo ExtendedSceneEnvironment que hereda de SceneEnvironment y añade además una serie de efectos integrados.

Para utilizar SceneEnvironment o ExtendedSceneEnvironment, asocia el environment property de un View3D a una instancia de estos tipos. El objeto se puede declarar en línea, por ejemplo, así:

View3D {
    environment: SceneEnvironment {
        antialiasingMode: SceneEnvironment.MSAA
        tonemapMode: SceneEnvironment.TonemapModeFilmic
        backgroundMode: SceneEnvironment.SkyBox
        lightProbe: Texture {
            source: "panoramic_hdri_background.hdr"
        }
    }
}

Como alternativa, el objeto de entorno se puede definir por separado. A continuación, uno o varios objetos ` View3D ` pueden hacer referencia a él. A continuación se muestra un fragmento de código de ejemplo, en el que se utiliza ` ExtendedSceneEnvironment `:

ExtendedSceneEnvironment {
    id: myEnv
    vignetteEnabled: true
}

View3D {
    width: parent.width / 2
    environment: myEnv
}

View3D {
    width: parent.width / 2
    x: parent.width / 2
    environment: myEnv
}

Descripción general de las funciones

Véase también ExtendedSceneEnvironment.

Documentación de la propiedad

antialiasingMode : enumeration

Esta propiedad controla el modo de suavizado que se aplica al renderizar la escena.

Los valores posibles son:

ConstanteDescripción
SceneEnvironment.NoAANo se aplica antialiasing.
SceneEnvironment.SSAASe aplica suavizado por sobremuestreo.
SceneEnvironment.MSAASe aplica suavizado por multimuestreo.
SceneEnvironment.ProgressiveAASe aplica suavizado progresivo.

El valor por defecto es « SceneEnvironment.NoAA ».

Supermuestreo

La escena se renderiza a una resolución superior y, a continuación, se reduce a la resolución real.

Ventajas: Alta calidad. Suaviza todo el contenido de la escena y no solo las siluetas geométricas.

Inconvenientes: suele ser más costoso que el MSAA. Aumenta el uso de memoria de vídeo. Compatible con elementos de View3D con cualquier renderMode excepto Inline, pero dado que la técnica implica renderizar primero a una textura, habilitar SSAA con un renderMode de Underlay u Overlay dará lugar al uso de una textura intermedia y una pasada de renderizado que normalmente no serían necesarias, lo que significa que la merma de rendimiento puede ser más notable. Se recomienda utilizar SSAA únicamente cuando el renderMode sea el predeterminado Offscreen.

Multimuestreo

Los bordes de la geometría se someten a un supermuestreo, lo que da como resultado siluetas más suaves. Sin embargo, esta técnica no tiene ningún efecto sobre los materiales del interior de la geometría.

Ventajas: Funciona con cualquier elemento de « View3D », independientemente del «renderMode». Ofrece buenos resultados en las siluetas de la geometría, donde el aliasing suele ser más notable; funciona con animaciones rápidas sin problemas. El rendimiento depende exclusivamente de las capacidades del sistema (GPU).

Inconvenientes: No ayuda con los problemas de texturas o reflejos. Aumenta el uso de la memoria de vídeo. Su uso puede resultar costoso en hardware gráfico menos potente. Se puede controlar por ventana o para elementos individuales de « View3D », dependiendo del «renderMode». Al utilizar «Underlay/Overlay» con un efecto aplicado o «Offscreen», el MSAA se puede controlar para cada elemento de « View3D ». Por otro lado, el uso de «Underlay/Overlay» sin ningún efecto o de «Inline» hará que el MSAA se controle por ventana.

Nota: Para los elementos « View3D » con un « renderMode » distinto de «Underlay/Overlay» con efectos o «Offscreen», el multimuestreo solo se puede habilitar a través de la opción « QSurfaceFormat » de « QQuickWindow » o « QQuickView ». Esto afectará entonces a todo el contenido, tanto 2D como 3D, de esa ventana.

Antisalias progresivo

Esta propiedad activa y establece el nivel de suavizado progresivo aplicado a la escena.

Cuando todo el contenido de la escena ha dejado de moverse, la cámara se agita muy ligeramente entre fotogramas, y el resultado de cada nuevo fotograma se fusiona con los fotogramas anteriores. Cuantos más fotogramas se acumulen, mejor será el resultado.

Ventajas: Ofrece excelentes resultados cuando todo el contenido de la escena está quieto.

Inconvenientes: No surte efecto si se producen cambios visuales. Es costoso debido a la necesidad de acumular y fusionar fotogramas. Aumenta el uso de la memoria de vídeo.

Nota: El suavizadoprogresivo no es compatible actualmente con el renderizado multivista y no debe utilizarse en aplicaciones de RV/RA.

Consulta las «Prácticas recomendadas sobre suavizado» para obtener más información sobre los métodos de suavizado.

antialiasingQuality : enumeration

Esta propiedad establece el nivel de suavizado aplicado a la escena. Su comportamiento depende de la opción « antialiasingMode » utilizada. Si la propiedad « antialiasingMode » está configurada en « NoAA », esta propiedad no tiene ningún efecto.

Los valores posibles son:

ConstanteDescripción
SceneEnvironment.MediumSSAA: El suavizado utiliza una resolución de sobremuestreo de 1,2x.
MSAA: El suavizado utiliza 2 muestras por píxel.
ProgressiveAA: El suavizado utiliza 2 fotogramas para la imagen final.
SceneEnvironment.HighSSAA: El suavizado utiliza una resolución de sobremuestreo de 1,5x.
MSAA: El suavizado utiliza 4 muestras por píxel.
ProgressiveAA: El suavizado utiliza 4 fotogramas para la imagen final.
SceneEnvironment.VeryHighSSAA: El antialiasing utiliza una resolución de sobremuestreo de 2,0x.
MSAA: El antialiasing utiliza 8 muestras por píxel.
ProgressiveAA: El antialiasing utiliza 8 fotogramas para la imagen final.

El valor por defecto es SceneEnvironment.High

aoBias : real

Esta propiedad define una distancia de corte que impide que los objetos muestren oclusión ambiental a distancias cortas. Los valores más altos aumentan la distancia necesaria entre los objetos para que se aprecie la oclusión ambiental.

Nota: Si observas sombras de oclusión ambiental en objetos en los que no debería haberlas, aumenta ligeramente el valor para eliminar los resultados más cercanos.

El valor por defecto es 0,0.

aoDistance : real

Esta propiedad define, a grandes rasgos, hasta qué distancia se extienden las sombras de oclusión ambiental desde los objetos. Cuanto mayor sea la distancia, mayor será el impacto en el rendimiento.

El valor por defecto es 5,0.

En la imagen se muestra el valor predeterminado de « aoSoftness » y el máximo de « aoStrength »:

aoDistance de 5aoDistance de 1

Escena con una distancia de oclusión ambiental de 5

Escena con una distancia de oclusión ambiental de 1

Nota: Para conseguir una oclusión ambiental en el espacio de pantalla con un buen aspecto visual, es necesario ajustar cuidadosamente una serie de parámetros relacionados, como « aoStrength », « aoSoftness », «aoDistance», « aoDither », « aoBias » y « aoSampleRate ».

Véase también aoStrength y aoSoftness.

aoDither : bool

Cuando esta propiedad está activada, dispersa los bordes de las bandas de sombra de la oclusión ambiental para mejorar la suavidad (aunque a veces se corre el riesgo de que aparezcan artefactos con patrones evidentes).

Nota: Las distanciasmuy grandes entre los planos de recorte de la cámara pueden causar problemas con la oclusión ambiental. Si observas bandas extrañas en la oclusión ambiental, prueba a ajustar la propiedad « clipFar » de la cámara para que esté más cerca del contenido.

El valor predeterminado es « false ».

Véase también « PerspectiveCamera.clipFar » y « OrthographicCamera.clipFar ».

aoEnabled : bool [since 6.5]

Activar o desactivar la oclusión ambiental.

El valor por defecto es « false », lo que significa que la oclusión ambiental está desactivada.

Nota: Si « aoStrength » o « aoDistance » es 0, al establecer esta propiedad en « true » también se ajustarán dichos valores adecuadamente para que la oclusión ambiental sea efectiva.

Nota: Para conseguir una oclusión ambiental en el espacio de pantalla con un aspecto visualmente atractivo, es necesario ajustar cuidadosamente una serie de parámetros relacionados, como aoStrength, aoSoftness, aoDistance, aoDither, aoBias y aoSampleRate.

Esta propiedad se introdujo en Qt 6.5.

Véase también aoStrength y aoDistance.

aoSampleRate : int

Esta propiedad define la calidad de la oclusión ambiental (más tonos de gris) a costa del rendimiento.

El valor debe ser 2, 3 o 4. El valor predeterminado es 2.

aoSoftness : real

Esta propiedad define el grado de suavidad de los bordes del sombreado por oclusión ambiental.

El valor debe estar comprendido entre 0,0 y 50,0. El valor por defecto es 50,0.

En la imagen se muestra el valor predeterminado « aoDistance » y el máximo « aoStrength »:

aoSoftness de 50aoSoftness de 25

Escena con un nivel de suavidad de oclusión ambiental de 50

Escena con un nivel de suavidad de oclusión ambiental de 25

Nota: Para conseguir una oclusión ambiental en el espacio de pantalla visualmente atractiva, es necesario ajustar cuidadosamente una serie de parámetros relacionados, como « aoStrength », «aoSoftness», « aoDistance », « aoDither », « aoBias » y « aoSampleRate ».

Véanse también aoStrength y aoDistance.

aoStrength : real

Esta propiedad define la intensidad de la oclusión ambiental aplicada. La oclusión ambiental es una forma de iluminación global aproximada que provoca sombras propias no direccionales cuando los objetos están muy próximos entre sí. Un valor de 100 produce sombras completamente oscuras; los valores más bajos hacen que las sombras parezcan más claras. Un valor de 0 desactiva por completo la oclusión ambiental, lo que mejora el rendimiento a costa del realismo visual de los objetos 3D renderizados en la escena.

Todos los valores distintos de 0 tienen el mismo impacto en el rendimiento.

El valor por defecto es 0,0. El valor máximo es 100,0.

Un valor de 0 equivale a establecer « aoEnabled » en «false».

En la imagen se muestra con los valores predeterminados de « aoSoftness » y « aoDistance »:

aoStrength de 0 (AO desactivado)aoStrength de 100aoStrength de 50

Escena con un nivel de oclusión ambiental de 0

Escena con un nivel de oclusión ambiental de 100

Escena con una intensidad de oclusión ambiental de 50

Nota: Para conseguir una oclusión ambiental en el espacio de pantalla visualmente atractiva es necesario ajustar cuidadosamente una serie de parámetros relacionados, como aoStrength, aoSoftness, aoDistance, aoDither, aoBias y aoSampleRate.

Véanse también aoEnabled, aoDistance y aoSoftness.

backgroundMode : enumeration

Esta propiedad controla si se debe borrar el fondo de la escena y cómo debe hacerse.

Nota: El borrado del búfer de color que respalda la vista 3D no siempre se produce: dependiendo de la propiedad renderMode, es posible que el View3D no realice ningún borrado por sí mismo, en cuyo caso SceneEnvironment.Transparent y SceneEnvironment.Color no tienen ningún efecto. Solo el modo predeterminado Offscreen render mode (renderizado en una textura) admite todos los modos de borrado. Con el modo Underlay, utiliza QQuickWindow::setColor() o Window.color para controlar el color de borrado de la escena Qt Quick. SkyBox se gestiona de forma diferente, ya que implica dibujar geometría real, por lo que funciona de forma idéntica en todos los modos de renderizado.

ConstanteDescripción
SceneEnvironment.TransparentLa escena se borra para que quede transparente. Esto resulta útil para renderizar contenido 3D sobre otro elemento. Este modo no tiene ningún efecto cuando el View3D utiliza un renderMode de Underlay u Overlay sin ningún posprocesamiento habilitado.
SceneEnvironment.ColorLa escena se borra con el color especificado por la propiedad « clearColor ». Este modo no tiene ningún efecto cuando el « View3D » utiliza un «renderMode» de «Underlay» u «Overlay» sin ningún posprocesamiento activado.
SceneEnvironment.SkyBoxLa escena no se borrará, sino que se renderizará un SkyBox o un Skydome. El SkyBox se define utilizando el mapa HDRI especificado en la propiedad « lightProbe ».
SceneEnvironment.SkyBoxCubeMapLa escena no se borrará, sino que se renderizará un SkyBox o un Skydome. El SkyBox se define mediante el cubemap especificado en la propiedad « skyBoxCubeMap ».
SceneEnvironment.SkyMaterialLa escena no se borrará, sino que se renderizará un SkyBox o un Skydome. El SkyBox se muestrea a partir del mapa cúbico generado por el « SkyMaterial » definido en la propiedad « skyMaterial ». (Desde Qt 6.12)

El valor por defecto es SceneEnvironment.Transparent

Veamos el siguiente ejemplo. Se espera que el modelo «Suzanne» haya sido preprocesado con la herramienta « balsam » y procede del repositorio «glTF Sample Models ».

import QtQuick
import QtQuick3D
import QtQuick3D.Helpers

Item {
    width: 1280
    height: 720

    View3D {
        id: v3d
        anchors.fill: parent

        environment: ExtendedSceneEnvironment {
            backgroundMode: SceneEnvironment.SkyBox
            lightProbe: Texture { source: "00455_OpenfootageNET_field_low.hdr" }

            glowEnabled: true
            glowStrength: 1.25
            glowBloom: 0.25
            glowBlendMode: ExtendedSceneEnvironment.GlowBlendMode.Additive
        }

        DirectionalLight {
        }

        Suzanne {
            scale: Qt.vector3d(50, 50, 50)
            z: -500
        }

        PerspectiveCamera {
            id: camera
        }

        WasdController {
            controlledObject: camera
        }
    }
}

Si utilizamos iluminación basada en imágenes además de « DirectionalLight » y empleamos la textura de la sonda de luz como skybox, obtenemos lo siguiente:

Objeto en 3D con fondo ambiental

¿Qué ocurre si no hay sonda de luz?

backgroundMode: SceneEnvironment.Transparent

En este caso, el fondo no lo proporciona View3D, sino QQuickWindow o QQuickView, que alojan la escena en 2D y 3D. La iluminación se basa únicamente en DirectionalLight.

Objeto 3D con fondo transparente

Utilizando un color transparente fijo:

backgroundMode: SceneEnvironment.Color
clearColor: "green"

Objeto en 3D con fondo verde

Véase también lightProbe, QQuickWindow::setColor(), Window::color y View3D.

clearColor : color

Esta propiedad define qué color se utilizará para borrar la ventana gráfica cuando se utilice « SceneEnvironment.Color » para la propiedad « backgroundMode ».

El valor por defecto es Qt::black

Véase también « backgroundMode ».

debugSettings : QtQuick3D::DebugSettings [since 6.5]

Esta propiedad especifica un objeto ` DebugSettings `, que se utiliza para configurar las herramientas de depuración del renderizador. Durante la construcción, el ` SceneEnvironment ` crea automáticamente un objeto ` DebugSettings ` asociado a sí mismo, por lo que normalmente no es necesario establecer un ` DebugSettings ` personalizado.

Un ejemplo de renderización de la escena con el modo de estructura de alambre activado:

Escena de Sponza en modo de estructura alámbrica

Visualización de los vectores normales de las mallas:

Escena de Sponza en la que se muestran las normales de superficie

Visualización de la contribución de la iluminación especular:

Escena de Sponza en la que se aprecian reflejos especulares

Esta propiedad se introdujo en Qt 6.5.

Véase también DebugSettings.

depthPrePassEnabled : bool

Cuando está activado, el renderizador realiza un «Z-prepass» para los objetos opacos, lo que significa que los renderiza con un shader sencillo y con la escritura de color desactivada, con el fin de rellenar previamente el búfer de profundidad antes de emitir las llamadas de dibujo para las pasadas de renderizado principales.

Esto puede mejorar el rendimiento dependiendo del contenido de la escena. Normalmente, las escenas con muchos objetos superpuestos y sombreado de fragmentos costoso son las que más se benefician de ello. Al mismo tiempo, cabe señalar que el renderizador realiza una clasificación de delante hacia atrás para los objetos opacos, lo que por sí mismo ayuda a reducir el sombreado de fragmentos innecesario y, por lo tanto, el prepaso Z no siempre aporta mejoras significativas.

En las GPU que utilizan una arquitectura de renderizado en mosaico, algo habitual en sistemas móviles e integrados, se recomienda establecer este parámetro en « false ».

El valor por defecto es « false ».

Nota: Esta propiedad no tiene ningún efecto cuando la comprobación de profundidad está desactivada.

depthTestEnabled : bool

El valor por defecto es true. De forma predeterminada, el renderizador clasifica los objetos de la escena como « opaque » o « semi-transparent ». Los objetos (submallas con el material asociado) de la lista « opaque » se renderizan en primer lugar, con la comprobación de profundidad y la escritura de profundidad activadas, lo que proporciona un culling Z óptimo para los objetos 3D típicos que no tienen regiones semitransparentes. Los objetos de la lista semi-transparent se renderizan con la escritura de profundidad desactivada, aunque con la prueba de profundidad activada (para comparar con los objetos opacos), en orden de atrás hacia delante (ordenados según la distancia de su punto central a la cámara). Esto permite una mezcla correcta («transparencia») para los objetos 3D que presentan regiones semitransparentes en su superficie, ya sea debido al « node opacity » o a algún mapa de color o textura del material.

Cuando esta propiedad se establece en « false », no se escribe ni se comprueba el búfer Z, se omite la prueba de profundidad y todos los objetos, incluidos los totalmente opacos, se renderizan de una sola vez, ordenados de atrás hacia adelante.

Rara vez será necesario establecer esta propiedad en « false ». Puede resultar útil en escenas en las que se sabe que el enfoque de dos pasadas ofrece pocas ventajas, ya sea porque hay muy pocos objetos opacos o porque estos se transforman de tal manera que una única pasada ordenada de atrás hacia adelante ofrece un mejor rendimiento.

Nota: Establecer esta propiedad en « false » puede provocar errores de renderizado en determinadas escenas. Además, algunas funciones, como las sombras, la oclusión ambiental, « SCREEN_TEXTURE » y « DEPTH_TEXTURE » en materiales y efectos personalizados, no funcionarán correctamente si no se habilita el uso del búfer de profundidad.

Nota: Este indicador no controla la presencia de un búfer de profundidad o de profundidad-plantilla. Dichos búferes pueden seguir asignándose incluso cuando se establece en « false ».

effects : List<QtQuick3D::Effect>

Esta propiedad contiene una lista de efectos de posprocesamiento que se aplicarán a toda la ventana gráfica. El resultado de cada efecto se transmite al siguiente, por lo que el orden es importante.

Nota: Por motivos técnicos, no se admite añadir varias veces el mismo nodo « Effect » a la lista, ya que esto dará lugar a resultados inesperados.

fog : QtQuick3D::Fog [since 6.5]

Cuando esta propiedad se establece en un objeto válido de tipo « Fog », se utiliza para configurar la compatibilidad integrada del renderizador con la niebla.

El valor por defecto es nulo, lo que significa que no hay niebla. Esto equivale a establecer un objeto Fog con la propiedad « enabled » fijada en «false».

Escena con efecto de niebla

Esta propiedad se introdujo en Qt 6.5.

Véase también Fog.

lightProbe : QtQuick3D::Texture

Esta propiedad define una imagen que se utiliza para iluminar la escena, ya sea en sustitución de las luces estándar o como complemento de estas.

Lo ideal es que la imagen sea una imagen de alto rango dinámico (HDR) o un cubemap pregenerado. El pre-baking proporciona mejoras significativas en el rendimiento en tiempo de ejecución, ya que no se dedica tiempo al filtrado ni a la generación de mipmaps. Si la fuente es un archivo .hdr u otra imagen, el preprocesamiento basado en la GPU se lleva a cabo en tiempo de ejecución tras cargar el archivo de imagen, lo que puede resultar muy lento, especialmente en hardware integrado y móvil. Por lo tanto, se recomienda encarecidamente que las aplicaciones preprocesen las imágenes .hdr a más tardar en el momento de la compilación, tal y como se describe aquí.

Nota: El uso de una textura con « sourceItem » no es compatible con esta propiedad. El prefiltrado de todos los niveles de mipmap para contenido dinámico de « Qt Quick » no suele ser razonable en la práctica debido a las implicaciones en el rendimiento.

Para obtener más información sobre la iluminación basada en imágenes, consulta Uso de la iluminación basada en imágenes.

Nota: La textura de sonda de luz, cuando la propiedad se establece en una «textura» válida, se utiliza para la iluminación independientemente de la « backgroundMode ». Sin embargo, cuando « backgroundMode » se establece en « SceneEnvironment.SkyBox », la textura también se utiliza para renderizar el fondo de la escena como un «skybox».

Los ejemplos que se muestran a continuación se han generado variando el valor de « backgroundMode » en el entorno de la siguiente escena. La escena no cuenta con «DirectionLight», « PointLight » ni « SpotLight ». Toda la iluminación se basa en la imagen HDRI panorámica.

import QtQuick
import QtQuick3D
import QtQuick3D.Helpers

Item {
    width: 1280
    height: 720

    View3D {
        id: v3d
        anchors.fill: parent

        environment: ExtendedSceneEnvironment {
            backgroundMode: SceneEnvironment.SkyBox
            lightProbe: Texture { source: "00455_OpenfootageNET_field_low.hdr" }

            tonemapMode: SceneEnvironment.TonemapModeFilmic
            sharpnessAmount: 0.4

            glowEnabled: true
            glowStrength: 1.25
            glowBloom: 0.25
            glowBlendMode: ExtendedSceneEnvironment.GlowBlendMode.Additive
        }

        Node {
            scale: Qt.vector3d(100, 100, 100)

            Sponza {
            }

            Suzanne {
                y: 1
                scale: Qt.vector3d(0.5, 0.5, 0.5)
                eulerRotation.y: -90
            }
        }

        PerspectiveCamera {
            id: camera
            y: 100
        }

        WasdController {
            controlledObject: camera
        }
    }
}

Resultados con el entorno anterior:

Escena con sonda de luz

Escena con sonda de luz desde una perspectiva diferente

Si cambiamos el valor de « backgroundMode » a « SceneEnvironment.Transparent », obtendríamos:

Escena con el parámetro «backgroundMode» establecido en «transparent»

Escena con el parámetro «backgroundMode» establecido en «transparent» desde una perspectiva diferente

Aquí, la iluminación de la escena 3D es la misma que antes, lo que significa que los materiales utilizan la sonda de luz en los cálculos de iluminación de la misma forma que antes, pero no se renderiza ningún skybox. El fondo es blanco, ya que ese es el color de transparencias predeterminado del QQuickWindow que aloja la escena 2D y 3D.

Es válido volver a establecer el valor de la propiedad `lightProbe` en el valor predeterminado `null`. Esto desasigna la textura asociada anteriormente. Por ejemplo, utilicemos la tecla «Suprimir» para alternar dinámicamente entre la iluminación basada en imágenes con un skybox y la ausencia de iluminación basada en imágenes con un color de fondo fijo:

environment: ExtendedSceneEnvironment {
    id: env

    backgroundMode: SceneEnvironment.SkyBox
    lightProbe: iblTex

    tonemapMode: SceneEnvironment.TonemapModeFilmic
    sharpnessAmount: 0.4

    glowEnabled: true
    glowStrength: 1.25
    glowBloom: 0.25
    glowBlendMode: ExtendedSceneEnvironment.GlowBlendMode.Additive
}

Texture {
    id: iblTex
    source: "00455_OpenfootageNET_field_low.hdr"
}

focus: true
Keys.onDeletePressed: {
    if (env.backgroundMode == SceneEnvironment.SkyBox) {
        env.backgroundMode = SceneEnvironment.Color;
        env.clearColor = "green";
        env.lightProbe = null;
    } else {
        env.backgroundMode = SceneEnvironment.SkyBox;
        env.lightProbe = iblTex;
    }
}

Al pulsar «Delete» se obtiene el siguiente resultado. Recuerda que la escena utilizada aquí no tiene luces, por lo que todos los modelos 3D aparecen completamente negros.

Objetos en 3D sin sonda de luz sobre fondo verde

Plano de tierra sin sonda luminosa sobre fondo verde

Aunque lightProbe se utiliza habitualmente en combinación con instancias de Texture que obtienen sus datos de un archivo de imagen (normalmente .hdr o .ktx), también puede tener sentido asociarlo a una Texture que utilice datos en memoria, procedurally generated image data. Un ejemplo claro de ello es una textura cuyos datos de imagen se generan mediante ProceduralSkyTextureData desde el módulo QtQuick3D.Helpers:

backgroundMode: SceneEnvironment.SkyBox
lightProbe: Texture {
    textureData: ProceduralSkyTextureData {
    }
}

Esto nos proporciona una textura de skybox HDR generada proceduralmente que ahora se utiliza tanto como skybox como para la iluminación basada en imágenes:

Escena arquitectónica iluminada por un cielo generado proceduralmente, visible al fondo

Véase también backgroundMode, «Uso de la iluminación basada en imágenes», «Generación previa del cubemap IBL», probeExposure, probeHorizon, probeOrientation y ProceduralSkyTextureData.

lightmapper : Lightmapper

Cuando esta propiedad se establece en un objeto Lightmapper válido, se tendrán en cuenta los ajustes especificados por el objeto a la hora de generar los mapas de luz.

El valor por defecto es null, lo que significa que se utilizarán los valores predeterminados para todos los ajustes relacionados con el horneado.

Para obtener más información sobre cómo hornear mapas de luz, consulta la documentación de Lightmapper.

Cuando los mapas de luz no son relevantes para una aplicación y nunca se genera iluminación horneada, la propiedad y el objeto asociado no tienen ninguna utilidad en la práctica.

Véase también Model::usedInBakedLighting, Model::bakedLightmap, Light::bakeMode y Lightmapper.

oitMethod : enumeration [since 6.11]

Esta propiedad define el método de transparencia independiente del orden (OIT). Al establecer esta propiedad en un método OIT válido, el renderizador representa los píxeles transparentes en el orden de profundidad correcto.

Los valores posibles son:

ConstanteDescripción
SceneEnvironment.OITNoneLa OIT está desactivada.
SceneEnvironment.OITWeightedBlendedAproximación a la transparencia independiente del orden.
SceneEnvironment.OITLinkedListTransparencia independiente del orden precisa.

El valor por defecto es « None » y la transparencia independiente del orden está desactivada.

Mezclaponderada

Se trata de una aproximación a la transparencia independiente del orden. Los fragmentos transparentes se representan en un búfer fuera de pantalla, al tiempo que se aplica una ponderación a cada fragmento en función de su distancia a la cámara. A continuación, este búfer se fusiona con el búfer de fondo tras eliminar la ponderación de cada píxel. Este método no sigue la regla de composición «fuente sobre fondo» para todos los fragmentos y el resultado difiere del resultado correcto; sin embargo, funciona también en hardware más antiguo y es más rápido que otros métodos más rigurosos.

Listaenlazada

Se trata de una transparencia independiente del orden precisa. Los fragmentos transparentes se renderizan en una lista enlazada durante la pasada de renderizado, se ordenan por profundidad y se fusionan en la pasada de composición.

Nota: Es posible quela OIT no funcione con MSAA en dispositivos con GLES 3.1 o inferior. Se recomienda no utilizar MSAA si se desea utilizar la OIT en dichos dispositivos.

Nota: La transparencia independientedel orden solo es aplicable al modo de mezcla «source-over». Si la escena contiene objetos con otros modos de mezcla, la OIT queda desactivada.

Esta propiedad se introdujo en Qt 6.11.

probeExposure : real

Esta propiedad modifica la cantidad de luz que emite la sonda de luz. Parte del mapeo de tonos consiste en el mapeo de exposición, y esta propiedad ajusta cómo se aplica el mapeo de tonos a los valores de luz de las sondas de luz.

Por defecto, la exposición está establecida en 1,0

Nota: Esta propiedad no tiene ningún efecto cuando la opción « tonemapMode » está establecida en « SceneEnvironment.TonemapModeNone ».

Véase también « lightProbe », « probeHorizon » y « probeOrientation ».

probeHorizon : real

Esta propiedad, cuando se define con valores crecientes, añade oscuridad (negro) a la mitad inferior del entorno, lo que hace que la iluminación provenga predominantemente de la parte superior de la imagen (y elimina reflejos específicos de la mitad inferior). Esta propiedad resulta útil para tener en cuenta un plano de suelo que tendría el efecto de ocultar el reflejo de la sonda de luz desde el suelo. Esto es necesario porque las contribuciones de las sondas de luz provienen directamente de la imagen sin tener en cuenta el contenido de la escena.

El rango de valores esperado para la propiedad `probeHorizon` está entre 0,0 y 1,0. Cualquier valor fuera de este rango se ajustará al rango esperado.

Por defecto, `probeHorizon` está establecido en 0,0, lo que significa que se utiliza toda la sonda de luz sin ajustes.

Nota: La propiedad `probeHorizon` solo afecta a la iluminación de los materiales y no tiene ningún efecto sobre el renderizado del «sky box».

Véase también lightProbe, probeExposure y probeOrientation.

probeOrientation : vector3d

Esta propiedad define la orientación de la sonda de luz. La orientación se define mediante los ángulos de Euler, expresados en grados, respecto a los ejes x, y y z.

Nota: Este valor modifica la forma en que se muestrea la textura « lightProbe » en combinación con cualquier rotación y desplazamiento de textura establecidos en la textura « lightProbe ».

Véase también « lightProbe », « probeHorizon » y « probeExposure ».

scissorRect : rect [since 6.5]

Esta propiedad define un rectángulo de recorte en coordenadas de vista, con la esquina superior izquierda en [0, 0]

Esta propiedad se introdujo en Qt 6.5.

skyBoxCubeMap : QtQuick3D::CubeMapTexture [since 6.4]

Esta propiedad define un mapa cúbico que se utilizará como skybox cuando el modo de fondo sea « SkyBoxCubeMap ».

Esta propiedad se introdujo en Qt 6.4.

skyMaterial : QtQuick3D::SkyMaterial [since 6.12]

Esta propiedad define un modelo de cielo procedural generado por la GPU que se utiliza para IBL y como fondo de la escena.

Esta propiedad se introdujo en Qt 6.12.

Véase también backgroundMode y lightProbe.

skyboxBlurAmount : real [since 6.4]

Esta propiedad determina el grado de desenfoque que debe aplicarse al skybox cuando se utiliza « SceneEnvironment.SkyBox » para la propiedad « backgroundMode ». El valor por defecto es « 0.0 », lo que significa que no hay desenfoque.

Los valores válidos oscilan entre 0,0 y 1,0; cualquier otro valor se ajustará a este rango.

Esta propiedad se introdujo en Qt 6.4.

specularAAEnabled : bool [since 6.4]

Cuando esta propiedad está activada, se mitiga el aliasing especular. El aliasing especular suele ser visible en forma de puntos brillantes, que pueden parpadear al mover la cámara.

El valor por defecto es «false».

AA especular desactivadoAntialiasing especular activado

Escena arquitectónica en la que se aprecian reflejos especulares sin suavizado

Escena arquitectónica en la que se aprecian reflejos especulares suavizados con antialiasing

Esta propiedad se introdujo en Qt 6.4.

temporalAAEnabled : bool [default: false]

Cuando esta propiedad esté activada, se utilizará el antialiasing temporal.

La cámara se mueve muy ligeramente entre fotogramas, y el resultado de cada nuevo fotograma se fusiona con el fotograma anterior.

Nota: El antialiasingtemporal no tiene ningún efecto cuando « antialiasingMode » está configurado en MSAA.

Nota: Al utilizar ProgressiveAA, se aplica el antialiasing temporal durante la animación de la escena. Una vez que la escena se vuelve estática, ProgressiveAA toma el relevo, pero solo cuando « temporalAAMode » está configurado como « SceneEnvironment.TAADefault». En otras palabras: ProgressiveAA no tiene ningún efecto cuando « temporalAAMode » está configurado como « SceneEnvironment.TAAMotionVector».

Ventajas: gracias al movimiento de la cámara, detecta detalles reales que, de otro modo, se perderían; tiene un impacto reducido en el rendimiento.

Inconvenientes: Los objetos que se mueven rápidamente provocan un efecto fantasma de un fotograma.

Nota: El antialiasingtemporal no es compatible actualmente con el renderizado multivista y no debe utilizarse en aplicaciones de RV/RA.

temporalAAMode : enumeration [since 6.11]

Controla el modo de antialiasing temporal. El antialiasing temporal reduce el parpadeo y el efecto de aliasing al combinar la información de varios fotogramas.

ConstanteDescripción
SceneEnvironment.TAADefaultCombina el fotograma actual con el anterior para aplicar un filtrado temporal básico.
SceneEnvironment.TAAMotionVectorUtiliza vectores de movimiento para seguir el desplazamiento de los píxeles entre fotogramas, lo que proporciona una calidad superior en las escenas animadas.

El valor predeterminado es « SceneEnvironment.TAADefault ».

Nota: El AAtemporal puede provocar artefactos de «fantasma» con objetos que se mueven rápidamente o movimientos rápidos de la cámara.

Nota: Funciona mejor con frecuencias de fotogramas constantes. Las variaciones en la frecuencia de fotogramas reducen su eficacia.

Esta propiedad se introdujo en Qt 6.11.

temporalAAStrength : real [default: 0.3]

Esta propiedad modifica la intensidad del movimiento temporal (suavizado). Solo surte efecto cuando la propiedad « temporalAAEnabled » tiene el valor «true».

Véase también « temporalAAEnabled ».

tonemapMode : enumeration [since 6.0]

Esta propiedad define cómo se aplica el mapeo de tonos a los colores antes del renderizado. Todo el renderizado en Qt Quick 3D se realiza en un espacio de color lineal, lo que en muchos casos puede dar lugar a valores de color que no se pueden visualizar. El «tonemapMode» determina la técnica que se utiliza para reasignar los colores a un rango visualizable.

El valor por defecto es SceneEnvironment.TonemapModeLinear

ConstantDescripción
SceneEnvironment.TonemapModeNoneSe omite todo el mapeo de tonos. Este modo resulta útil al aplicar efectos de posprocesamiento.
SceneEnvironment.TonemapModeLinearSe aplica un mapeo de tonos lineal. Los colores se someten a una corrección gamma y se devuelven en el espacio de color sRGB.
SceneEnvironment.TonemapModeAcesSe aplica el mapeo de tonos del sistema de codificación de color Academy (ACES).
SceneEnvironment.TonemapModeHejlDawsonSe aplica el mapeo de tonos Hejl-Dawson.
SceneEnvironment.TonemapModeFilmicSe aplica el mapeo de tonos «Filmic».

Consulta ExtendedSceneEnvironment para ver un ejemplo de estos diferentes modos.

Nota: Al utilizar efectos de posprocesamiento, la mayoría de ellos esperan datos de color lineales sin mapeo de tonos. En el caso de los efectos personalizados proporcionados por la aplicación e implementados mediante el tipo ` Effect `, es importante saber que, a partir de Qt 6.5, los efectos pueden dar por hecho que funcionan con datos de color lineales, y que el mapeo de tonos se realiza automáticamente en la salida del último efecto de la cadena. Si es necesario personalizar completamente el mapeo de tonos, considere establecer el valor SceneEnvironment.TonemapModeNone para desactivar el mapeador de tonos integrado y, en su lugar, realice los ajustes adecuados en el valor del color en el último efecto de la cadena. Esto no se aplica a los efectos integrados de ExtendedSceneEnvironment, ya que estos se encargan automáticamente del mapeo de tonos adecuado, independientemente de la combinación de efectos integrados que esté habilitada en el entorno.

Esta propiedad se introdujo en Qt 6.0.

© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.