C

Timeline QML Type

Import Statement:	`import QtQuick.Timeline`
Since:	Qt Quick Ultralite 1.3
Inherits:	QtObject

継承されたメンバーを含む全メンバーのリスト

プロパティ

animations : list
currentFrame : real
enabled : bool
endFrame : real
startFrame : real

詳細説明

startFrame とendFrame の間のフレームのタイムラインを指定します。そのキーフレームは、currentFrame が変更されたときに、影響を受けるプロパティがどのように変更されるかを記述します。

Timeline {
    startFrame: 0
    currentFrame: 50
    endFrame: 100
}

タイムラインにキーフレームを追加するには、KeyframeGroup タイプの子を追加します。各KeyframeGroup には、特定のプロパティがどのように変化するかを記述するKeyframes が含まれています。

Timeline {
    // ...

    KeyframeGroup {
        target: myitem
        property: "x"
        Keyframe {
            frame: 20
            value: 50
        }
    }
}

Timelineはアニメーションに使うことも、アイテムの動作を制御するために使うこともできます。例えば、currentFrame にバインドすることで、現在のフレームが進行状況を反映するプログレスバーを作成することができます。また、animations プロパティのTimelineAnimations は、currentFrame を直接アニメーション化することができます。

次の例では、Timeline を使ってRectangle のwidth とheight プロパティをアニメートしています：

Rectangle {
    color: "white"
    Rectangle {
        id: rect
        color: "red"
        width: 100
        height: 100
    }

    Timeline {
        startFrame: 0
        endFrame: 100

        KeyframeGroup {
            target: rect
            property: "width"
            Keyframe {
                frame: 50
                value: 150
            }
            Keyframe {
                frame: 100
                value: 25
                easing.type: Easing.InOutQuad
            }
        }

        KeyframeGroup {
            target: rect
            property: "height"
            Keyframe {
                frame: 0
                value: 50
            }
            Keyframe {
                frame: 70
                value: 150
            }
        }

        animations: [
            TimelineAnimation {
                running: true
                pingPong: true
                // ???
            }
        ]
    }
}

注意： Qt Quick Ultralite Timeline はkeyframes プロパティをサポートしていません。

KeyframeGroup とTimelineAnimationも参照してください。

プロパティのドキュメント

animations : list

Timelineに付けられたアニメーションのリスト。アニメーションはTimelineAnimation タイプでなければならず、自動的にcurrentFrame プロパティに適用されます。

currentFrame : real

タイムライン上の現在のキーフレーム。現在のキーフレームは、アニメーションにすることも、バインディングを付けることもできます。バインディングを使用すると、コンポーネントの動作を制御することができます。

enabled : bool

タイムラインが有効かどうか。

Timelineが無効の場合、Timelineが影響する全てのプロパティは通常の値になります。タイムラインが有効な場合、プロパティ値は現在のフレームとキーフレームによって決定されます。

一度に1つのプロパティに対してアクティブにできるタイムラインは1つだけです。

endFrame : real

タイムラインの終了。この値は影響しません。

startFrame : real

タイムラインの開始。各KeyframeGroup は、timeline が最初に有効にされた時にターゲットプロパティが持っていた値で、startFrame に暗黙のKeyframe を持っています。

詳細はこちら。