C

Qt Quick ウルトラライトタイムラインの例

Qt Quick UltraliteでのTimelineの使い方を説明します。

概要

timeline サンプルはTimelineタイプの使い方を示しています。左から右に移動しながら、赤から緑に色を変える2つの長方形の周期的なアニメーションを表示します。その後、色のアニメーションを止め、長方形を垂直の中心に向かって動かします。しばらくすると、アニメーションは逆再生され、このアニメーションが終わると、サイクルが再開される。

対象プラットフォーム

プロジェクト構成

CMakeプロジェクトファイル

CMakeLists.txt ファイルには、サンプルのビルドスクリプトが含まれています。

QmlProject ファイル

Timeline モジュールを使用するには、Timeline のモジュールにインポートする必要があります：

    ...
        ModuleFiles {
                MCU.qulModules: ["Timeline"]
        }
    ...

アプリケーションのUI

timeline.qml は、画面に表示されるアプリケーションのUIを定義します。

import QtQuick 2.15
import QtQuick.Timeline 1.0

Rectangle {
    id: root
    readonly property int rectSize: root.height / 5

    color: "#c2c2c2"

    Timeline {
        id: timeline1
        animations: [
            TimelineAnimation {
                id: timelineAnimation
                pingPong: true
                running: true
                from: 0
                duration: 5000
                loops: Animation.Infinite
                to: 800
            }
        ]
        startFrame: 0
        enabled: true
        endFrame: 10000

        KeyframeGroup {
            target: rectangle
            property: "x"
            Keyframe {
                id: d
                value: root.width - rectangle.width
                frame: 300
            }

            Keyframe {
                value: root.width - rectangle.width
                frame: 548
            }
        }

        KeyframeGroup {
            target: rectangle
            property: "y"

            Keyframe {
                value: 0
                frame: 300
            }

            Keyframe {
                value: root.height * 0.5 - rectangle.height
                frame: 552
            }
        }

        KeyframeGroup {
            target: rectangle
            property: "color"

            Keyframe {
                value: "red"
                frame: 0
                easing.type: Easing.InCubic
            }

            Keyframe {
                value: "green"
                frame: 552
                easing.type: Easing.OutCubic
            }
        }

        KeyframeGroup {
            target: rectangle1
            property: "x"
            Keyframe {
                value: root.width - rectangle1.width
                frame: 300
            }

            Keyframe {
                value: root.width - rectangle1.width
                frame: 548
            }
        }

        KeyframeGroup {
            target: rectangle1
            property: "y"
            Keyframe {
                value: root.height - rectangle1.height
                frame: 0
            }

            Keyframe {
                value: root.height - rectangle1.height
                frame: 300
            }

            Keyframe {
                value: root.height * 0.5
                frame: 548
            }
        }

        KeyframeGroup {
            target: rectangle1
            property: "color"

            Keyframe {
                value: "red"
                frame: 0
                easing.type: Easing.OutCubic
            }

            Keyframe {
                value: "green"
                frame: 552
                easing.type: Easing.OutCubic
            }
        }

        KeyframeGroup {
            target: text
            property: "text"

            Keyframe {
                value: "2"
                frame: 300
            }

            Keyframe {
                value: "3"
                frame: 548
            }
        }
    }

    Rectangle {
        id: rectangle
        x: 0
        y: 0
        width: rectSize
        height: rectSize
        color: "#ffffff"
    }

    Rectangle {
        id: rectangle1
        x: 0
        y: root.height - height
        width: rectSize
        height: rectSize
        color: "#ffffff"

        Text {
            id: text
            anchors.centerIn: parent
            text: "1"
        }
    }
}

ファイル

Timelineも参照してください。

特定の Qt ライセンスの下で利用可能です。
詳細を参照してください。