ToolTip QML Type

任意のコントロールに対してツールチップを表示します。詳細...

• 継承されたメンバーを含む、すべてのメンバーの一覧

プロパティ

• delay : int
• text : string
• timeout : int

関連プロパティ

• delay : int
• policy : enumeration (since 6.12)
• text : string
• timeout : int
• toolTip : ToolTip
• visible : bool

方法

• void hide() (since QtQuick.Controls 2.5 (Qt 5.12))
• void show(string text, int timeout) (since QtQuick.Controls 2.5 (Qt 5.12))

添付のメソッド

• void hide()
• void show(string text, int timeout)

詳細説明

ツールチップとは、コントロールの機能についてユーザーに知らせる短いテキストのことです。通常、親コントロールの上または下に配置されます。ツールチップのテキストには、リッチテキスト形式の任意の文字列を指定できます。

添付のツールチップ

コントロールのツールチップを設定する最も簡単な方法は、アタッチドプロパティを介してtext およびvisibility を指定することです。次の例はこのアプローチを示しています:

Button {
    text: qsTr("Save")

    ToolTip.visible: down
    ToolTip.text: qsTr("Save the active project")
}

通常、一度に表示されるツールチップは1つだけです。リソースを節約するため、ToolTipアタッチドプロパティを使用するすべての項目は、同じビジュアルツールチップラベルインスタンスを共有します。 ビジュアルは共有されていますが、text 、timeout 、およびdelay は、それぞれのアタッチドプロパティを使用する項目ごとに個別に保存されます。ただし、複数の項目が同時に共有ツールチップを表示させることはできません。共有ツールチップは、最後にそれを表示させた項目に対してのみ表示されます。共有ツールチップの位置は、フレームワークによって決定されます。

遅延とタイムアウト

ツールチップは、特定の外部イベントやユーザーの操作の結果として表示され、通常は一定時間のタイムアウト後に非表示になるという点で、一時的なものです。ツールチップが表示されるまでの遅延や、非表示になるまでのタイムアウトを制御することが可能です。これにより、ツールチップの表示・非表示に関するさまざまな戦略を実装することが可能になります。

たとえば、タッチスクリーンでは、ボタンを長押しした結果としてツールチップを表示するのが一般的なパターンです。次の例は、長押しの時間が経過するまでツールチップの表示を遅延させる方法を示しています。この例では、ボタンから指を離すとすぐにツールチップが非表示になります。

Button {
    text: qsTr("Button")

    ToolTip.visible: pressed
    ToolTip.delay: Application.styleHints.mousePressAndHoldInterval
    ToolTip.text: qsTr("This tool tip is shown after pressing and holding the button down.")
}

一方、ポインタデバイスでは、ボタンにカーソルをしばらく合わせ続けた結果としてツールチップを表示したい場合があります。次の例は、ボタンにカーソルを1秒間合わせ続けた後にツールチップを表示し、5秒間のタイムアウト後に非表示にする方法を示しています。

Button {
    text: qsTr("Button")
    hoverEnabled: true

    ToolTip.delay: 1000
    ToolTip.timeout: 5000
    ToolTip.visible: hovered
    ToolTip.text: qsTr("This tool tip is shown after hovering the button for a second.")
}

カスタムツールチップ

ツールチップの位置をより細かく制御する必要がある場合や、複数のツールチップインスタンスを同時に表示する必要がある場合は、ローカルなツールチップインスタンスを作成することも可能です。これにより、ツールチップをカスタマイズすることができ、Popup APIの全機能を利用できます。次の例は、ハンドルをドラッグしたときにスライダーの値を表示するツールチップを示しています。

Slider {
    id: slider
    value: 0.5

    ToolTip {
        parent: slider.handle
        visible: slider.pressed
        text: slider.value.toFixed(1)
    }
}

「ツールチップのカスタマイズ」、「ポップアップコントロール」、および「closePolicy 」も参照してください 。

プロパティのドキュメント

delay : int

このプロパティは、ツールチップが表示されるまでの遅延時間（ミリ秒）を指定します。遅延時間が負の値の場合、ツールチップは即座に表示されます。デフォルト値は0 です。

「Delay and Timeout」も参照してください 。

text : string

このプロパティには、ツールチップに表示されるテキストが格納されます。

timeout : int

このプロパティは、ツールチップが非表示になるまでのタイムアウト（ミリ秒）を指定します。タイムアウトに負の値が指定されたツールチップは、自動的に非表示にはなりません。デフォルト値は-1 です。

「Delay and Timeout」も参照してください 。

添付プロパティのドキュメント

ToolTip.delay : int [attached]

この添付プロパティは、共有ツールチップの表示遅延（ミリ秒単位）を保持します。このプロパティは、どのアイテムにも設定できます。

policy がToolTip.Manual の場合、デフォルト値は0 となります。それ以外の場合はQStyleHints::toolTipWakeUpDelay()となります。

「 Attached Tool Tips 」および「Delay and Timeout 」も参照してください 。

ToolTip.policy : enumeration [attached, since 6.12]

この付属プロパティは、shared tool tip instance の表示可否が自動的に処理されるかどうかを制御します。このプロパティは、ToolTip.visible が設定されていない項目に対してのみ効果を発揮します。ToolTip.text が設定されている項目のみが表示されます。このプロパティは、以下の項目およびそれらの派生型に対してのみ効果を発揮します：Control 、TextArea 、TextField 。その他のすべての型については、visible を手動で設定する必要があります。

また、このプロパティは、共有ツールチップインスタンスの delay および timeout プロパティのデフォルト値を決定します（ToolTip.visible またはToolTip.text が設定されているかどうかに関係なく）。

このプロパティは、アタッチされたToolTip の子要素に伝播されます。

使用可能な値:

デフォルト値は `ToolTip.Automatic` です。

このプロパティは、Qt 6.12 で導入された共有ツールチップのデフォルト値を無効にする手段を提供します。これは、アイテムとのインタラクションが行われる前に `visible` プロパティを明示的に設定していないレガシーコードにおいて特に重要です。 visible プロパティを宣言的に設定しており、delay および timeout の新しいデフォルト値に問題がないアプリケーションの場合、policy は必要ありません。

このプロパティは Qt 6.12 で導入されました。

Attached Tool Tipsも参照してください 。

ToolTip.text : string [attached]

この添付プロパティには、共有ツールチップのテキストが格納されます。このプロパティは、任意のアイテムに添付することができます。

「Attached Tool Tips」も参照してください 。

ToolTip.timeout : int [attached]

このアタッチメントプロパティには、共有ツールチップのタイムアウト（ミリ秒単位）が格納されます。このプロパティは、どのアイテムにもアタッチすることができます。

デフォルト値はテキストの長さに基づいており、常に少なくとも10秒間設定されます。

「 Attached Tool Tips 」および「Delay and Timeout 」も参照してください 。

ToolTip.toolTip : ToolTip [attached]

このアタッチされたプロパティは、共有ツールチップのインスタンスを保持します。このプロパティは、任意のアイテムにアタッチすることができます。

「Attached Tool Tips」も参照してください 。

ToolTip.visible : bool [attached]

この添付プロパティは、共有ツールチップが表示されているかどうかを保持します。このプロパティは、任意のアイテムに添付することができます。

「Attached Tool Tips」も参照してください 。

メソッドのドキュメント

[since QtQuick.Controls 2.5 (Qt 5.12)] void hide()

このメソッドはツールチップを非表示にします。

このメソッドは、QtQuick.Controls 2.5 (Qt 5.12) で導入されました。

[since QtQuick.Controls 2.5 (Qt 5.12)] void show(string text, int timeout)

このメソッドは、text をツールチップとして表示します。ツールチップの表示時間はtimeout （ミリ秒）で制限されます。

このメソッドは、QtQuick.Controls 2.5 (Qt 5.12) で導入されました。

添付のメソッドドキュメント

[attached] void hide()

このアタッチされたメソッドは、共有ツールチップを非表示にします。このメソッドは、どのアイテムにもアタッチすることができます。

Attached Tool Tipsも参照してください 。

[attached] void show(string text, int timeout = -1)

このアタッチメントメソッドは、text およびtimeout （ミリ秒）を使用して、共有ツールチップを表示します。このメソッドは、任意のアイテムにアタッチすることができます。

Attached Tool Tipsも参照してください 。