Text QML Type

シーンに書式付きテキストを追加する方法を指定します。詳細...

• 継承されたメンバーを含む、すべてのメンバーの一覧
• 非推奨のメンバ

プロパティ

• advance : size
• antialiasing : bool
• baseUrl : url
• bottomPadding : real
• clip : bool
• color : color
• contentHeight : real
• contentWidth : real
• effectiveHorizontalAlignment : enumeration
• elide : enumeration
• font.bold : bool
• font.capitalization : enumeration
• font.contextFontMerging : bool (since 6.8)
• font.family : string
• font.features : object (since 6.6)
• font.hintingPreference : enumeration
• font.italic : bool
• font.kerning : bool
• font.letterSpacing : real
• font.pixelSize : int
• font.pointSize : real
• font.preferShaping : bool
• font.preferTypoLineMetrics : bool (since 6.8)
• font.strikeout : bool
• font.styleName : string
• font.underline : bool
• font.variableAxes : object (since 6.7)
• font.weight : int
• font.wordSpacing : real
• fontInfo.bold : bool
• fontInfo.family : string
• fontInfo.italic : bool
• fontInfo.pixelSize : int
• fontInfo.pointSize : real
• fontInfo.styleName : string
• fontInfo.weight : int
• fontSizeMode : enumeration
• horizontalAlignment : enumeration
• hoveredLink : string
• leftPadding : real
• lineCount : int
• lineHeight : real
• lineHeightMode : enumeration
• linkColor : color
• maximumLineCount : int
• minimumPixelSize : int
• minimumPointSize : int
• padding : real
• renderType : enumeration
• renderTypeQuality : int (since 6.0)
• rightPadding : real
• style : enumeration
• styleColor : color
• text : string
• textFormat : enumeration
• topPadding : real
• truncated : bool
• verticalAlignment : enumeration
• wrapMode : enumeration

信号

• lineLaidOut(object line)
• linkActivated(string link)
• linkHovered(string link)

方法

• void forceLayout()
• string linkAt(real x, real y)

詳細説明

テキスト項目には、プレーンテキストとリッチテキストの両方を表示できます。たとえば、次のように、特定のフォントやサイズで赤いテキストを定義できます:

Text {
    text: "Hello World!"
    font.family: "Helvetica"
    font.pointSize: 24
    color: "red"
}

リッチテキストを定義するには、HTML形式のマークアップまたはMarkdownを使用します：

Text {
    text: "<b>Hello</b> <i>World!</i>"
}

Text {
    text: "**Hello** *World!*"
}

高さと幅が明示的に設定されていない場合、Textは必要なスペースを判断し、それに応じて設定しようとします。wrapMode が設定されていない限り、高さの代わりに幅を優先します（すべてのテキストが1行に収められます）。

1行のプレーンテキストを指定された幅に収めるには、elide プロパティを使用できます。

Textは読み取り専用のテキストを提供します。編集可能なテキストについては、TextEdit を参照してください。

「フォント」の例も参照してください 。

プロパティのドキュメント

advance : size [read-only]

テキスト項目の最初の文字のベースライン原点から、テキストフローにおいてその直後に続くテキスト項目の最初の文字のベースライン原点までの距離（ピクセル単位）。

なお、テキストが右から左へ流れる場合、この進み量は負の値になることがある。

antialiasing : bool

テキストにアンチエイリアシングを適用するかどうかを決定するために使用されます。renderType が Text.NativeRendering に設定されているテキストのみ、アンチエイリアシングを無効にすることができます。

デフォルトはtrue です。

baseUrl : url

このプロパティは、テキスト内の相対URLを解決するために使用されるベースURLを指定します。

URLは、ベースURLのターゲットと同じディレクトリ内にあるものとして解決されるため、最後の「/」以降のパス部分はすべて無視されます。

デフォルト値は、Textアイテムをインスタンス化するQMLファイルのURLです。

これらのプロパティは、コンテンツの周囲のパディングを指定します。このスペースは、contentWidth およびcontentHeight に加えて確保されます。

clip : bool

このプロパティは、テキストがクリップされているかどうかにかかわらず有効です。

なお、テキストが境界矩形に収まらない場合、テキストは不自然に切り詰められてしまいます。

限られたスペースに長くなる可能性のあるテキストを表示したい場合は、代わりにelide を使用することをお勧めします。

color : color

テキストの色。

16進数表記を使用して定義された緑色のテキストの例：

Text {
    color: "#00FF00"
    text: "green text"
}

SVGの色名を使用して定義されたスチールブルーのテキストの例：

Text {
    color: "steelblue"
    text: "blue text"
}

contentHeight : real [read-only]

テキストの高さを返します。これには、設定された高さに収まりきらないテキストがあるために覆い隠された部分を超える高さも含まれます。

contentWidth : real [read-only]

textの幅を返します。WrapModeが設定されている場合、改行不足によってカバーされる幅を超えた部分も含みます。

「テキスト」項目の幅と高さの範囲内で、テキストの水平および垂直方向の配置を設定します。デフォルトでは、テキストは垂直方向に上揃えになります。水平方向の配置は、テキストの自然な配置に従います。たとえば、左から右に読むテキストは左揃えになります。

horizontalAlignment の有効な値は、Text.AlignLeft 、Text.AlignRight 、Text.AlignHCenter 、Text.AlignJustify です。verticalAlignment の有効な値は、Text.AlignTop 、Text.AlignBottom 、Text.AlignVCenter です。

なお、テキストが 1 行のみの場合、テキストのサイズはテキストの領域そのものとなります。この一般的なケースでは、すべての配置は同等です。たとえば、テキストを親要素の中央に配置したい場合は、Item::anchors を変更するか、horizontalAlignment を Text.AlignHCenter に設定し、幅を親要素の幅にバインドする必要があります。

添付プロパティLayoutMirroring::enabled を使用してアプリケーションのレイアウトをミラーリングする場合、テキストの水平方向の配置もミラーリングされます。ただし、horizontalAlignment プロパティは変更されません。Textの実際の水平方向の配置を取得するには、読み取り専用プロパティeffectiveHorizontalAlignment を使用してください。

elide : enumeration

このプロパティを設定すると、テキストの一部が「Text」項目の幅に合わせて省略されます。テキストが省略されるのは、明示的に幅が設定されている場合のみです。

このプロパティは、Text.PlainText およびText.StyledText 形式で機能しますが、Text.RichText またはText.MarkdownText 形式では使用できません。

省略の値は次の通りです：

このプロパティが Text.ElideRight に設定されている場合、wrapped テキストで使用できます。テキストの省略は、maximumLineCount またはheight が設定されている場合にのみ行われます。maximumLineCount とheight の両方が設定されている場合、行が許容される高さ内に収まらない場合を除き、maximumLineCount が適用されます。

テキストが複数長文字列であり、モードが `Text.ElideNone` でない場合、収まる最初の文字列が使用され、そうでない場合は最後の文字列が省略されます。

複数の長さの文字列は、長いものから短いものの順に並べられ、Unicodeの「文字列終端子」文字U009C で区切られます（QMLでは、"\u009C" または"\x9C" と記述します）。

font.bold : bool

フォントの太さを太字にするかどうかを設定します。

font.capitalization : enumeration

テキストの大文字小文字の設定を行います。

Text { text: "Hello"; font.capitalization: Font.AllLowercase }

font.contextFontMerging : bool [since 6.8]

選択したフォントに特定の文字が含まれていない場合、Qt はその文字を含む、見た目が似ている代替フォントを自動的に選択します。デフォルトでは、これは文字単位で行われます。

つまり、ごくまれなケースでは、たとえ同じ文字体系であっても、1つの文字列を表現するために多くの異なるフォントが使用される可能性があります。contextFontMerging をtrueに設定すると、代わりに、入力文字列の最大の部分集合と一致するフォールバックフォントが検索されるようになります。これは、欠落しているグリフがある文字列では処理負荷が高くなりますが、より一貫性のある結果が得られる可能性があります。 デフォルトでは、contextFontMerging はfalse です。

このプロパティは Qt 6.8 で導入されました。

QFont::StyleStrategyも参照してください 。

font.family : string

フォントのファミリー名を設定します。

ファミリー名は大文字と小文字を区別せず、必要に応じてフォントメーカー名を含めることもできます（例：「Helvetica [Cronyx]」）。 そのフォントファミリーが複数のフォントメーカーから提供されており、フォントメーカーが指定されていない場合は、任意のフォントメーカーが選択されます。そのフォントファミリーが利用できない場合は、フォントマッチングアルゴリズムを使用してフォントファミリーが設定されます。

font.features : object [since 6.6]

テキストの内容に基づいてテキストの形状を調整する際、特定の OpenType 機能に整数値を適用します。これにより、フォントの形状調整プロセスへの高度なアクセスが可能となり、API では通常サポートされていないフォント機能をサポートするために利用できます。

フォント機能は、4文字のタグから整数値へのマッピングによって表されます。ほとんどの場合、タグとともに渡されるこの整数値はブール値を表します。つまり、値が 0 の場合は機能が無効であり、0 以外の値の場合は有効であることを意味します。ただし、特定のフォント機能については、異なる解釈が適用される場合があります。 たとえば、「salt 」機能に適用する場合、その値は使用するスタイルの代替案を指定するインデックスとなります。

例えば、「frac 」フォント機能では、スラッシュで区切られた斜体分数（1/2 など）を、異なる表現に変換します。通常、これは分数全体を単一の文字幅に収めることを意味します（½ など）。

フォントがfrac 機能をサポートしている場合、以下のコードのようにシェイパーで有効にすることができます：

Text {
    text: "One divided by two is 1/2"
    font.family: "MyFractionFont"
    font.features: { "frac": 1 }
}

同じマッピング内で複数の機能に値を割り当てることができます。たとえば、そのフォントのカーニングも無効にしたい場合は、次のように明示的に無効にすることができます：

Text {
    text: "One divided by two is 1/2"
    font.family: "MyFractionFont"
    font.features: { "frac": 1, "kern": 0 }
}

また、フォントのプロパティを 1 つのオブジェクトにまとめて取得することもできます：

Text {
    text: "One divided by two is 1/2"
    font: {
        family: "MyFractionFont"
        features: { "frac": 1, "kern": 0 }
    }
}

dlig、hlig ）は、font.letterSpacing が設定されている場合、無効化されますが、これは合字の使用が装飾的な目的のみである文字体系に限られます。合字が必須である文字体系では、これらの機能はデフォルトの状態のまま維持されます。font.features を使用して設定された値は、デフォルトの挙動を上書きします。例えば、"kern" が1に設定されている場合、font::kerning プロパティがfalseに設定されているかどうかに関係なく、カーニングは常に有効になります。同様に、

0 に設定された場合、カーニングは常に無効になります。

このプロパティは Qt 6.6 で導入されました。

QFont::setFeature()も参照してください 。

font.hintingPreference : enumeration

テキストに推奨されるヒンティングを設定します。

これは、基盤となるテキストレンダリングシステムに対して特定のレベルのヒンティングを使用するよう指示するものであり、プラットフォームによってサポート状況が異なります。詳細については、QFont::HintingPreference のドキュメントにある表を参照してください。

Text { text: "Hello"; renderType: Text.NativeRendering; font.hintingPreference: Font.PreferVerticalHinting }

font.italic : bool

そのフォントにイタリック体があるかどうかを設定します。

font.kerning : bool

テキストの整形時に、カーニングのOpenType機能を有効または無効にします。これを無効にすると、テキストの作成や変更時のパフォーマンスが向上する場合がありますが、その代わりに一部の視覚的な機能が犠牲になります。デフォルト値はtrue です。

Text { text: "OATS FLAVOUR WAY"; font.kerning: false }

font.letterSpacing : real

フォントの文字間隔を設定します。

文字間隔を設定すると、フォント内の個々の文字間のデフォルトの間隔が変更されます。正の値を設定すると、文字間隔が対応するピクセル分だけ広がり、負の値を設定すると狭くなります。

font.pixelSize : int

フォントサイズをピクセル単位で設定します。

この関数を使用すると、フォントはデバイス依存になります。デバイス非依存の方法でフォントサイズを設定するには、pointSize を使用してください。

font.pointSize : real

フォントサイズをポイント単位で設定します。ポイントサイズは 0 より大きくなければなりません。

font.preferShaping : bool

フォントによっては、文字を正しく表示するために、一連の文字に対して複雑なルールを適用することがあります。 ブラフミー文字系などの一部の文字体系では、テキストを読みやすくするためにこれが必須ですが、例えばラテン文字系では、これは単なる装飾的な機能に過ぎません。preferShaping プロパティをfalseに設定すると、必要のない場合にこうした機能をすべて無効にすることができ、ほとんどの場合、パフォーマンスが向上します。

デフォルト値は `true` です。

Text { text: "Some text"; font.preferShaping: false }

font.preferTypoLineMetrics : bool [since 6.8]

フォントのascent 、descent 、leading を提供する、互いに競合する一連の垂直線メトリック。これらは、しばしば「win（Windows）メトリック」と「typo（タイポグラフィ）メトリック」と呼ばれます。 仕様では行間隔にtypo メトリクスの使用を推奨していますが、多くのアプリケーションでは、フォントのfsSelectionフィールドに USE_TYPO_METRICS フラグが設定されていない限り、win メトリクスを優先します。下位互換性の理由から、Qtアプリケーションでも同様です。 これは、USE_TYPO_METRICS フラグを設定してtypo メトリクスの有効性を示しているフォントや、win メトリクスとtypo メトリクスが一致しているフォントについては問題になりません。しかし、一部のフォントでは、win メトリクスが望ましい行間よりも大きくなっていたり、USE_TYPO_METRICS フラグが誤って設定されていない場合があります。そのようなフォントでは、font.preferTypoLineMetrics を設定することで、より良い結果が得られる可能性があります。

デフォルトでは、preferTypoLineMetrics はfalse に設定されています。

このプロパティはQt 6.8で導入されました。

「QFont::StyleStrategy」も参照してください 。

font.strikeout : bool

そのフォントに打ち消し線スタイルがあるかどうかを設定します。

font.styleName : string

フォントのスタイル名を設定します。

スタイル名の大文字小文字は区別されません。設定すると、フォントはfont.weight 、font.bold 、font.italic といったフォントプロパティではなく、スタイル名に基づいて照合されます。

font.underline : bool

テキストに下線を引くかどうかを設定します。

font.variableAxes : object [since 6.7]

可変フォントの可変軸に浮動小数点値を適用します。

可変フォントは、同じフォントファイル内に複数のバリエーション（太さ、幅、スタイルが異なるもの）を格納する方法を提供します。これらのバリエーションは、「可変軸」と呼ばれる事前定義されたパラメータセットに対する浮動小数点値として指定されます。 特定のインスタンスには通常、フォントデザイナーによって名前が付けられており、Qt では、従来のサブファミリーと同様に setStyleName() を使用してこれらを選択できます。

場合によっては、さまざまな軸に任意の値を指定することも有用です。たとえば、フォントに「Regular」と「Bold」のサブファミリーがある場合、その中間のウェイトが必要になることがあります。その場合は、フォントの「wght」軸にカスタム値を指定することで、手動でこれを要求することができます。

Text {
    text: "Foobar"
    font.family: "MyVariableFont"
    font.variableAxes: { "wght": (Font.Normal + Font.Bold) / 2.0 }
}

フォントが「wght」軸をサポートしており、指定された値がその定義された範囲内にある場合、ウェイト 550.0 に対応するフォントが提供されます。

多くのフォントが提供する標準的な軸として、「wght」（ウェイト）、「wdth」（幅）、「ital」（イタリック）、「opsz」（光学サイズ）などがあります。これらはそれぞれ、フォント自体で個別の範囲が定義されています。 たとえば、「wght」の範囲は 100 から 900（QFont::Thin からQFont::Black ）であるのに対し、「ital」の範囲は 0 から 1（イタリックなしから完全なイタリック）である場合があります。

フォントはカスタム軸を定義することも可能です。唯一の制限は、その名前がQFont::Tag の要件（4文字のLatin-1文字のシーケンス）を満たしている必要があることです。

デフォルトでは、可変軸は設定されていません。

このプロパティは Qt 6.7 で導入されました。

QFont::setVariableAxis()も参照してください 。

font.weight : int

指定するフォントのウェイト。指定するウェイトは、1 から 1000 までの整数、または以下の事前定義された値のいずれかでなければなりません。

Text { text: "Hello"; font.weight: Font.DemiBold }

font.wordSpacing : real

フォントの単語間隔を設定します。

単語間隔を設定すると、個々の単語間のデフォルトの間隔が変更されます。正の値を指定すると、単語間隔が指定したピクセル数だけ広がり、負の値を指定すると、それに応じて単語間隔が狭くなります。

fontInfo.bold : bool [read-only]

現在のフォントおよびfontSizeMode に対して解決済みのフォント情報の太字の状態。解決済みのフォントのウェイトが「太字」以上である場合にtrueとなります。

fontInfo.family : string [read-only]

現在のフォントおよびfontSizeMode に対して解決されたフォントのファミリー名。

fontInfo.italic : bool [read-only]

現在のフォントおよびfontSizeMode に対して解決済みのフォント情報のイタリック表示の状態。

fontInfo.pixelSize : int [read-only]

現在のフォントおよびfontSizeMode に対して解決されたフォント情報のピクセルサイズ。

fontInfo.pointSize : real [read-only]

現在のフォントおよびfontSizeMode に対して解決されたフォント情報のpointSize。

fontInfo.styleName : string [read-only]

現在のフォントおよびfontSizeMode に対して解決されたフォント情報のスタイル名。

fontInfo.weight : int [read-only]

現在のフォントおよびfontSizeMode に対して解決済みのフォント情報の重み。

fontSizeMode : enumeration

このプロパティは、表示されるテキストのフォントサイズがどのように決定されるかを指定します。取り得る値は次のとおりです。

収まるテキストのフォントサイズには、minimumPointSize またはminimumPixelSize プロパティで指定された最小値と、font.pointSize またはfont.pixelSize プロパティで指定された最大値があります。

Text { text: "Hello"; fontSizeMode: Text.Fit; minimumPixelSize: 10; font.pixelSize: 72 }

最小フォントサイズでもテキストが項目の境界内に収まらない場合、elide プロパティに従ってテキストが省略されます。

textFormat プロパティがText.RichText に設定されている場合、このプロパティは完全に無視されるため、まったく効果がありません。textFormat がText.StyledText に設定されている場合、テキスト内にフォントサイズタグが存在しない限り、このプロパティが適用されます。フォントサイズタグが存在する場合でも、このプロパティはそれらのタグを優先します。これにより、fontSizeModeの設定に完全に準拠しない場合があります。

hoveredLink : string [read-only]

このプロパティには、ユーザーがテキスト内に埋め込まれたリンクにカーソルを合わせた際のリンク文字列が含まれます。リンクはリッチテキストまたはHTML形式である必要があり、hoveredLink という文字列によってその特定のリンクにアクセスできます。

「 linkHovered 」および「linkAt()」も参照してください 。

lineCount : int [read-only]

テキスト項目内で表示されている行数を返します。

このプロパティはリッチテキストではサポートされていません。

「maximumLineCount」も参照してください 。

lineHeight : real

テキストの行高を設定します。値は、lineHeightMode の設定に応じて、ピクセル単位または倍率で指定できます。

デフォルト値は乗数 1.0 です。行高は正の値でなければなりません。

lineHeightMode : enumeration

このプロパティは、行の高さをどのように指定するかを決定します。指定可能な値は次のとおりです：

linkColor : color

テキスト内のリンクの色。

このプロパティは、StyledTexttextFormat では機能しますが、RichText では機能しません。RichText におけるリンクの色は、テキスト内に CSS スタイルタグを含めることで指定できます。

maximumLineCount : int

このプロパティを設定すると、テキスト項目に表示される行数を制限できます。elide が Text.ElideRight に設定されている場合、テキストは適切に省略されます。デフォルトでは、これは可能な限り最大の整数の値になります。

このプロパティはリッチテキストではサポートされていません。

lineCount およびelideも参照してください 。

minimumPixelSize : int

このプロパティは、fontSizeMode プロパティによって拡大縮小されたテキストの最小フォントピクセルサイズを指定します。

fontSizeMode がText.FixedSizeの場合、またはfont.pixelSize が-1の場合、このプロパティは無視されます。

minimumPointSize : int

このプロパティは、fontSizeMode プロパティによって拡大・縮小されたテキストの最小フォントポイントsize を指定します。

fontSizeMode がText.FixedSizeの場合、またはfont.pointSize が-1の場合、このプロパティは無視されます。

renderType : enumeration

このコンポーネントのデフォルトのレンダリングタイプを上書きします。

サポートされているレンダリングタイプは以下の通りです：

ターゲットプラットフォーム上でテキストをネイティブに表示したい場合、かつテキストの変形などの高度な機能を必要としない場合は、Text.NativeRendering を選択してください。NativeRendering レンダリングタイプと組み合わせてこれらの機能を使用すると、品質が低下し、場合によってはピクセル化された結果になることがあります。

Text.QtRendering とText.CurveRendering はどちらもハードウェアアクセラレーション技術です。QtRendering の方が高速ですが、メモリを多く消費し、大きなサイズではレンダリング上の不具合が生じることがあります。QtRendering で良好な視覚的結果が得られない場合や、グラフィックスメモリの消費量を抑えることが優先される場合は、CurveRendering を代替手段として検討すべきです。

デフォルトのレンダリングタイプは、QQuickWindow::textRenderType() によって決定されます。

renderTypeQuality : int [since 6.0]

このコンポーネントのデフォルトのレンダリング品質を上書きします。これは低レベルのカスタマイズであり、ほとんどの場合は無視して構いません。現在、この設定が効果を発揮するのは、renderType がText.QtRendering に設定されている場合のみです。

Text.QtRendering で使用されるラスタライズアルゴリズムでは、テキストサイズが大きい場合に、鋭い角が本来よりも丸く見えるなどのアーティファクトが発生する可能性があります。特定のテキスト項目でこれが問題となる場合は、renderTypeQuality の値を大きくすることでレンダリング品質を向上させることができますが、その代償としてメモリ消費量が増加します。

renderTypeQuality には、0 より大きい任意の整数、または以下の事前定義された値のいずれかを指定できます。

このプロパティは Qt 6.0 で導入されました。

style : enumeration

追加のテキストスタイルを設定します。

サポートされているテキストスタイルは以下の通りです：

Row {
    Text { font.pointSize: 24; text: "Normal" }
    Text { font.pointSize: 24; text: "Raised"; style: Text.Raised; styleColor: "#AAAAAA" }
    Text { font.pointSize: 24; text: "Outline";style: Text.Outline; styleColor: "red" }
    Text { font.pointSize: 24; text: "Sunken"; style: Text.Sunken; styleColor: "#AAAAAA" }
}

styleColor : color

テキストスタイルで使用される補助色を定義します。

styleColor これは、輪郭付きテキストの輪郭色として、また浮き出しテキストや凹みテキストの影色として使用されます。スタイルが設定されていない場合は、まったく使用されません。

Text { font.pointSize: 18; text: "hello"; style: Text.Raised; styleColor: "gray" }

「style」も参照してください 。

text : string

表示するテキスト。テキストには、プレーンテキストとリッチテキストの両方が使用可能です。

このアイテムは、テキストをスタイル付きテキストとして扱うべきかどうかを自動的に判断しようとします。この判断はQt::mightBeRichText() を使用して行われます。ただし、Markdown の検出は自動では行われません。

textFormatも参照してください 。

textFormat : enumeration

text プロパティの表示方法。

サポートされているテキスト形式は以下の通りです：

テキスト形式がText.AutoText の場合、「テキスト」項目は、そのテキストをスタイル付きテキストとして扱うべきかどうかを自動的に判断します。この判断はQt::mightBeRichText() を使用して行われます。この関数は、テキストの最初の行にHTMLタグが存在するかどうかを検出できますが、Markdownとプレーンテキストを区別することはできません。

Text.StyledText は、HTML 3.2のスタイルに準拠した、基本的なテキスト書式設定マークアップをサポートする最適化されたフォーマットです：

<b></b> - bold
<del></del> - strike out (removed content)
<s></s> - strike out (no longer accurate or no longer relevant content)
<strong></strong> - bold
<i></i> - italic
<br> - new line
<p> - paragraph
<u> - underlined text
<font color="color_name" size="1-7"></font>
<h1> to <h6> - headers
<a href=""> - anchor
<img src="" align="top,middle,bottom" width="" height=""> - inline images
<ol type="">, <ul type=""> and <li> - ordered and unordered lists
<pre></pre> - preformatted
All entities

Text.StyledText パーサーは厳格であり、タグが正しくネストされていることを要求します。

Column {
    Text {
        font.pointSize: 24
        text: "<b>Hello</b> <i>World!</i>"
    }
    Text {
        font.pointSize: 24
        textFormat: Text.RichText
        text: "<b>Hello</b> <i>World!</i>"
    }
    Text {
        font.pointSize: 24
        textFormat: Text.PlainText
        text: "<b>Hello</b> <i>World!</i>"
    }
    Text {
        font.pointSize: 24
        textFormat: Text.MarkdownText
        text: "**Hello** *World!*"
    }
}

Text.RichText は、「サポートされているHTMLサブセット」ページに記載されているように、HTML 4のより広範なサブセットをサポートしています。パフォーマンスが向上するため、代わりにText.PlainText 、Text.StyledText 、またはText.MarkdownText の使用を推奨します。

• コードブロックはdefault monospace font を使用しますが、周囲を囲むハイライトボックスは表示されません
• ブロック引用はインデントされますが、引用文の横に縦線は表示されません

truncated : bool [read-only]

maximumLineCount またはelide によりテキストが切り詰められている場合、true を返します。

このプロパティは、リッチテキストではサポートされていません。

「 maximumLineCount 」および「elide 」も参照してください 。

wrapMode : enumeration

このプロパティを設定すると、テキストが「Text」項目の幅に合わせて折り返されます。テキストが折り返されるのは、明示的に幅が設定されている場合のみです。wrapMode には、以下のいずれかを指定できます。

Signal ドキュメント

lineLaidOut(object line)

このシグナルは、プレーンテキストモードまたはスタイル付きテキストモードでのレイアウト処理中に、テキストの各行がレイアウトされるたびに発火します。リッチテキストモードでは発火しません。指定されたline オブジェクトは、現在レイアウトされている行に関する詳細情報を提供します。

これにより、行のレイアウト処理中にその行の位置やサイズを調整することが可能になります。例えば、列を作成したり、オブジェクトの周囲にテキストを配置したりするために使用できます。

指定されたline オブジェクトのプロパティは以下の通りです：

たとえば、次のコードは Text アイテムの最初の 5 行を 100 ピクセル右にずらします:

onLineLaidOut: (line)=> {
    if (line.number < 5) {
        line.x = line.x + 100
        line.width = line.width - 100
    }
}

次の例では、アイテムを最後の行の末尾に配置することができます:

onLineLaidOut: (line)=> {
    if (line.isLast) {
        lastLineMarker.x = line.x + line.implicitWidth
        lastLineMarker.y = line.y + (line.height - lastLineMarker.height) / 2
    }
}

linkActivated(string link)

このシグナルは、ユーザーがテキスト内に埋め込まれたリンクをクリックしたときに発火します。リンクはリッチテキストまたはHTML形式である必要があり、link という文字列によってその特定のリンクにアクセスできます。

    Text {
            textFormat: Text.RichText
            text: "See the <a href=\"http://qt-project.org\">Qt Project website</a>."
            onLinkActivated: (link)=> console.log(link + " link activated")
    }

サンプルコードでは、「Qt Project のウェブサイトをご覧ください」というテキストが表示されます。

強調表示されたリンクをクリックすると、コンソールにhttp://qt-project.org link activated が出力されます。

linkHovered(string link)

このシグナルは、ユーザーがテキスト内に埋め込まれたリンクにカーソルを合わせると発生します。リンクはリッチテキストまたはHTML形式である必要があり、link という文字列によってその特定のリンクにアクセスできます。

「 hoveredLink 」および「linkAt()」も参照してください 。

メソッドのドキュメント

void forceLayout()

表示されているテキストの再レイアウトを実行します。

string linkAt(real x, real y)

ポイントx 、コンテンツ座標y にあるリンク文字列を返します。そのポイントにリンクが存在しない場合は、空の文字列を返します。

hoveredLinkも参照してください 。