Qt Quick 3D - Ejemplo de extensión de niebla volumétrica
Muestra cómo implementar la niebla volumétrica en una extensión de renderizado.

Descripción general
Este ejemplo implementa la niebla volumétrica como una extensión de renderizado « Qt Quick » 3D render extension y muestra cómo reutilizar la extensión en tu propio proyecto.
La extensión divide el frustum de la cámara en una cuadrícula 3D de «froxels»(vóxeles alineados con el frustum) y utiliza un shader de cálculo para acumular la luz que se dispersa hacia la cámara en cada celda. A continuación, un efecto de posprocesamiento superpone el resultado sobre el fotograma renderizado.
Controles
Arrastra con el ratón para hacer girar la cámara alrededor de la escena. Utiliza el panel de configuración para modificar los ajustes de iluminación, niebla, posprocesamiento y sombras.
Implementación
Nota: La extensión inyecta luz en la malla de froxels mediante un sombreador de cálculo, por lo que requiere una API gráfica y hardware compatible con sombreadores de cálculo. Las versiones de OpenGL anteriores a la 4.3 y las de OpenGL ES anteriores a la 3.1 no admiten sombreadores de cálculo. Consulta QRhi::Compute para obtener más detalles.
El tipo « VolumetricFogExtension » implementa la extensión de niebla volumétrica. Se encuentra en el subproyecto independiente « VFExtension », por lo que puedes añadirlo a tu propio proyecto sin modificarlo.
Configure las siguientes propiedades en VolumetricFogExtension:
VolumetricFogExtension {
id: froxelExtension
froxelWidth: 160
froxelHeight: 96
froxelDepth: 96
nearPlane: 1.0
farPlane: 4000.0
fogVolumes: [ fogSphere ]
iesTexture: settings.iesLights ? iesAtlasTexture : null
iesCount: iesTextureData.sources.length
iesLightProfiles: [
IESLightProfileIndex { light: pinkSpot; index: settings.iesLightIndex; intensity: 0.5}
]
}Las propiedades froxelWidth, froxelHeight y froxelDepth definen la resolución de la malla de froxeles que rellena el shader de cálculo. Una resolución más alta produce una dispersión de la luz más detallada, pero consume más memoria de la GPU y tiempo de cálculo.
Las propiedades nearPlane y farPlane definen el rango de profundidad que cubre el efecto volumétrico. Deben coincidir con las distancias de recorte de PerspectiveCamera.
La propiedad « fogVolumes » contiene la lista de nodos « Fog3DVolume » que definen dónde está presente la niebla en la escena.
Perfiles de luz IES
Un perfil fotométrico de la Sociedad de Ingeniería de Iluminación (IES) determina la distribución angular de la luz de un foco. La propiedad « iesTexture » admite un « Texture » cuyos datos proceden de un objeto « IESTextureData ». Dicho objeto analiza archivos « .ies » y los empaqueta en una textura de atlas 2D. La propiedad « iesCount » especifica cuántos perfiles contiene el atlas, y « iesLightProfiles » asigna luces individuales a índices de perfil mediante objetos « IESLightProfileIndex ».
Texture {
id: iesAtlasTexture
textureData: IESTextureData {
id: iesTextureData
sources: [
"qrc:/assets/l0.ies",
"qrc:/assets/l1.ies",
"qrc:/assets/l2.ies",
"qrc:/assets/l3.ies",
"qrc:/assets/l4.ies",
"qrc:/assets/l5.ies",
]
}
tilingModeHorizontal: Texture.ClampToEdge
tilingModeVertical: Texture.ClampToEdge
minFilter: Texture.Linear
magFilter: Texture.Linear
generateMipmaps: false
}Cómo añadir la extensión a un View3D
Añade la extensión a la lista « extensions » del « View3D ». A continuación, el canal de renderizado invoca el shader de cálculo de la extensión una vez por fotograma:
View3D {
extensions: [ froxelExtension ]
}Volúmenes de niebla
Un nodo « Fog3DVolume » define una región de niebla en la escena. La propiedad « type » selecciona una de dos formas, « Fog3DVolume.Sphere » o « Fog3DVolume.Box », y la propiedad « extents » establece las dimensiones del contorno. Las propiedades « color » y « density » controlan el aspecto.
Al avanzar en noiseOffset en cada fotograma se anima el ruido. Para que la densidad disminuya con la altura, establece heightEnabled en true y ajusta leastIntenseY, mostIntenseY y heightCurve:
Fog3DVolume {
id: fogSphere
type: Fog3DVolume.Sphere
extents: Qt.vector3d(5000, 5000, 5000)
color: settings.fogVolumeColor
density: settings.fogVolumeDensity
noiseOffset: Qt.vector3d(baseNode.time * 0.1 * settings.fogSpeed,
baseNode.time * 0.02 * settings.fogSpeed,
baseNode.time * 0.01 * settings.fogSpeed)
noiseScale: settings.fogVolumeNoiseScale
heightEnabled: settings.fogVolumeHeightEnabled
leastIntenseY: settings.fogVolumeHeightLeastY
mostIntenseY: settings.fogVolumeHeightMostY
heightCurve: settings.fogVolumeHeightCurve
}VolumetricFogEffect
La extensión expone su resultado a través de la propiedad de solo lectura froxelTexture, una textura RGBA 3D que contiene los datos acumulados de dispersión de la luz para cada froxel. Añade el efecto de posprocesamiento VolumetricFogEffect a ExtendedSceneEnvironment para utilizar esa textura. El efecto realiza un recorrido de rayos a través de la textura de froxeles y superpone la luz volumétrica al fotograma renderizado:
effects: [
VolumetricFogEffect {
froxelTexture: froxelExtension.froxelTexture
cameraPosition: camera.scenePosition
cameraForward: camera.forward
invViewMatrix: camera.sceneTransform
marchSteps: froxelExtension.froxelDepth
nearPlane: froxelExtension.nearPlane
farPlane: froxelExtension.farPlane
frameBaseJitter: se.temporalAAEnabled &&
se.temporalAAMode === SceneEnvironment.TAAMotionVector &&
se.antialiasingMode !== SceneEnvironment.MSAA ? 1.0 : 0.0
jitterIntensity: settings.jitterIntensity
}
]La propiedad « marchSteps » controla el número de pasos del trazado de rayos. Ajústala a « froxelDepth ». Las propiedades « frameBaseJitter » y « jitterIntensity » habilitan el dithering temporal, lo que reduce los artefactos de bandas cuando la escena también utiliza antialiasing temporal.
Reutilización de la extensión en tu propio proyecto
El subproyecto « VFExtension » se compila como un módulo QML independiente. Para utilizarlo en otro proyecto, copia el directorio, añádelo con « add_subdirectory() » y vincula la biblioteca a tu proyecto de destino:
add_subdirectory(VFExtension)
target_link_libraries(myapp PRIVATE VFExtension)A continuación, importa el módulo en QML:
import VFExtensionNota: La extensión incluye encabezados 3D privados de Qt Quick y está enlazada con Qt6::Quick3DPrivate. La API privada no ofrece ninguna garantía de compatibilidad ni a nivel de código fuente ni de binarios, por lo que es posible que la extensión requiera modificaciones al pasar a una versión más reciente de Qt.
Véase también «Qt Quick 3D - Ejemplo de la extensión Stencil Outline», «Qt Quick 3D - Ejemplo de niebla sencilla» y «Pasos de renderizado definidos por el usuario en Qt Quick 3D».
© 2026 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.