Loader QML Type

如果加载器当前处于活动状态，则该属性为true 。此属性的默认值为true 。

如果加载器处于非活动状态，更改source 或sourceComponent 将不会导致项目被实例化，直到加载器被激活。

将该值设置为非活动状态将导致加载器加载的任何item 被释放，但不会影响source 或sourceComponent 。

非活动加载器的status 始终是Null 。

另请参阅 source 和sourceComponent 。

该属性表示组件是否会被异步实例化。默认情况下，它是false 。

与source 属性结合使用时，加载和编译也将在后台线程中执行。

异步加载会在多个帧中创建组件声明的对象，从而降低动画出现闪烁的可能性。异步加载时，状态将变为 Loader.Loading。整个组件创建完成后，item ，状态将变为 Loader.Ready。

当异步加载正在进行时，将此属性的值更改为false 将强制立即同步完成。如果必须在异步加载完成前访问加载器内容，则可以先开始异步加载，然后强制完成加载。

为避免看到项目逐步加载，可适当设置visible ，例如

Loader {
    source: "mycomponent.qml"
    asynchronous: true
    visible: status == Loader.Ready
}

请注意，该属性只影响对象的实例化；它与通过网络异步加载组件无关。

该属性保存当前加载的顶层对象。

自QtQuick 2.0 起，Loader 可以加载任何对象类型。

该属性显示从网络加载 QML 数据的进度，从 0.0（未加载）到 1.0（已完成）。大多数 QML 文件都很小，因此该值会从 0 迅速变为 1。

另请参阅 status 。

该属性包含要实例化的 QML 组件的 URL。

自QtQuick 2.0 起，Loader 可以加载任何类型的对象；它并不局限于 Item 类型。

要卸载当前加载的对象，可将此属性设为空字符串，或将sourceComponent 设为undefined 。将source 设为新的 URL 也会导致卸载由前一个 URL 创建的项。

另请参阅 sourceComponent,status, 和progress 。

该属性包含要实例化的Component 。

Item {
    Component {
        id: redSquare
        Rectangle { color: "red"; width: 10; height: 10 }
    }

    Loader { sourceComponent: redSquare }
    Loader { sourceComponent: redSquare; x: 10 }
}

要卸载当前加载的对象，请将此属性设置为undefined 。

自QtQuick 2.0 起，Loader 可以加载任何类型的对象；它并不局限于 Item 类型。

另请参阅 source 和progress 。

此属性表示 QML 加载的状态。它可以是

• Loader.Null - 加载器处于非活动状态或未设置 QML 源
• Loader.Ready - QML 源已加载
• Loader.Loading - 当前正在加载 QML 源
• Loader.Error - 加载 QML 源时发生错误

使用此状态提供更新或以某种方式回应状态变化。例如，您可以

• 触发状态变化：

  State { name: 'loaded'; when: loader.status == Loader.Ready }
• 实现onStatusChanged 信号处理器：

  Loader {
      id: loader
      onStatusChanged: if (loader.status == Loader.Ready) console.log('Loaded')
  }
• 绑定状态值：

  Text { text: loader.status == Loader.Ready ? 'Loaded' : 'Not loaded' }

请注意，如果源文件是本地文件，初始状态将是 Ready（或 Error）。虽然在这种情况下不会出现 onStatusChanged 信号，但仍会调用 onLoaded 信号。

另请参阅 progress 。

当status 变为Loader.Ready 或初始加载成功时，将发出该信号。

创建给定source 组件的对象实例，该实例将具有给定的properties 。properties 参数为可选参数。加载和实例化完成后，可通过item 属性访问该实例。

如果调用此函数时active 属性为false ，则不会加载给定的source 组件，但会缓存source 和初始properties 。当加载器变成active 时，将创建一个设置了初始properties 的source 组件实例。

以这种方式设置组件实例的初始属性值不会触发任何相关的Behavior。

请注意，如果在调用此函数后但在设置加载器active 之前更改了source 或sourceComponent ，缓存的properties 将被清除。

示例

// ExampleComponent.qml
import QtQuick 2.0
Rectangle {
    id: rect
    color: "red"
    width: 10
    height: 10

    Behavior on color {
        NumberAnimation {
            target: rect
            property: "width"
            to: (rect.width + 20)
            duration: 0
        }
    }
}

// example.qml
import QtQuick 2.0
Item {
    Loader {
        id: squareLoader
        onLoaded: console.log(squareLoader.item.width);
        // prints [10], not [30]
    }

    Component.onCompleted: {
        squareLoader.setSource("ExampleComponent.qml",
                             { "color": "blue" });
        // will trigger the onLoaded code when complete.
    }
}

另见 source 和active 。