Pane QML Type

Bietet einen Hintergrund, der zum Stil und Thema der Anwendung passt. Mehr...

• Liste aller Mitglieder, einschließlich geerbter Mitglieder

Eigenschaften

• contentChildren : list<Item>
• contentData : list<QtObject>
• contentHeight : real
• contentWidth : real

Ausführliche Beschreibung

Pane bietet eine Hintergrundfarbe, die zum Stil und Thema der Anwendung passt. Der Bereich bietet kein eigenes Layout, sondern erfordert die Positionierung seines Inhalts, z. B. durch Erstellen eines RowLayout oder eines ColumnLayout.

Elemente, die als Kinder eines Fensters deklariert sind, werden automatisch dem contentItem des Fensters zugeordnet. Dynamisch erstellte Elemente müssen explizit dem contentItem zugeordnet werden.

Wie in Event Handling erwähnt, lässt Pane keine Klick- und Berührungsereignisse zu den darunter liegenden Elementen durch. Wenn wheelEnabled true ist, gilt dies auch für Mausrad-Ereignisse.

Größenanpassung des Inhalts

Wenn nur ein einzelnes Element in einem Fenster verwendet wird, passt es sich an die implizite Größe des enthaltenen Elements an. Dies macht es besonders geeignet für die Verwendung in Verbindung mit Layouts.

Pane {
    ColumnLayout {
        anchors.fill: parent
        CheckBox { text: qsTr("E-mail") }
        CheckBox { text: qsTr("Calendar") }
        CheckBox { text: qsTr("Contacts") }
    }
}

Manchmal gibt es aber auch zwei Elemente innerhalb des Bereichs:

Pane {
    SwipeView {
        // ...
    }
    PageIndicator {
        anchors.horizontalCenter: parent.horizontalCenter
        anchors.bottom: parent.bottom
    }
}

In diesem Fall kann Pane keine sinnvolle implizite Größe berechnen. Da wir die PageIndicator über der SwipeView verankern, können wir die Inhaltsgröße einfach auf die implizite Größe der Ansicht setzen:

Pane {
    contentWidth: view.implicitWidth
    contentHeight: view.implicitHeight

    SwipeView {
        id: view
        // ...
    }
    PageIndicator {
        anchors.horizontalCenter: parent.horizontalCenter
        anchors.bottom: parent.bottom
    }
 }

Wenn die contentItem keine implizite Größe und nur ein Kind hat, verwendet Pane die implizite Größe dieses Kindes. Im folgenden Code zum Beispiel nimmt das Fenster die Größe des Rechtecks an:

Pane {
    Item {
        Rectangle {
            implicitWidth: 200
            implicitHeight: 200
            color: "salmon"
        }
    }
}

Siehe auch Pane anpassen, Container Controls, Fokusmanagement in Qt Quick Controls und Event Handling.

Dokumentation der Eigenschaft

contentChildren : list<Item>

Diese Eigenschaft enthält die Liste der untergeordneten Elemente des Inhalts.

Die Liste enthält alle Elemente, die in QML als untergeordnete Objekte des Fensters deklariert wurden.

Siehe auch Item::children und contentData.

contentData : list<QtObject> [default]

Diese Eigenschaft enthält die Liste der Inhaltsdaten.

Die Liste enthält alle Objekte, die in QML als Kinder des Fensters deklariert wurden.

Siehe auch Item::data und contentChildren.

contentHeight : real

Diese Eigenschaft enthält die Höhe des Inhalts. Sie wird für die Berechnung der impliziten Gesamthöhe des Fensters verwendet.

Für weitere Informationen siehe Content Sizing.

Siehe auch contentWidth.

contentWidth : real

Diese Eigenschaft enthält die Breite des Inhalts. Sie wird für die Berechnung der gesamten impliziten Breite des Bereichs verwendet.

Für weitere Informationen siehe Content Sizing.

Siehe auch contentHeight.