Pane QML Type

アプリケーションのスタイルやテーマに合わせた背景を提供します。詳細...

• 継承されたメンバーを含む、すべてのメンバーの一覧

プロパティ

• contentChildren : list<Item>
• contentData : list<QtObject>
• contentHeight : real
• contentWidth : real

詳細説明

Paneは、アプリケーションのスタイルやテーマに合わせた背景色を提供します。Pane自体に独自のレイアウト機能はなく、RowLayout やColumnLayout を作成するなどして、コンテンツの位置を指定する必要があります。

Paneの子として宣言されたアイテムは、自動的にそのPaneのcontentItem の子となります。動的に作成されたアイテムは、明示的にcontentItem の子として設定する必要があります。

Event Handling で述べたように、Paneは下位のアイテムに対してクリックやタッチイベントを通しません。wheelEnabled がtrue の場合、マウスホイールイベントについても同様です。

コンテンツのサイズ調整

Pane内で使用されるアイテムが1つのみの場合、Paneは、その中に含まれるアイテムの暗黙的なサイズに合わせてサイズ変更されます。このため、レイアウトとの併用に特に適しています。

Pane {
    ColumnLayout {
        anchors.fill: parent
        CheckBox { text: qsTr("E-mail") }
        CheckBox { text: qsTr("Calendar") }
        CheckBox { text: qsTr("Contacts") }
    }
}

場合によっては、Pane内に2つのアイテムが含まれることがあります：

Pane {
    SwipeView {
        // ...
    }
    PageIndicator {
        anchors.horizontalCenter: parent.horizontalCenter
        anchors.bottom: parent.bottom
    }
}

この場合、Paneは適切な暗黙のサイズを算出できません。PageIndicator をSwipeView の上に配置しているため、コンテンツサイズをビューの暗黙のサイズに設定するだけで済みます：

Pane {
    contentWidth: view.implicitWidth
    contentHeight: view.implicitHeight

    SwipeView {
        id: view
        // ...
    }
    PageIndicator {
        anchors.horizontalCenter: parent.horizontalCenter
        anchors.bottom: parent.bottom
    }
 }

contentItem に暗黙的なサイズがなく、子要素が1つしかない場合、Paneはその子要素の暗黙的なサイズを使用します。たとえば、次のコードでは、PaneはRectangleのサイズを想定します:

Pane {
    Item {
        Rectangle {
            implicitWidth: 200
            implicitHeight: 200
            color: "salmon"
        }
    }
}

「Paneのカスタマイズ」、「コンテナコントロール」、「 Qt Quick コントロールのフォーカス管理」、および「Event Handling 」も参照してください 。

プロパティのドキュメント

contentChildren : list<Item>

このプロパティには、コンテンツの子要素のリストが格納されます。

このリストには、QML内でそのペインの子として宣言されたすべての項目が含まれます。

「 Item::children 」および「contentData 」も参照してください 。

contentData : list<QtObject> [default]

このプロパティには、コンテンツデータのリストが格納されます。

このリストには、QML内でそのペインの子として宣言されたすべてのオブジェクトが含まれます。

「 Item::data 」および「contentChildren 」も参照してください 。

contentHeight : real

このプロパティは、コンテンツの高さを保持します。これは、ペインの暗黙的な合計高さを計算するために使用されます。

詳細については、Content Sizing を参照してください。

「contentWidth」も参照してください 。

contentWidth : real

このプロパティは、コンテンツの幅を保持します。これは、ペインの暗黙的な合計幅を計算するために使用されます。

詳細については、Content Sizing を参照してください。

「contentHeight」も参照してください 。