Back to Qt.io
Contact Us Blog Download Qt
このページでは

C

PathArc QML Type

指定された半径を持つ円弧を定義します。詳細...

Import Statement: import QtQuick
Since: Qt Quick Ultralite 1.8

列挙型

プロパティ

詳細な説明

PathArcは、指定された位置で終わり、指定された半径を持つ弧を簡単に定義する方法を提供します。その設計は、SVGの楕円コマンドarc に基づいています。

以下のQMLコードを実行すると、下図のようなパスが生成されます：

指定された半径を用いて PathArc を使用して描画された円弧。

import QtQuick
import QtQuick.Shapes
Rectangle {
    width: 350
    height: 350
    Shape {
        ShapePath {
            startX: 100; startY: 0
            strokeColor: "skyblue"
            PathArc {
                x: 0; y: 100
                radiusX: 100; radiusY: 100
                useLargeArc: true
            }
        }
    }
}

注： プロジェクトにQul::Shapes モジュールライブラリをリンクする必要があります 。詳細については、 Qt Quick Ultralite Shapes QML Typesを参照してください。

前述のコードスニペットからわかるように、円を定義するには単一の PathArc だけでは不十分です。円の半分ずつを定義する PathArc アイテムが、少なくとも 2 つ必要になります。

関連項目: Path 、PathLine 、PathQuad 、PathCubic 、およびPathSvg 。

列挙に関するドキュメント

Direction

アークの方向オプションの一覧を表示します。

定数説明
PathArc.ClockWise円弧を時計回りに描画します
PathArc.CounterClockWise円弧を反時計回りに描画します

プロパティのドキュメント

direction : Direction [default]

円弧の方向を指定します。

radiusX : real

radiusY : real

円弧の半径を定義します。

以下のQMLは、半径の値を変化させることで円弧の形状を変更する方法を示しています：

PathArcにおける異なるradiusXおよびradiusYの値による視覚的な効果を比較した2つのアーク。

import QtQuick
import QtQuick.Shapes
Rectangle {
    width: 350
    height: 350
    Shape {
        ShapePath {
            startX: 0; startY: 100
            strokeColor: "skyblue"
            PathArc {
                x: 50; y: 100
                radiusX: 25; radiusY: 15
            }
            PathArc {
                x: 100; y: 100
                radiusX: 25; radiusY: 25
            }
            PathArc {
                x: 150; y: 100
                radiusX: 25; radiusY: 50
            }
            PathArc {
                x: 200; y: 100
                radiusX: 50; radiusY: 100
            }
        }
    }
}

注： プロジェクトにQul::Shapes モジュールライブラリをリンクする必要があります 。詳細については、 Qt Quick Ultralite Shapes QML Typesを参照してください。

useLargeArc : bool

アークポイントで定義された大きなアークを使用するかどうか。

開始位置、終了位置、半径、方向が固定されている場合、データに適合する弧は2通り考えられます。useLargeArcは、これらを区別するために使用されます。たとえば、以下のQMLでは、useLargeArcの値を変更することで、下図に示す2つの弧のいずれかを作成できます。

PathArc の useLargeArc プロパティについて、false に設定すると小さな円弧になり、true に設定すると大きな円弧になる様子を示しています。

import QtQuick
import QtQuick.Shapes
Rectangle {
    width: 350
    height: 350
    Repeater {
        id: repeater
        model: 2
        Shape {
            ShapePath {
                startX: 0; startY: 100
                strokeColor: index === 0 ? "brown" : "skyblue"
                PathArc {
                    x: 100; y: 200
                    radiusX: 100; radiusY: 100
                    useLargeArc: index === 0 ? true : false
                    direction: PathArc.Clockwise
                }
            }
        }
    }
}

デフォルト値は false です。

注： Qul::Shapes モジュールライブラリをプロジェクトにリンクする必要があります 。詳細については、 Qt Quick Ultralite Shapes QML Typesを参照してください。

x : real

y : real

円弧の終点を指定します。

xAxisRotation : real

円弧の回転角度を度単位で指定します。デフォルト値は 0 です。

円弧とは、円または楕円の一部です。半径と始点および終点が与えられると、それらの点を結ぶ2つの楕円が存在します。このプロパティは、これらの楕円のX軸に対する回転を定義します。

注：この 値は 、x方向とy方向の半径が異なる場合、つまり弧が楕円の一部である場合にのみ有効です。

特定の Qt ライセンスで利用可能です。
詳細はこちらをご覧ください。