Qt QML Type

Stellt ein globales Objekt mit nützlichen Aufzählungen und Funktionen aus Qt bereit. Mehr...

• Liste aller Mitglieder, einschließlich geerbter Mitglieder
• Veraltete Elemente

Eigenschaften

• application : Application
• inputMethod : InputMethod
• platform : var
• styleHints : QtObject
• uiLanguage : string

Methoden

• string QT_TRANSLATE_NOOP(string context, string sourceText, string disambiguation)
• string QT_TRID_NOOP(string id)
• string QT_TR_NOOP(string sourceText, string disambiguation)
• color alpha(color baseColor, real value)
• ArrayBuffer atob(ArrayBuffer data) (since 6.11)
• var atob(var data) (since 6.11)
• var binding(var function)
• ArrayBuffer btoa(ArrayBuffer data) (since 6.11)
• var btoa(var data) (since 6.11)
• void callLater(function)
• void callLater(function, argument1, argument2, ...)
• color color(string name)
• color colorEqual(color lhs, string rhs)
• Component createComponent(url url, enumeration mode, QtObject parent)
• Component createComponent(string moduleUri, string typeName, enumeration mode, QtObject parent) (since 6.5)
• QtObject createQmlObject(string qml, QtObject parent, url url)
• color darker(color baseColor, real factor)
• real enumStringToValue(enumType, keyName)
• string enumValueToString(enumType, keyValue)
• list<string> enumValueToStrings(enumType, keyValue)
• string escapeHtml(string data) (since 6.12)
• void exit(int retCode)
• font font(var fontSpecifier)
• list<string> fontFamilies()
• string formatDate(datetime date, variant format, variant localeFormatOption)
• string formatDateTime(datetime dateTime, variant format, variant localeFormatOption)
• string formatTime(datetime time, variant format, variant localeFormatOption)
• void gc()
• color hsla(real hue, real saturation, real lightness, real alpha)
• color hsva(real hue, real saturation, real value, real alpha)
• bool isQtObject(object)
• color lighter(color baseColor, real factor)
• locale locale(name)
• string md5(data)
• matrix4x4 matrix4x4()
• matrix4x4 matrix4x4(var values)
• matrix4x4 matrix4x4(real m11, real m12, real m13, real m14, real m21, real m22, real m23, real m24, real m31, real m32, real m33, real m34, real m41, real m42, real m43, real m44)
• bool openUrlExternally(url target)
• point point(real x, real y)
• string qsTr(string sourceText, string disambiguation, int n)
• string qsTrId(string id, int n)
• string qsTranslate(string context, string sourceText, string disambiguation, int n)
• quaternion quaternion(real scalar, real x, real y, real z)
• void quit()
• rect rect(real x, real y, real width, real height)
• url resolvedUrl(url url)
• url resolvedUrl(url url, object context)
• color rgba(real red, real green, real blue, real alpha)
• size size(real width, real height)
• color tint(color baseColor, color tintColor)
• url url(url url)
• vector2d vector2d(real x, real y)
• vector3d vector3d(real x, real y, real z)
• vector4d vector4d(real x, real y, real z, real w)

Ausführliche Beschreibung

Qt ist ein Singleton-Typ, der Hilfsfunktionen, Eigenschaften und Aufzählungen bereitstellt. Hier ist ein Beispiel, das die Verwendung dieses Typs veranschaulicht:

import QtQuick 2.0

Text {
    color: Qt.rgba(1, 0, 0, 1)
    text: Qt.md5("hello, world")
}

Aufzählungen

Das Qt-Objekt enthält die in der „ Qt Namespace “ verfügbaren Aufzählungen. So können Sie beispielsweise auf die Aufzählungswerte „ Qt::LeftButton “ und „ Qt::RightButton “ als „ Qt.LeftButton “ und „ Qt.RightButton “ zugreifen.

Typen

Das Qt-Objekt enthält außerdem Hilfsfunktionen zum Erstellen von Objekten bestimmter Datentypen. Dies ist vor allem dann nützlich, wenn die Eigenschaften eines Elements festgelegt werden sollen und die Eigenschaft einen der folgenden Typen aufweist:

• rect - Verwenden Sie „ Qt.rect()“
• point - Verwenden Sie ` Qt.point()`
• size - Verwenden Sie ` Qt.size()`

Wenn das Modul „ QtQuick “ importiert wurde, stehen den Clients außerdem die folgenden Hilfsfunktionen zum Erstellen von Objekten bestimmter Datentypen zur Verfügung:

• color - use Qt.rgba(), Qt.hsla(), Qt.darker(), Qt.lighter() oder Qt.tint()
• font - Verwenden Sie Qt.font()
• vector2d - Verwenden Sie Qt.vector2d()
• vector3d - Verwenden Sie Qt.vector3d()
• vector4d - Verwende Qt.vector4d()
• quaternion - Verwenden Sie „ Qt.quaternion()“
• matrix4x4 - Verwende Qt.matrix4x4()

Datums- und Zeitformatierer

Das Qt-Objekt enthält mehrere Funktionen zur Formatierung von Werten vom Typ „ QDateTime “, „ QDate “ und „ QTime “.

• string Qt.formatDateTime(datetime date, variant format)
• string Qt.formatDate(datetime date, variant format)
• string Qt.formatTime(datetime date, variant format)

Die Formatspezifikation ist unter Qt.formatDateTime beschrieben.

Dynamische Objekterstellung

Mit den folgenden Funktionen des globalen Objekts können Sie QML-Elemente dynamisch aus Dateien oder Zeichenketten erstellen. Einen Überblick über deren Verwendung finden Sie unter „Dynamische Erstellung von QML-Objekten aus JavaScript “.

• object Qt.createComponent(url)
• object Qt.createQmlObject(string qml, object parent, url url)

Weitere Funktionen

Die folgenden Funktionen sind ebenfalls auf dem Qt-Objekt verfügbar.

• Qt.quit()
• Qt.md5(Zeichenkette)
• string Qt.btoa(string)
• string Qt.atob(string)
• object Qt.binding(function)
• object Qt.locale()
• string Qt.resolvedUrl(string)
• Qt.openUrlExternally(Zeichenkette)
• list<string> Qt.fontFamilies()

Eigenschaftsdokumentation

application : Application

Das Objekt „ application “ ermöglicht den Zugriff auf globale Eigenschaften des Anwendungszustands, die von vielen QML-Komponenten gemeinsam genutzt werden.

Es entspricht dem Singleton „ Application “.

Das folgende Beispiel verwendet das ` application `-Objekt, um anzugeben, ob die Anwendung derzeit aktiv ist:

import QtQuick

Rectangle {
    width: 300; height: 55
    color: Qt.application.active ? "white" : "lightgray"
    Text {
        text: "Application " + (Qt.application.active ? "active" : "inactive")
        opacity: Qt.application.active ? 1.0 : 0.5
        anchors.centerIn: parent
    }
}

• application.active
• application.state
• application.layoutDirection
• application.font

inputMethod : InputMethod

Es entspricht dem Singleton „ InputMethod “.

Das „ inputMethod “-Objekt ermöglicht den Zugriff auf das „ QInputMethod “-Objekt der Anwendung sowie auf alle dessen Eigenschaften und Slots. Weitere Details finden Sie in der Dokumentation unter „ QInputMethod “.

platform : var

Das Objekt „ platform “ liefert Informationen über die zugrunde liegende Plattform.

Seine Eigenschaften sind:

styleHints : QtObject

Das Objekt „ styleHints “ stellt plattformspezifische Stilhinweise und Einstellungen bereit. Weitere Informationen finden Sie in der Dokumentation unter QStyleHints.

Sie sollten stattdessen über ` Application::styleHints ` auf `StyleHints` zugreifen, da dies bessere Typinformationen für Werkzeuge wie den „Qt Quick “-Compiler liefert.

uiLanguage : string

Die Variable `uiLanguage` enthält den Namen der Sprache, die für die Übersetzung von Zeichenfolgen der Benutzeroberfläche verwendet werden soll. In C++ wird sie als Eigenschaft ` QJSEngine::uiLanguage ` bereitgestellt.

Sie können den Wert frei festlegen und in Bindungen verwenden. Es wird empfohlen, ihn nach der Installation von Übersetzern in Ihrer Anwendung festzulegen. Gemäß Konvention bedeutet eine leere Zeichenkette, dass keine Übersetzung aus der im Quellcode verwendeten Sprache vorgesehen ist.

Wenn Sie „ QQmlApplicationEngine “ verwenden und sich der Wert ändert, wird „ QQmlEngine::retranslate()“ aufgerufen.

Methodendokumentation

string QT_TRANSLATE_NOOP(string context, string sourceText, string disambiguation)

Kennzeichnet „ sourceText “ für die dynamische Übersetzung im angegebenen „ context “; d. h., die gespeicherte „ sourceText “ wird nicht verändert.

Wird dieselbe ` sourceText ` in verschiedenen Rollen innerhalb desselben Übersetzungskontexts verwendet, kann eine zusätzliche Identifikationszeichenfolge für ` disambiguation` übergeben werden.

Gibt den sourceText zurück.

QT_TRANSLATE_NOOP wird in Verbindung mit den dynamischen Übersetzungsfunktionen qsTr() und qsTranslate() verwendet. Es kennzeichnet eine Zeichenkette als übersetzungsbedürftig (sodass sie über lupdate identifiziert werden kann), überlässt die eigentliche Übersetzung jedoch den dynamischen Funktionen.

Beispiel:

Item {
    property string greeting: QT_TRANSLATE_NOOP("CustomContext", "hello")

    Text { text: qsTranslate("CustomContext", greeting) }
}

Siehe auch Internationalisierung mit Qt.

string QT_TRID_NOOP(string id)

Markiert „ id “ für die dynamische Übersetzung.

Gibt den id zurück.

QT_TRID_NOOP wird in Verbindung mit der Funktion zur dynamischen Übersetzung qsTrId() verwendet. Es kennzeichnet eine Zeichenkette als übersetzungsbedürftig (sodass sie über lupdate identifiziert werden kann), überlässt die eigentliche Übersetzung jedoch der Funktion qsTrId().

Beispiel:

Item {
    property string greetingId: QT_TRID_NOOP("hello_id")

    Text { text: qsTrId(greetingId) }
}

Siehe auch qsTrId() und Internationalisierung mit Qt.

string QT_TR_NOOP(string sourceText, string disambiguation)

Kennzeichnet „ sourceText “ für die dynamische Übersetzung; d. h., die gespeicherte „ sourceText “ wird nicht verändert.

Wird dieselbe ` sourceText ` in verschiedenen Rollen innerhalb desselben Übersetzungskontexts verwendet, kann eine zusätzliche Identifikationszeichenfolge für ` disambiguation` übergeben werden.

Gibt den sourceText zurück.

QT_TR_NOOP wird in Verbindung mit den dynamischen Übersetzungsfunktionen qsTr() und qsTranslate() verwendet. Es kennzeichnet eine Zeichenkette als übersetzungsbedürftig (sodass sie über lupdate identifiziert werden kann), überlässt die eigentliche Übersetzung jedoch den dynamischen Funktionen.

Beispiel:

Item {
    property string greeting: QT_TR_NOOP("hello")

    Text { text: qsTr(greeting) }
}

Siehe auch Internationalisierung mit Qt.

color alpha(color baseColor, real value)

Gibt „ baseColor “ mit einem Alpha-Wert von „ value “ zurück.

value ist eine reelle Zahl im Bereich von 0 (vollständig transparent) bis 1 (vollständig undurchsichtig).

[since 6.11] ArrayBuffer atob(ArrayBuffer data)

ASCII in Binärcode – Diese Funktion dekodiert die Base64-kodierte Zeichenkette „ data “ und gibt sie zurück.

Sie können beliebige arrayähnliche Strukturen als „ data “ übergeben, und die Funktion versucht, diese in ein Byte-Array zu konvertieren. Dies funktioniert insbesondere mit einer Liste von Zahlen und einer Liste von Ein-Zeichen-Zeichenketten. Am effizientesten ist es jedoch, entweder ein „ QByteArray “-Objekt oder ein JavaScript-„ArrayBuffer“-Objekt zu übergeben.

Wenn die Konvertierung fehlschlägt und sich herausstellt, dass das „ data “ nicht die erwartete Form aufweist, wird eine „ Invalid Character “-Ausnahme ausgelöst und ein leeres Array zurückgegeben.

Diese Methode wurde in Qt 6.11 eingeführt.

[since 6.11] var atob(var data)

ASCII in Binärcode – Diese Funktion decodiert die Base64-kodierte Zeichenfolge „ data “ und gibt sie zurück.

Diese Methode wurde in Qt 6.11 eingeführt.

var binding(var function)

Gibt ein JavaScript-Objekt zurück, das eine Eigenschaftsbindung darstellt, zusammen mit einem „ function “, der die Bindung auswertet.

Es gibt zwei Hauptanwendungsfälle für die Funktion: Erstens, um eine Eigenschaftsbindung imperativ aus JavaScript-Code anzuwenden:

Item {
    property bool someCondition: true
    property int edgePosition

    Component.onCompleted: {
        if (someCondition == true) {
            // bind to the result of the binding expression passed to Qt.binding()
            edgePosition = Qt.binding(function() { return x + width })
        }
    }
}

und zweitens, um eine Eigenschaftsbindung bei der Initialisierung von Eigenschaftswerten dynamisch erstellter Objekte (über ` Component.createObject()` oder ` Loader.setSource()`) anzuwenden.

Nehmen wir beispielsweise an, es gibt eine „DynamicText“-Komponente:

import QtQuick

Text {
    id: textElement
    width: 200
    height: 200
    text: "Default text"
    property string dynamicText: "Dynamic text"
    onTextChanged: console.log(text)
}

Die Ausgabe von:

Item {
    id: root
    property string dynamicText: "Root text"

    Component.onCompleted: {
        var c = Qt.createComponent("DynamicText.qml")

        var obj1 = c.createObject(root, { 'text': Qt.binding(function() { return dynamicText + ' extra text' }) })
        root.dynamicText = "Modified root text"

        var obj2 = c.createObject(root, { 'text': Qt.binding(function() { return this.dynamicText + ' extra text' }) })
        obj2.dynamicText = "Modified dynamic text"
    }
}

und von:

Item {
    id: root
    property string dynamicText: "Root text"

    Loader {
        id: loaderOne
        onLoaded: root.dynamicText = "Modified root text"
    }

    Loader {
        id: loaderTwo
        onLoaded: item.dynamicText = "Modified dynamic text"
    }

    Component.onCompleted: {
        loaderOne.setSource("DynamicText.qml", { 'text': Qt.binding(function() { return dynamicText + ' extra text' }) })
        loaderTwo.setSource("DynamicText.qml", { 'text': Qt.binding(function() { return this.dynamicText + ' extra text' }) })
    }
}

sollten beide lauten:

Root text extra text
Modified root text extra text
Dynamic text extra text
Modified dynamic text extra text

Diese Funktion kann nicht in Eigenschaftsbindungsdeklarationen verwendet werden (siehe die Dokumentation zu Bindungsdeklarationen und Bindungszuweisungen), es sei denn, das Ergebnis wird in einem Array gespeichert, das an eine var-Eigenschaft gebunden ist.

Item {
    width: 50
    property var storedBindings: [ Qt.binding(function() { return x + width }) ] // stored
    property int a: Qt.binding(function() { return x + width }) // error!
    property int b

    Component.onCompleted: {
        b = storedBindings[0] // causes binding assignment
    }
}

[since 6.11] ArrayBuffer btoa(ArrayBuffer data)

Binär in ASCII – diese Funktion gibt eine Base64-Kodierung von data zurück.

Sie können jedes arrayähnliche Objekt als „ data “ übergeben, und die Funktion versucht, es in ein Byte-Array zu konvertieren. Dies funktioniert insbesondere mit einer Liste von Zahlen und einer Liste von Ein-Zeichen-Zeichenketten. Am effizientesten ist es jedoch, entweder ein „ QByteArray “-Objekt oder ein JavaScript-„ArrayBuffer“-Objekt zu übergeben.

Wenn die Konvertierung fehlschlägt und sich herausstellt, dass das „ data “ nicht die erwartete Form hat, wird eine „ Invalid Character “-Ausnahme ausgelöst und ein leeres Array zurückgegeben.

Diese Methode wurde in Qt 6.11 eingeführt.

[since 6.11] var btoa(var data)

Binär in ASCII – diese Funktion gibt eine Base64-Kodierung von data zurück.

Diese Methode wurde in Qt 6.11 eingeführt.

Verwenden Sie diese Funktion, um überflüssige Aufrufe einer Funktion oder eines Signals zu vermeiden.

Die Funktion, die als erstes Argument an Qt.callLater() übergeben wird, wird später aufgerufen, sobald die QML-Engine zur Ereignisschleife zurückkehrt.

Wird diese Funktion mehrmals kurz hintereinander mit derselben Funktion als erstem Argument aufgerufen, wird diese Funktion nur einmal aufgerufen.

Beispiel:

import QtQuick

Rectangle {
    width: 480
    height: 320

    property int callsToUpdateMinimumWidth: 0
    property bool optimize: true

    property int currentTextModel: 0
    property var columnTexts: [
        ["Click on either", "rectangle above", "and note how the counter", "below updates", "significantly faster using the", "regular (non-optimized)", "implementation"],
        ["The width", "of this column", "is", "no wider than the", "widest item"],
        ["Note how using Qt.callLater()", "the minimum width is", "calculated a bare-minimum", "number", "of times"]
    ]

    Text {
        x: 20; y: 280
        text: "Times minimum width has been calculated: " + callsToUpdateMinimumWidth
    }

    Row {
        y: 25; spacing: 30; anchors.horizontalCenter: parent.horizontalCenter
        Rectangle {
            width: 200; height:  50; color: "lightgreen"
            Text { text: "Optimized behavior\nusing Qt.callLater()"; anchors.centerIn: parent }
            MouseArea { anchors.fill: parent; onClicked: { optimize = true; currentTextModel++ } }
        }
        Rectangle {
            width: 200; height:  50; color: "lightblue"
            Text { text: "Regular behavior"; anchors.centerIn: parent}
            MouseArea { anchors.fill: parent; onClicked: { optimize = false; currentTextModel++ } }
        }
    }

    Column {
        id: column
        anchors.centerIn: parent

        onChildrenChanged: optimize ? Qt.callLater(updateMinimumWidth) : updateMinimumWidth()

        property int widestChild
        function updateMinimumWidth() {
            callsToUpdateMinimumWidth++
            var w = 0;
            for (var i in children) {
                var child = children[i];
                if (child.implicitWidth > w) {
                    w = child.implicitWidth;
                }
            }

            widestChild = w;
        }

        Repeater {
            id: repeater
            model: columnTexts[currentTextModel%3]
            delegate: Text {
                color: "white"
                text: modelData
                width: column.widestChild
                horizontalAlignment: Text.Center
                Rectangle { anchors.fill: parent; z: -1; color: index%2 ? "gray" : "darkgray" }
            }
        }
    }
}

Alle zusätzlichen Argumente, die an `Qt XML.callLater()` übergeben werden, werden an die aufgerufene Funktion weitergeleitet. Beachten Sie, dass bei der Beseitigung redundanter Aufrufe nur der letzte Satz von Argumenten an die Funktion übergeben wird.

color color(string name)

Gibt die Farbe zurück, die dem angegebenen „ name “ entspricht (d. h. rot oder #ff0000). Wenn es keine solche Farbe gibt, wird „ null “ zurückgegeben.

color colorEqual(color lhs, string rhs)

Gibt „ true “ zurück, wenn sowohl „ lhs “ als auch „ rhs “ gleiche Farbwerte liefern. Beide Argumente können entweder Farbwerte oder Zeichenfolgenwerte sein. Wenn ein Zeichenfolgenwert übergeben wird, muss dieser in eine Farbe konvertierbar sein, wie für den Werttyp „ color “ beschrieben.

Component createComponent(url url, enumeration mode, QtObject parent)

Gibt ein „ Component “-Objekt zurück, das anhand der QML-Datei unter der angegebenen Adresse url erstellt wurde, oder unter null, falls eine leere Zeichenkette angegeben wurde.

Die Eigenschaft „ Component::status “ der zurückgegebenen Komponente gibt an, ob die Komponente erfolgreich erstellt wurde. Wenn der Status „ Component.Error “ lautet, finden Sie eine Fehlerbeschreibung unter „ Component::errorString()“.

Wenn der optionale Parameter ` mode ` auf ` Component.Asynchronous` gesetzt ist, wird die Komponente in einem Hintergrund-Thread geladen. Die Eigenschaft ` Component::status ` hat während des Ladevorgangs den Wert ` Component.Loading `. Der Status ändert sich zu ` Component.Ready `, wenn die Komponente erfolgreich geladen wurde, oder zu ` Component.Error `, wenn der Ladevorgang fehlschlägt. Dieser Parameter ist standardmäßig auf ` Component.PreferSynchronous ` gesetzt, falls er weggelassen wird.

Wenn „ mode “ auf „ Component.PreferSynchronous “ gesetzt ist, versucht Qt, die Komponente synchron zu laden, kann sie jedoch bei Bedarf auch asynchron laden. Zu den Szenarien, die ein asynchrones Laden verursachen können, gehören unter anderem die folgenden:

• Die URL verweist auf eine Netzwerkressource
• Die Komponente wird als Ergebnis einer anderen Komponente erstellt, die asynchron geladen wird

Wenn der optionale Parameter ` parent ` angegeben wird, sollte er auf das Objekt verweisen, das zum übergeordneten Objekt für das erstellte ` Component `-Objekt wird. Wenn kein Modus übergeben wurde, kann dies das zweite Argument sein.

Rufen Sie ` Component.createObject()` für die zurückgegebene Komponente auf, um eine Objektinstanz der Komponente zu erstellen.

Beispiel:

import QtQuick

Item {
    id: container
    width: 300; height: 300

    function loadButton() {
        var component = Qt.createComponent("Button.qml");
        if (component.status == Component.Ready) {
            var button = component.createObject(container);
            button.color = "red";
        }
    }

    Component.onCompleted: loadButton()
}

Weitere Informationen zur Verwendung dieser Funktion finden Sie unter „Dynamische Erstellung von QML-Objekten aus JavaScript “.

Um ein QML-Objekt aus einer beliebigen QML-Zeichenkette (anstelle einer Datei) zu erstellen, verwenden Sie ` Qt.createQmlObject()`.

[since 6.5] Component createComponent(string moduleUri, string typeName, enumeration mode, QtObject parent)

Gibt ein ` Component `-Objekt zurück, das für den durch ` moduleUri ` und ` typeName` angegebenen Typ erstellt wurde.

import QtQml
QtObject {
    id: root
    property Component myComponent: Qt.createComponent("QtQuick", "Rectangle", Component.Asynchronous, root)
}

Diese Überladung verhält sich größtenteils wie die auf „ url “ basierende Version, kann jedoch zur Instanziierung von Typen verwendet werden, die keine URL haben (z. B. über QML_ELEMENT registrierte C++-Typen).

• Der Typ ist in C++ implementiert
• Der Typ ist eine Inline-Komponente.

Wenn der optionale Parameter ` parent ` angegeben wird, sollte er auf das Objekt verweisen, das zum übergeordneten Objekt des erstellten ` Component `-Objekts wird. Wenn kein Modus übergeben wurde, kann dies das zweite Argument sein.

Diese Methode wurde in Qt 6.5 eingeführt.

QtObject createQmlObject(string qml, QtObject parent, url url)

Kompiliert die angegebene Zeichenfolge „ qml “ zu einer Komponente und gibt anschließend ein neues Objekt zurück, das aus dieser Komponente erstellt wurde. Das neue Objekt verfügt über die angegebene „ parent “. Gibt „ null “ zurück, wenn beim Erstellen der Komponente oder des Objekts ein Fehler aufgetreten ist.

Wenn „ url “ angegeben wird, wird diese als URL der Komponente verwendet. Dies ist für die Fehlerberichterstattung nützlich.

Beispiel (wobei ` parentItem ` die ID eines vorhandenen QML-Elements ist):

const newObject = Qt.createQmlObject(`
    import QtQuick

    Rectangle {
        color: "red"
        width: 20
        height: 20
    }
    `,
    parentItem,
    "myDynamicSnippet"
);

Im Falle eines Fehlers wird ein ` QQmlError `-Objekt ausgelöst. Dieses Objekt verfügt über eine zusätzliche Eigenschaft, ` qmlErrors`, die ein Array der aufgetretenen Fehler enthält. Jedes Objekt in diesem Array verfügt über die Elemente ` lineNumber`, ` columnNumber`, ` fileName ` und ` message`. Wenn beispielsweise im obigen Codeausschnitt das Wort „color“ fälschlicherweise als „colro“ geschrieben worden wäre, würde das Array ein Objekt wie das folgende enthalten: { „lineNumber“ : 1, „columnNumber“ : 32, „fileName“ : „dynamicSnippet1“, „message“ : "Kann nicht einer nicht vorhandenen Eigenschaft „colro“ zugewiesen werden"}.

Weitere Informationen zur Verwendung dieser Funktion finden Sie unter „Dynamische Erstellung von QML-Objekten aus JavaScript “.

color darker(color baseColor, real factor)

Gibt eine Farbe zurück, die um den angegebenen Wert „ factor “ dunkler ist als „ baseColor “.

Ist der Faktor größer als 1,0, gibt diese Funktion eine dunklere Farbe zurück. Wird der Faktor auf 3,0 gesetzt, wird eine Farbe mit einem Drittel der Helligkeit zurückgegeben. Ist der Faktor kleiner als 1,0, ist die zurückgegebene Farbe heller; wir empfehlen jedoch, hierfür die Qt-Funktion „lighter()“ zu verwenden. Ist der Faktor 0 oder negativ, ist der Rückgabewert nicht definiert.

Die Funktion wandelt die aktuelle RGB-Farbe in HSV um, dividiert die V-Komponente durch den Faktor und wandelt die Farbe wieder in RGB zurück.

Wird factor nicht angegeben, wird eine Farbe zurückgegeben, die 50 % dunkler ist als baseColor (Faktor 2,0).

real enumStringToValue(enumType, keyName)

Gibt den numerischen Wert des Schlüssels „ keyName “ in der Aufzählung „ enumType “ zurück. Wenn die Aufzählung nicht gefunden werden konnte, wird ein „ TypeError “ ausgelöst. Wenn der Schlüssel kein Eintrag der Aufzählung ist, wird ein „ ReferenceError “ ausgelöst.

string enumValueToString(enumType, keyValue)

Gibt die Zeichenfolgendarstellung eines Schlüssels der Enumeration „ enumType “ zurück, der den Wert „ keyValue “ hat. Wenn die Enumeration nicht gefunden werden konnte, wird eine Ausnahme vom Typ „ TypeError “ ausgelöst. Wenn der Wert mit keinem Schlüssel der Enumeration übereinstimmt, wird eine Ausnahme vom Typ „ ReferenceError “ ausgelöst.

list<string> enumValueToStrings(enumType, keyValue)

Gibt eine Liste der Zeichenfolgendarstellung aller Schlüssel der Enumeration „ enumType “ zurück, die den Wert „ keyValue “ haben. Wenn die Enumeration nicht gefunden werden konnte, wird eine „ TypeError “ ausgelöst. Wenn kein Schlüssel in der Enumeration den Wert „ keyValue “ hat, wird eine „ ReferenceError “ ausgelöst.

[since 6.12] string escapeHtml(string data)

Gibt „ data “ zurück, wobei die HTML-Sonderzeichen maskiert sind.

Diese Funktion konvertiert die Klartextzeichenfolge „ data “ in eine HTML-Zeichenfolge, wobei die HTML-Metazeichen „ < “, „ > “, „ & “ und „ " “ durch HTML-Entitäten ersetzt werden.

Beispiel:

var plain = "<script>alert('XSS')</script>";
var escaped = Qt.escapeHtml(plain);
// escaped is now "&lt;script&gt;alert('XSS')&lt;/script&gt;"

Diese Methode wurde in Qt 6.12 eingeführt.

Siehe auch ` QString::toHtmlEscaped()`.

void exit(int retCode)

Diese Funktion löst das Signal „ QQmlEngine::exit(int)“ aus. Innerhalb des QML-Tools führt dies dazu, dass die Launcher-Anwendung mit dem angegebenen Rückgabecode (retCode) beendet wird. Um beim Aufruf dieser Methode die Ereignisschleife mit einem bestimmten Rückgabecode zu verlassen, kann eine C++-Anwendung das Signal „ QQmlEngine::exit(int)“ mit dem Slot „ QCoreApplication::exit(int)“ verbinden.

Siehe auch quit().

font font(var fontSpecifier)

Gibt eine Schriftart mit den im Objekt „ fontSpecifier “ angegebenen Eigenschaften oder die am besten passende Schriftart zurück. Das Objekt „ fontSpecifier “ sollte Schlüssel-Wert-Paare enthalten, wobei gültige Schlüssel die Namen der Untereigenschaften des Typs „ font “ sind und die Werte gültige Werte für die jeweilige Untereigenschaft darstellen. Ungültige Schlüssel werden ignoriert.

list<string> fontFamilies()

Gibt eine Liste der für die Anwendung verfügbaren Schriftfamilien zurück.

string formatDate(datetime date, variant format, variant localeFormatOption)

Gibt eine Zeichenfolgenrepräsentation von ` date` zurück, die optional mithilfe von ` format` formatiert wird.

Der Parameter „ date “ kann ein JavaScript-Objekt vom Typ „ Date “, eine Eigenschaft von „ date “, ein „ QDate “ oder ein Wert vom Typ „ QDateTime “ sein. Die Parameter „ format “ und „ localeFormatOption “ können einen der möglichen Formatwerte annehmen, wie sie für „ Qt.formatDateTime()“ beschrieben sind.

Wenn „ format “ nicht angegeben ist, wird „ date “ mithilfe von „ Locale.ShortFormat “ unter Verwendung der Standard-Locale formatiert.

Siehe auch ` Locale`.

string formatDateTime(datetime dateTime, variant format, variant localeFormatOption)

Gibt eine Zeichenfolgenrepräsentation von ` dateTime` zurück, die optional mithilfe von ` format ` und ` localeFormatOption` formatiert wird.

Der Parameter „ dateTime “ kann ein JavaScript-Objekt vom Typ „ Date “, eine Eigenschaft von „ date “, ein Wert vom Typ „ QDate “, „ QTime “ oder „ QDateTime “ sein.

Wenn „ format “ nicht angegeben wird, wird „ dateTime “ mithilfe von „ Locale.ShortFormat “ unter Verwendung der Standard-Lokalisierung formatiert. Andernfalls sollte „ format “ entweder einer der folgenden Werte sein:

• Einer der Aufzählungswerte von „ Qt::DateFormat “, z. B. „ Qt.RFC2822Date “ oder „ Qt.ISODate “.
• Eine Zeichenfolge, die das Format der zurückgegebenen Zeichenfolge angibt, wie unten beschrieben.
• Ein „ locale “-Objekt.

Wenn „ format “ ein Locale-Objekt angibt, wird „ dateTime “ mit „ QLocale::toString “ formatiert. In diesem Fall kann „ localeFormatOption “ einen Wert vom Typ „ QLocale::FormatType “ enthalten, um die Formatierung weiter anzupassen. Wenn kein Wert angegeben wird, wird „ Locale.ShortFormat “ verwendet.

Wenn „ format “ eine Formatzeichenfolge angibt, sollten die folgenden Ausdrücke zur Angabe des Datums verwendet werden:

Darüber hinaus können die folgenden Ausdrücke zur Angabe der Uhrzeit verwendet werden:

Alle anderen Eingabezeichen werden ignoriert. Jede Zeichenfolge, die in einfache Anführungszeichen gesetzt ist, wird als Text behandelt und nicht als Ausdruck verwendet. Zwei aufeinanderfolgende einfache Anführungszeichen („''“) werden in der Ausgabe durch ein einzelnes Anführungszeichen ersetzt.

Wenn beispielsweise der folgende Datums-/Zeitwert angegeben wurde:

// 21 May 2001 14:13:09
var dateTime = new Date(2001, 5, 21, 14, 13, 09)

Dieser Wert „ dateTime “ könnte an „ Qt.formatDateTime() “, „ Qt.formatDate()“ oder „ Qt.formatTime()“ mit den unten aufgeführten Werten für „ format “ übergeben werden, um die folgenden Ergebnisse zu erzielen:

Siehe auch Locale.

string formatTime(datetime time, variant format, variant localeFormatOption)

Gibt eine Zeichenfolgenrepräsentation von ` time` zurück, die optional mithilfe von ` format` und, falls angegeben, von ` localeFormatOption` formatiert wird.

Der Parameter „ time “ kann ein JavaScript-Objekt vom Typ „ Date “, ein „ QTime “ oder ein Wert vom Typ „ QDateTime “ sein. Die Parameter „ format “ und „ localeFormatOption “ können einen beliebigen der möglichen Formatwerte annehmen, wie sie für „ Qt.formatDateTime()“ beschrieben sind.

Wenn „ format “ nicht angegeben ist, wird „ time “ unter Verwendung der Standard-Locale gemäß „ Locale.ShortFormat “ formatiert.

Siehe auch „ Locale “.

void gc()

Führt den Garbage Collector aus.

Dies entspricht dem Aufruf von ` QJSEngine::collectGarbage()`.

Siehe auch „Garbage Collection“.

color hsla(real hue, real saturation, real lightness, real alpha)

Gibt eine Farbe mit den angegebenen Komponenten „ hue “, „ saturation “, „ lightness “ und „ alpha “ zurück. Alle Komponenten sollten im Bereich von 0 bis 1 (einschließlich) liegen.

color hsva(real hue, real saturation, real value, real alpha)

Gibt eine Farbe mit den angegebenen Komponenten „ hue “, „ saturation “, „ value “ und „ alpha “ zurück. Alle Komponenten sollten im Bereich von 0 bis 1 (einschließlich) liegen.

bool isQtObject(object)

Gibt „ true “ zurück, wenn „ object “ eine gültige Referenz auf ein Qt- oder QML-Objekt ist, andernfalls „ false “.

color lighter(color baseColor, real factor)

Gibt eine Farbe zurück, die um den angegebenen Wert „ factor “ heller ist als „ baseColor “.

Ist der Faktor größer als 1,0, gibt diese Funktion eine hellere Farbe zurück. Wird der Faktor auf 1,5 gesetzt, wird eine um 50 % hellere Farbe zurückgegeben. Ist der Faktor kleiner als 1,0, ist die zurückgegebene Farbe dunkler; wir empfehlen jedoch, für diesen Zweck die Funktion „Qt.darker()“ zu verwenden. Ist der Faktor 0 oder negativ, ist der Rückgabewert nicht definiert.

Die Funktion wandelt die aktuelle RGB-Farbe in HSV um, multipliziert die V-Komponente mit dem Faktor und wandelt die Farbe wieder in RGB zurück.

Wird factor nicht angegeben, wird eine Farbe zurückgegeben, die 50 % heller ist als baseColor (Faktor 1,5).

locale locale(name)

Gibt ein JS-Objekt zurück, das die Ländereinstellung mit dem angegebenen „ name “ darstellt, der das Format „language[_territory][.codeset][@modifier]“ oder „C“ hat, wobei:

• language ein aus zwei Kleinbuchstaben bestehender ISO-639-Sprachcode ist,
• territory ein zweistelliger Ländercode nach ISO 3166 in Großbuchstaben ist und
• codeset und „ modifier “ ignoriert werden.

Wenn die Zeichenfolge nicht dem Locale-Format entspricht oder „language“ kein gültiger ISO-369-Code ist, wird stattdessen die Locale „C“ verwendet. Wenn „country“ fehlt oder kein gültiger ISO-3166-Code ist, wird das für die angegebene Sprache am besten geeignete Land ausgewählt.

Das zurückgegebene Objekt ist ein anonymer QML-Typ, der auf QLocale basiert.

Siehe auch Locale.

string md5(data)

Gibt eine Hexadezimalzeichenfolge des MD5-Hashwerts von data zurück.

matrix4x4 matrix4x4()

Gibt eine 4×4-Einheitsmatrix zurück.

matrix4x4 matrix4x4(var values)

Gibt eine 4×4-Matrix mit dem angegebenen „ values “ zurück. „ values “ sollte ein JavaScript-Array mit 16 Elementen sein.

Die Array-Indizes entsprechen den Positionen in der Matrix wie folgt:

matrix4x4 matrix4x4(real m11, real m12, real m13, real m14, real m21, real m22, real m23, real m24, real m31, real m32, real m33, real m34, real m41, real m42, real m43, real m44)

Gibt eine 4×4-Matrix mit den angegebenen Werten zurück.

Die Argumente entsprechen ihren Positionen in der Matrix:

bool openUrlExternally(url target)

Versucht, die angegebene URL „ target “ in einer externen Anwendung zu öffnen, basierend auf den Desktop-Einstellungen des Benutzers. Gibt „ true “ zurück, wenn der Vorgang erfolgreich ist, andernfalls „ false “.

Wenn „ target “ eine relative URL ist, wird sie aufgelöst. Anschließend wird die URL an „ QDesktopServices::openUrl “ weitergeleitet.

point point(real x, real y)

Gibt einen Punkt mit den angegebenen Koordinaten „ x “ und „ y “ zurück.

string qsTr(string sourceText, string disambiguation, int n)

Gibt eine übersetzte Version von sourceText zurück, optional basierend auf einer Zeichenkette aus disambiguation und dem Wert von n für Zeichenketten, die Pluralformen enthalten; andernfalls wird sourceText selbst zurückgegeben, wenn keine passende übersetzte Zeichenkette verfügbar ist.

Beispiele mit sourceText und n:

    Text { text: qsTr("hello") }

    // Translates the source text into the correct
    // plural form and replaces %n with the value of total.
    Text {
        text: qsTr("%n message(s) saved", "", total)
    }

Wenn dieselbe „ sourceText “ in verschiedenen Rollen innerhalb desselben Übersetzungskontexts verwendet wird, kann für ` disambiguation` eine zusätzliche Kennungszeichenfolge übergeben werden. Weitere Informationen und Beispiele finden Sie unter „Disambiguate Identical Text“.

Siehe auch „ qsTranslate()“, „Internationalisierung mit Qt“ und „Quellcode für die Übersetzung schreiben“.

string qsTrId(string id, int n)

Gibt eine übersetzte Zeichenkette zurück, die durch „ id “ identifiziert wird. Wird keine passende Zeichenkette gefunden, wird die ID selbst zurückgegeben. Dies sollte unter normalen Umständen nicht vorkommen.

Ist n >= 0, werden alle Vorkommen von „ %n “ in der resultierenden Zeichenkette durch eine dezimale Darstellung von „ n “ ersetzt. Darüber hinaus kann der Übersetzungstext je nach dem Wert von n variieren.

Beispiel:

Text { text: qsTrId("hello_id") }

Es ist möglich, eine Vorlage für die Quellzeichenfolge wie folgt anzugeben:

//% <string>

    Text {
        //% "hello"
        text: qsTrId("hello_id")
    }

oder

/*% <string> */

    Text {
        /*% "hello" */
        text: qsTrId("hello_id")
    }

Um binäre Übersetzungsdateien (QM) zu erstellen, die für die Verwendung mit dieser Funktion geeignet sind, muss die Option „ -idbased “ an das Tool „ lrelease “ übergeben werden.

Siehe auch „ QT_TRID_NOOP“ () und „Internationalisierung mit Qt“.

string qsTranslate(string context, string sourceText, string disambiguation, int n)

Gibt eine übersetzte Version von sourceText innerhalb der angegebenen context zurück, optional basierend auf einer Zeichenfolge aus disambiguation und dem Wert von n für Zeichenfolgen, die Pluralformen enthalten; andernfalls wird sourceText selbst zurückgegeben, wenn keine passende übersetzte Zeichenfolge verfügbar ist.

Wird dieselbe „ sourceText “ in verschiedenen Rollen innerhalb desselben Übersetzungs- context s verwendet, kann ein zusätzlicher identifizierender String für „ disambiguation “ übergeben werden.

Beispiel:

Text { text: qsTranslate("CustomContext", "hello") }

Verwenden Sie diese Funktion, wenn Sie eine Übersetzungsdatei „ context “ haben, die sich von der Datei „ context “ unterscheidet.

Siehe auch Internationalisierung mit Qt XML und ` qsTr()` ().

quaternion quaternion(real scalar, real x, real y, real z)

Gibt ein Quaternion mit den angegebenen Werten für „ scalar “, „ x “, „ y “ und „ z “ zurück.

void quit()

Diese Funktion löst die Ausgabe des Signals „ QQmlEngine::quit()“ aus. Innerhalb des QML-Tools führt dies zum Beenden der Launcher-Anwendung; um eine C++-Anwendung beim Aufruf dieser Methode zu beenden, verbinden Sie das Signal „ QQmlEngine::quit()“ mit dem Slot „ QCoreApplication::quit()“.

Siehe auch ` exit()`.

rect rect(real x, real y, real width, real height)

Gibt ein Rechteck zurück, dessen linke obere Ecke bei x, y liegt und dessen Breite und Höhe durch die angegebenen Werte width und height definiert sind.

url resolvedUrl(url url)

Gibt url zurück, aufgelöst relativ zur URL des Aufrufers.

Wenn kein Aufrufer vorhanden ist oder der Aufrufer keinem QML-Kontext zugeordnet ist, gibt die Funktion ` url ` zurück, aufgelöst relativ zur Basis-URL der QML-Engine. Wenn die QML-Engine keine Basis-URL hat, wird einfach ` url` zurückgegeben.

Siehe auch url().

url resolvedUrl(url url, object context)

Gibt url zurück, aufgelöst relativ zur URL des QML-Kontexts von context. Wenn context keinem QML-Kontext zugeordnet ist, wird url zurückgegeben, aufgelöst relativ zur Basis-URL der QML-Engine. Wenn die QML-Engine keine Basis-URL hat, wird einfach url zurückgegeben.

Siehe auch url().

color rgba(real red, real green, real blue, real alpha)

Gibt eine Farbe mit den angegebenen Komponenten „ red “, „ green “, „ blue “ und „ alpha “ zurück. Alle Komponenten sollten im Bereich von 0 bis 1 (einschließlich) liegen.

size size(real width, real height)

Gibt eine Größe mit den angegebenen Werten für „ width “ und „ height “ zurück.

color tint(color baseColor, color tintColor)

Mit dieser Funktion lässt sich eine Farbe (baseColor) mit einer anderen (tintColor) abtönen.

Die Tönungsfarbe sollte in der Regel weitgehend transparent sein, da Sie sonst die darunterliegende Farbe nicht sehen können. Das folgende Beispiel erzeugt eine leichte rote Tönung, indem die Tönungsfarbe reines Rot ist, das nur zu 1/16 deckend ist.

Item {
    Rectangle {
        x: 0; width: 80; height: 80
        color: "lightsteelblue"
    }
    Rectangle {
        x: 100; width: 80; height: 80
        color: Qt.tint("lightsteelblue", "#10FF0000")
    }
}

Das Tönungsverfahren ist besonders nützlich, wenn aufgrund eines bestimmten Ereignisses eine subtile Veränderung vermittelt werden soll; in diesem Fall können Sie die sichtbare Farbe durch Tönung effektiver anpassen.

url url(url url)

Gibt „ url “ unverändert zurück. Dies kann verwendet werden, um eine Typumwandlung zu „ url “ zu erzwingen. Im Gegensatz zu Qt XML.resolvedUrl() bleiben dabei alle relativen URLs erhalten. Da Zeichenketten implizit in URLs umgewandelt werden, kann die Funktion mit einer Zeichenkette als Argument aufgerufen werden und gibt dann eine URL zurück.

Siehe auch ` resolvedUrl()`.

vector2d vector2d(real x, real y)

Gibt einen Vector2d mit den angegebenen Werten für „ x “ und „ y “ zurück.

vector3d vector3d(real x, real y, real z)

Gibt einen Vector3d mit den angegebenen Werten für „ x “, „ y “ und „ z “ zurück.

vector4d vector4d(real x, real y, real z, real w)

Gibt einen Vektor vom Typ „vector4d“ zurück, der die angegebenen Werte für „ x “, „ y “, „ z “ und „ w “ enthält.