LayoutMirroring QML Type (Uncreatable)

レイアウトの挙動を反映するために使用されるプロパティ。詳細...

注：これは生成不可能な型です。QML ではインスタンス化できません。

• 継承されたメンバーを含む、すべてのメンバーの一覧

プロパティ

• childrenInherit : bool
• enabled : bool

詳細説明

「LayoutMirroring」アタッチメントタイプは、アイテムのアンカー、ポジショナータイプ（Row やGrid など）、およびビュー（GridView やhorizontalListView など）を水平方向にミラーリングするために使用されます。ミラーリングは視覚的な変更であり、左側のアンカーが右側のアンカーになり、Grid やRow などのポジショナータイプでは、子アイテムの水平レイアウトが反転します。

アイテムのミラーリングを有効にするには、enabled プロパティをtrueに設定します。デフォルトでは、これはそのアイテム自体にのみ影響します。childrenInherit プロパティをtrueに設定すると、ミラーリングの挙動がすべての子アイテムにも波及します。アイテムに対してLayoutMirroring アタッチメントタイプが定義されていない場合、ミラーリングは有効になりません。

以下の例は、ミラーリングの動作を示しています。下のRow は、親要素の左側にアンカーが設定されています。しかし、ミラーリングが有効になっているため、アンカーの位置が水平方向に反転し、現在は右側にアンカーされています。 また、Row 内の項目はデフォルトで左から右に配置されますが、ミラーリングが有効化されたため、項目の番号付けや不透明度からもわかるように、右から左に配置されるようになりました：

import QtQuick

Rectangle {
    LayoutMirroring.enabled: true
    LayoutMirroring.childrenInherit: true

    width: 300; height: 50
    color: "yellow"
    border.width: 1

    Row {
        anchors { left: parent.left; margins: 5 }
        y: 5; spacing: 5

        Repeater {
            model: 5

            Rectangle {
                color: "red"
                opacity: (5 - index) / 5
                width: 40; height: 40

                Text {
                    text: index + 1
                    anchors.centerIn: parent
                }
            }
        }
    }
}

レイアウトのミラーリングは、異なる言語圏を対象とするアプリケーションにおいて、左から右（LTR）と右から左（RTL）の両方のレイアウトバージョンをサポートする必要がある場合に役立ちます。childrenInherit プロパティを使用すると、アプリケーション内のすべての項目に対して手動でレイアウト設定を行うことなく、レイアウトのミラーリングを適用できます。 ただし、ミラーリングは `Item ` および `x ` の座標値によって定義された配置には影響を与えないため、ミラーリングを有効にしても、意図したレイアウト方向をサポートするためにレイアウトの修正が必要になる場合が多いことに留意してください。 また、ミラーリングが望ましくない動作である場合や、子アイテムがすでに何らかのカスタムな方法でミラーリングを実装している場合は、個々の子アイテムのミラーリングを無効にする（当該アイテムの `LayoutMirroring.enabled ` を `false` に設定する）必要がある場合があります。

アプリケーションのデフォルトのレイアウト方向に基づいてレイアウト方向を設定するには、次のコードを使用します。

LayoutMirroring.enabled: Qt.application.layoutDirection === Qt.RightToLeft

LayoutMirroring やその他の関連機能を使用して、アプリケーションの右から左への表示対応を実装する方法の詳細については、「右から左へのユーザーインターフェース」を参照してください。

プロパティのドキュメント

childrenInherit : bool

このプロパティは、この項目の「LayoutMirroring.enabled 」値がその子要素に継承されるかどうかを指定します。

デフォルト値は false です。

enabled : bool

このプロパティは、項目のレイアウトが水平方向に反転するかどうかを指定します。これを true に設定すると、アンカー設定が水平方向に反転し、左アンカーが右アンカーに、右アンカーが左アンカーになります。ポジショナータイプ（Row やGrid など）およびビュータイプ（GridView やListView など）の場合、これにより項目の水平レイアウト方向も反転します。

デフォルト値は false です。