WorkerScript QML Type

Qt Quick アプリケーションでスレッドの使用を有効にする。詳細...

• 継承されたメンバを含む全メンバのリスト

プロパティ

• ready : bool
• source : url

信号

• message(jsobject msg)

方法

• sendMessage(jsobject message)

詳しい説明

WorkerScriptを使用して、新しいスレッドで操作を実行します。これは、メインのGUIスレッドがブロックされないように、バックグラウンドで操作を実行するのに便利です。

メッセージは、sendMessage() とonMessage() ハンドラを使用して、新しいスレッドと親スレッドの間で渡すことができます。

例を挙げましょう：

import QtQuick

Rectangle {
    width: 300; height: 300

    Text {
        id: myText
        text: 'Click anywhere'
    }

    WorkerScript {
        id: myWorker
        source: "script.mjs"

        onMessage: (messageObject)=> myText.text = messageObject.reply
    }

    MouseArea {
        anchors.fill: parent
        onClicked: (mouse)=> myWorker.sendMessage({ 'x': mouse.x, 'y': mouse.y })
    }
}

上記のワーカースクリプトでは、新しいスレッドで実行される操作を処理する JavaScript ファイル "script.mjs" を指定しています。以下はscript.mjs です：

WorkerScript.onMessage = function(message) {
    // ... long-running operations and calculations are done here
    WorkerScript.sendMessage({ 'reply': 'Mouse is at ' + message.x + ',' + message.y })
}

ユーザーが矩形内のどこかをクリックすると、sendMessage() が呼び出され、script.mjs のWorkerScript.onMessage() ハンドラがトリガーされます。このメッセージは、myWorker のonMessage() ハンドラによって受信される。

この例では、".mjs "という拡張子を持つECMAScriptモジュールを使用している。このスクリプトはimport文を使って他のモジュールの機能にアクセスすることができ、JavaScriptのストリクトモードで実行されます。

ワーカースクリプトに ".js" という拡張子がある場合は、プレーンな JavaScript ステートメントが含まれているとみなされ、非厳密モードで実行されます。

制限事項

WorkerScript.onMessage() 関数は別スレッドで実行されるため、JavaScript ファイルはメインの QML エンジンとは別のコンテキストで評価されます。つまり、QMLに取り込まれる通常のJavaScriptファイルとは異なり、上記の例のscript.mjs はQMLアイテムのプロパティやメソッド、その他の属性にアクセスすることはできませんし、QQmlContext を通してQMLオブジェクトに設定されたコンテキストプロパティにアクセスすることもできません。

さらに、ワーカースクリプトとの間で受け渡しできる値のタイプにも制限があります。詳しくはsendMessage() のドキュメントを参照してください。

プレーンな JavaScript ソースであるワーカースクリプトは.import構文を使用できません。ECMAScript モジュールであるスクリプトは、import および export ステートメントを自由に使用できます。

プロパティ ドキュメント

シグナル・ドキュメント

メソッド ドキュメンテーション