Qt QML Type

Das application Objekt ermöglicht den Zugriff auf globale Anwendungsstatus-Eigenschaften, die von vielen QML-Komponenten gemeinsam genutzt werden.

Es ist das gleiche wie das Application Singleton.

Das folgende Beispiel verwendet das application Objekt, um anzuzeigen, ob die Anwendung gerade aktiv ist:

import QtQuick

Rectangle {
    width: 300; height: 55
    color: Qt.application.active ? "white" : "lightgray"
    Text {
        text: "Application " + (Qt.application.active ? "active" : "inactive")
        opacity: Qt.application.active ? 1.0 : 0.5
        anchors.centerIn: parent
    }
}

• application.active
• application.state
• application.layoutDirection
• application.font

Es ist dasselbe wie das InputMethod Singleton.

Das Objekt inputMethod ermöglicht den Zugriff auf das Objekt QInputMethod der Anwendung und alle seine Eigenschaften und Slots. Weitere Einzelheiten finden Sie in der Dokumentation QInputMethod.

Das platform Objekt liefert Informationen über die zugrunde liegende Plattform.

Seine Eigenschaften sind:

Das styleHints Objekt bietet plattformspezifische Style-Hinweise und Einstellungen. Siehe die QStyleHints Dokumentation für weitere Details.

Sie sollten stattdessen über Application::styleHints auf StyleHints zugreifen, da dies bessere Typinformationen für Werkzeuge wie das Qt Quick Compiler.

Das uiLanguage-Objekt enthält den Namen der Sprache, die für die Übersetzung der Zeichenketten der Benutzeroberfläche verwendet wird. Sie ist in C++ als QQmlEngine::uiLanguage-Eigenschaft verfügbar.

Sie können den Wert frei setzen und in Bindungen verwenden. Es wird empfohlen, sie nach der Installation von Übersetzern in Ihrer Anwendung zu setzen. Konventionell bedeutet eine leere Zeichenkette, dass keine Übersetzung aus der im Quellcode verwendeten Sprache erfolgen soll.

Wenn Sie QQmlApplicationEngine verwenden und sich der Wert ändert, wird QQmlEngine::retranslate() aufgerufen.

Verwenden Sie diese Funktion, um redundante Aufrufe einer Funktion oder eines Signals zu vermeiden.

Die Funktion, die als erstes Argument an Qt.callLater() übergeben wird, wird später aufgerufen, wenn die QML-Engine zur Ereignisschleife zurückkehrt.

Wenn diese Funktion mehrmals kurz hintereinander mit der gleichen Funktion als erstes Argument aufgerufen wird, wird diese Funktion nur einmal aufgerufen.

Zum Beispiel:

import QtQuick

Rectangle {
    width: 480
    height: 320

    property int callsToUpdateMinimumWidth: 0
    property bool optimize: true

    property int currentTextModel: 0
    property var columnTexts: [
        ["Click on either", "rectangle above", "and note how the counter", "below updates", "significantly faster using the", "regular (non-optimized)", "implementation"],
        ["The width", "of this column", "is", "no wider than the", "widest item"],
        ["Note how using Qt.callLater()", "the minimum width is", "calculated a bare-minimum", "number", "of times"]
    ]

    Text {
        x: 20; y: 280
        text: "Times minimum width has been calculated: " + callsToUpdateMinimumWidth
    }

    Row {
        y: 25; spacing: 30; anchors.horizontalCenter: parent.horizontalCenter
        Rectangle {
            width: 200; height:  50; color: "lightgreen"
            Text { text: "Optimized behavior\nusing Qt.callLater()"; anchors.centerIn: parent }
            MouseArea { anchors.fill: parent; onClicked: { optimize = true; currentTextModel++ } }
        }
        Rectangle {
            width: 200; height:  50; color: "lightblue"
            Text { text: "Regular behavior"; anchors.centerIn: parent}
            MouseArea { anchors.fill: parent; onClicked: { optimize = false; currentTextModel++ } }
        }
    }

    Column {
        id: column
        anchors.centerIn: parent

        onChildrenChanged: optimize ? Qt.callLater(updateMinimumWidth) : updateMinimumWidth()

        property int widestChild
        function updateMinimumWidth() {
            callsToUpdateMinimumWidth++
            var w = 0;
            for (var i in children) {
                var child = children[i];
                if (child.implicitWidth > w) {
                    w = child.implicitWidth;
                }
            }

            widestChild = w;
        }

        Repeater {
            id: repeater
            model: columnTexts[currentTextModel%3]
            delegate: Text {
                color: "white"
                text: modelData
                width: column.widestChild
                horizontalAlignment: Text.Center
                Rectangle { anchors.fill: parent; z: -1; color: index%2 ? "gray" : "darkgray" }
            }
        }
    }
}

Alle zusätzlichen Argumente, die an Qt.callLater() übergeben werden, werden an die aufgerufene Funktion weitergereicht. Beachten Sie, dass, wenn redundante Aufrufe eliminiert werden, nur der letzte Satz von Argumenten an die Funktion weitergegeben wird.

Markiert sourceText für die dynamische Übersetzung in die angegebene context; d.h. die gespeicherte sourceText wird nicht verändert.

Wenn dieselbe sourceText in verschiedenen Rollen innerhalb desselben Übersetzungskontexts verwendet wird, kann eine zusätzliche Identifizierungszeichenfolge für disambiguation übergeben werden.

Gibt die sourceText zurück.

QT_TRANSLATE_NOOP wird in Verbindung mit den dynamischen Übersetzungsfunktionen qsTr() und qsTranslate() verwendet. Es identifiziert eine Zeichenkette als übersetzungsbedürftig (damit sie von lupdate identifiziert werden kann), überlässt aber die eigentliche Übersetzung den dynamischen Funktionen.

Beispiel:

Item {
    property string greeting: QT_TRANSLATE_NOOP("CustomContext", "hello")

    Text { text: qsTranslate("CustomContext", greeting) }
}

Siehe auch Internationalisierung mit Qt.

Markiert id für die dynamische Übersetzung.

Gibt die id zurück.

QT_TRID_NOOP wird in Verbindung mit der dynamischen Übersetzungsfunktion qsTrId() verwendet. Sie identifiziert einen String als übersetzungsbedürftig (so dass er mit lupdate identifiziert werden kann), überlässt aber die eigentliche Übersetzung qsTrId().

Beispiel:

Item {
    property string greetingId: QT_TRID_NOOP("hello_id")

    Text { text: qsTrId(greetingId) }
}

Siehe auch qsTrId() und Internationalisierung mit Qt.

Markiert sourceText für dynamische Übersetzung; d.h. die gespeicherte sourceText wird nicht verändert.

Wenn dieselbe sourceText in verschiedenen Rollen innerhalb desselben Übersetzungskontexts verwendet wird, kann ein zusätzlicher Identifizierungsstring für disambiguation übergeben werden.

Gibt die sourceText zurück.

QT_TR_NOOP wird in Verbindung mit den dynamischen Übersetzungsfunktionen qsTr() und qsTranslate() verwendet. Es identifiziert eine Zeichenkette als übersetzungsbedürftig (damit sie von lupdate identifiziert werden kann), überlässt aber die eigentliche Übersetzung den dynamischen Funktionen.

Beispiel:

Item {
    property string greeting: QT_TR_NOOP("hello")

    Text { text: qsTr(greeting) }
}

Siehe auch Internationalisierung mit Qt.

Gibt baseColor mit einem Alpha-Wert von value zurück.

value ist ein realer Wert zwischen 0 (völlig transparent) und 1 (völlig undurchsichtig).

ASCII zu binär - diese Funktion dekodiert den base64 kodierten data String und gibt ihn zurück.

Gibt ein JavaScript-Objekt zurück, das eine Eigenschaftsbindung darstellt, mit einer function, die die Bindung auswertet.

Es gibt zwei Hauptanwendungsfälle für diese Funktion: Erstens, um eine Eigenschaftsbindung zwingend aus JavaScript-Code anzuwenden:

Item {
    property bool someCondition: true
    property int edgePosition

    Component.onCompleted: {
        if (someCondition == true) {
            // bind to the result of the binding expression passed to Qt.binding()
            edgePosition = Qt.binding(function() { return x + width })
        }
    }
}

und zweitens, um eine Eigenschaftsbindung bei der Initialisierung von Eigenschaftswerten dynamisch konstruierter Objekte (über Component.createObject() oder Loader.setSource()) anzuwenden.

Nehmen wir zum Beispiel die Existenz einer DynamicText-Komponente an:

import QtQuick

Text {
    id: textElement
    width: 200
    height: 200
    text: "Default text"
    property string dynamicText: "Dynamic text"
    onTextChanged: console.log(text)
}

die Ausgabe von:

Item {
    id: root
    property string dynamicText: "Root text"

    Component.onCompleted: {
        var c = Qt.createComponent("DynamicText.qml")

        var obj1 = c.createObject(root, { 'text': Qt.binding(function() { return dynamicText + ' extra text' }) })
        root.dynamicText = "Modified root text"

        var obj2 = c.createObject(root, { 'text': Qt.binding(function() { return this.dynamicText + ' extra text' }) })
        obj2.dynamicText = "Modified dynamic text"
    }
}

und von:

Item {
    id: root
    property string dynamicText: "Root text"

    Loader {
        id: loaderOne
        onLoaded: root.dynamicText = "Modified root text"
    }

    Loader {
        id: loaderTwo
        onLoaded: item.dynamicText = "Modified dynamic text"
    }

    Component.onCompleted: {
        loaderOne.setSource("DynamicText.qml", { 'text': Qt.binding(function() { return dynamicText + ' extra text' }) })
        loaderTwo.setSource("DynamicText.qml", { 'text': Qt.binding(function() { return this.dynamicText + ' extra text' }) })
    }
}

sollten beide sein:

Root text extra text
Modified root text extra text
Dynamic text extra text
Modified dynamic text extra text

Diese Funktion kann nicht in Eigenschaftsbindungsdeklarationen verwendet werden (siehe die Dokumentation zu Bindungsdeklarationen und Bindungszuweisungen), außer wenn das Ergebnis in einem Array gespeichert wird, das an eine var-Eigenschaft gebunden ist.

Item {
    width: 50
    property var storedBindings: [ Qt.binding(function() { return x + width }) ] // stored
    property int a: Qt.binding(function() { return x + width }) // error!
    property int b

    Component.onCompleted: {
        b = storedBindings[0] // causes binding assignment
    }
}

Binary to ASCII - diese Funktion gibt eine base64-Kodierung von data zurück.

Gibt die Farbe zurück, die der angegebenen name entspricht (d.h. rot oder #ff0000). Wenn es keine solche Farbe gibt, wird null zurückgegeben.

Gibt true zurück, wenn sowohl lhs als auch rhs die gleichen Farbwerte ergeben. Beide Argumente können entweder Farbwerte oder Zeichenkettenwerte sein. Wenn ein String-Wert übergeben wird, muss er in eine Farbe konvertierbar sein, wie für den Wertetyp color beschrieben.

Gibt ein Component -Objekt zurück, das unter Verwendung der QML-Datei unter der angegebenen url erstellt wurde, oder null, wenn eine leere Zeichenkette angegeben wurde.

Die Component::status Eigenschaft der zurückgegebenen Komponente zeigt an, ob die Komponente erfolgreich erstellt wurde. Wenn der Status Component.Error ist, finden Sie unter Component::errorString() eine Fehlerbeschreibung.

Wenn der optionale Parameter mode auf Component.Asynchronous gesetzt ist, wird die Komponente in einem Hintergrund-Thread geladen. Die Eigenschaft Component::status lautet Component.Loading während des Ladevorgangs. Der Status ändert sich zu Component.Ready, wenn die Komponente erfolgreich geladen wird, oder zu Component.Error, wenn das Laden fehlschlägt. Dieser Parameter ist standardmäßig auf Component.PreferSynchronous gesetzt, wenn er weggelassen wird.

Wenn mode auf Component.PreferSynchronous gesetzt ist, versucht Qt, die Komponente synchron zu laden, kann sie aber gegebenenfalls auch asynchron laden. Zu den Szenarien, die ein asynchrones Laden verursachen können, gehören unter anderem die folgenden:

• Die URL verweist auf eine Netzwerkressource
• Die Komponente wird als Ergebnis einer anderen Komponente erstellt, die asynchron geladen wird.

Wenn der optionale Parameter parent angegeben wird, sollte er auf das Objekt verweisen, das zum übergeordneten Objekt für das erstellte Component Objekt wird. Wenn kein Modus übergeben wurde, kann dies das zweite Argument sein.

Rufen Sie Component.createObject() für die zurückgegebene Komponente auf, um eine Objektinstanz der Komponente zu erstellen.

Zum Beispiel:

import QtQuick

Item {
    id: container
    width: 300; height: 300

    function loadButton() {
        var component = Qt.createComponent("Button.qml");
        if (component.status == Component.Ready) {
            var button = component.createObject(container);
            button.color = "red";
        }
    }

    Component.onCompleted: loadButton()
}

Weitere Informationen zur Verwendung dieser Funktion finden Sie unter Dynamische QML-Objekterstellung aus JavaScript.

Um ein QML-Objekt aus einer beliebigen QML-Zeichenkette (statt aus einer Datei) zu erstellen, verwenden Sie Qt.createQmlObject().

Dies ist eine überladene Funktion.

Gibt ein Component Objekt zurück, das für den durch moduleUri und typeName angegebenen Typ erstellt wurde.

import QtQml
QtObject {
    id: root
    property Component myComponent: Qt.createComponent("QtQuick", "Rectangle", Component.Asynchronous, root)
}

Diese Überladung verhält sich größtenteils wie die auf url basierende Version, kann aber verwendet werden, um Typen zu instanziieren, die keine URL haben (z. B. C++-Typen, die über QML_ELEMENT registriert wurden).

• Der Typ ist in C++ implementiert
• Der Typ ist eine Inline-Komponente.

Wenn der optionale Parameter parent übergeben wird, sollte er auf das Objekt verweisen, das das Elternobjekt für das erstellte Component Objekt wird. Wenn kein Modus übergeben wurde, kann dies das zweite Argument sein.

Diese Methode wurde in Qt 6.5 eingeführt.

Gibt ein neues Objekt zurück, das aus der angegebenen Zeichenkette qml erstellt wurde und den angegebenen parent hat, oder null, wenn ein Fehler bei der Erstellung des Objekts auftrat.

Wenn filepath angegeben ist, wird es für die Fehlerberichterstattung für das erstellte Objekt verwendet.

Beispiel (wobei parentItem die ID eines vorhandenen QML-Objekts ist):

const newObject = Qt.createQmlObject(`
    import QtQuick

    Rectangle {
        color: "red"
        width: 20
        height: 20
    }
    `,
    parentItem,
    "myDynamicSnippet"
);

Im Falle eines Fehlers wird ein QQmlError Objekt ausgelöst. Dieses Objekt hat eine zusätzliche Eigenschaft, qmlErrors, die ein Array der aufgetretenen Fehler ist. Jedes Objekt in diesem Array hat die Mitglieder lineNumber, columnNumber, fileName und message. Wenn zum Beispiel in dem obigen Ausschnitt color als "colro" falsch geschrieben wurde, würde das Array ein Objekt wie das folgende enthalten: {"lineNumber" : 1, "columnNumber" : 32, "fileName" : "dynamicSnippet1", "message" : "Cannot assign to non-existent property "colro""}.

Weitere Informationen zur Verwendung dieser Funktion finden Sie unter Dynamische QML-Objekterstellung aus JavaScript.

Gibt eine Farbe zurück, die um den angegebenen Faktor factor dunkler ist als baseColor.

Wenn der Faktor größer als 1,0 ist, gibt diese Funktion eine dunklere Farbe zurück. Wenn Sie den Faktor auf 3,0 setzen, wird eine Farbe mit einem Drittel der Helligkeit zurückgegeben. Wenn der Faktor kleiner als 1.0 ist, wird eine hellere Farbe zurückgegeben, aber wir empfehlen die Verwendung der Funktion Qt.lighter() für diesen Zweck. Wenn der Faktor 0 oder negativ ist, ist der Rückgabewert nicht spezifiziert.

Die Funktion konvertiert die aktuelle RGB-Farbe nach HSV, teilt die Wertkomponente (V) durch den Faktor und konvertiert die Farbe zurück nach RGB.

Wenn factor nicht angegeben wird, wird eine Farbe zurückgegeben, die 50% dunkler ist als baseColor (Faktor 2,0).

Diese Funktion bewirkt, dass das Signal QQmlEngine::exit(int) ausgegeben wird. Innerhalb des qml-Tools führt dies dazu, dass die Launcher-Anwendung mit dem angegebenen Rückgabewert (retCode) beendet wird. Um die Ereignisschleife mit einem bestimmten Rückgabewert zu verlassen, wenn diese Methode aufgerufen wird, kann eine C++-Anwendung das Signal QQmlEngine::exit(int) mit dem Slot QCoreApplication::exit(int) verbinden.

Siehe auch quit().

Gibt eine Schriftart mit den im Objekt fontSpecifier angegebenen Eigenschaften oder die nächstgelegene passende Schriftart zurück. Das Objekt fontSpecifier sollte Schlüssel-Wert-Paare enthalten, wobei die gültigen Schlüssel die Namen der Untereigenschaften des Typs font und die Werte die gültigen Werte für jede Untereigenschaft sind. Ungültige Schlüssel werden ignoriert.

Gibt eine Liste der für die Anwendung verfügbaren Schriftfamilien zurück.

Gibt eine String-Darstellung von date zurück, die optional mit format formatiert werden kann.

Der Parameter date kann ein JavaScript Date Objekt, eine date Eigenschaft, ein QDate oder QDateTime Wert sein. Die Parameter format und localeFormatOption können alle möglichen Formatwerte sein, wie für Qt.formatDateTime() beschrieben.

Wenn format nicht angegeben ist, wird date unter Verwendung des Standardgebietsschemas Locale.ShortFormat formatiert.

Siehe auch Locale.

Gibt eine String-Darstellung von dateTime zurück, optional formatiert unter Verwendung von format und localeFormatOption.

Der Parameter dateTime kann ein JavaScript Date Objekt, eine date Eigenschaft, ein QDate, QTime oder QDateTime Wert sein.

Wenn format nicht angegeben wird, wird dateTime unter Verwendung von Locale.ShortFormat mit dem Standardgebietsschema formatiert. Andernfalls sollte format entweder sein:

• Einer der Qt::DateFormat Aufzählungswerte, wie Qt.RFC2822Date oder Qt.ISODate.
• Eine Zeichenkette, die das Format der zurückgegebenen Zeichenkette angibt, wie unten beschrieben.
• Ein locale Objekt.

Wenn format ein Gebietsschemaobjekt angibt, wird dateTime mit QLocale::toString formatiert. In diesem Fall kann localeFormatOption einen Wert des Typs QLocale::FormatType enthalten, um die Formatierung weiter abzustimmen. Wenn keine Angabe gemacht wird, wird Locale.ShortFormat verwendet.

Wenn format eine Formatzeichenkette angibt, sollte sie die folgenden Ausdrücke verwenden, um das Datum anzugeben:

Zusätzlich können die folgenden Ausdrücke verwendet werden, um die Zeit anzugeben:

Alle anderen Eingabezeichen werden ignoriert. Eine Folge von Zeichen, die in einfachen Anführungszeichen eingeschlossen sind, wird als Text behandelt und nicht als Ausdruck verwendet. Zwei aufeinanderfolgende einfache Anführungszeichen ("''") werden in der Ausgabe durch ein einfaches Anführungszeichen ersetzt.

Zum Beispiel, wenn der folgende Datums-/Zeitwert angegeben wurde:

// 21 May 2001 14:13:09
var dateTime = new Date(2001, 5, 21, 14, 13, 09)

Dieser Wert dateTime könnte an Qt.formatDateTime(), Qt.formatDate() oder Qt.formatTime() mit den nachstehenden Werten format übergeben werden, um die folgenden Ergebnisse zu erzielen:

Siehe auch Locale.

Gibt eine String-Repräsentation von time zurück, optional formatiert mit format und, falls angegeben, localeFormatOption.

Der Parameter time kann ein JavaScript Date Objekt, ein QTime oder QDateTime Wert sein. Bei den Parametern format und localeFormatOption kann es sich um jeden der möglichen Formatwerte handeln, die für Qt.formatDateTime() beschrieben sind.

Wenn format nicht angegeben wird, wird time unter Verwendung von Locale.ShortFormat mit dem Standardgebietsschema formatiert.

Siehe auch Locale.

Führt den Garbage Collector aus.

Dies ist gleichbedeutend mit dem Aufruf von QJSEngine::collectGarbage().

Siehe auch Garbage Collection.

Gibt eine Farbe mit den angegebenen Komponenten hue, saturation, lightness und alpha zurück. Alle Komponenten sollten im Bereich 0-1 (einschließlich) liegen.

Gibt eine Farbe mit den angegebenen Komponenten hue, saturation, value und alpha zurück. Alle Komponenten sollten im Bereich 0-1 (einschließlich) liegen.

Gibt true zurück, wenn object ein gültiger Verweis auf ein Qt- oder QML-Objekt ist, andernfalls false.

Gibt eine Farbe zurück, die um den angegebenen factor heller ist als baseColor.

Wenn der Faktor größer als 1.0 ist, gibt diese Funktion eine hellere Farbe zurück. Setzt man den Faktor auf 1.5, wird eine Farbe zurückgegeben, die 50% heller ist. Wenn der Faktor kleiner als 1.0 ist, wird eine dunklere Farbe zurückgegeben, aber wir empfehlen die Verwendung der Funktion Qt.darker() für diesen Zweck. Wenn der Faktor 0 oder negativ ist, ist der Rückgabewert nicht spezifiziert.

Die Funktion konvertiert die aktuelle RGB-Farbe in HSV, multipliziert die Wertkomponente (V) mit dem Faktor und konvertiert die Farbe zurück nach RGB.

Wenn factor nicht angegeben wird, wird eine Farbe zurückgegeben, die 50 % heller ist als baseColor (Faktor 1,5).

Gibt ein JS-Objekt zurück, das das Gebietsschema mit dem angegebenen name repräsentiert, das das Format "language[_territory][.codeset][@modifier]" oder "C" hat, wobei:

• language ein kleingeschriebener, zweistelliger ISO 639-Sprachcode ist,
• territory ein zweibuchstabiger ISO-3166-Ländercode in Großbuchstaben ist und
• codeset und modifier werden ignoriert.

Wenn die Zeichenkette gegen das Gebietsschema verstößt oder die Sprache kein gültiger ISO 369-Code ist, wird stattdessen das Gebietsschema "C" verwendet. Wenn country nicht vorhanden oder kein gültiger ISO-3166-Code ist, wird das am besten geeignete Land für die angegebene Sprache gewählt.

Siehe auch Locale.

Gibt einen Hex-String des md5-Hashes von data zurück.

Gibt eine Identitätsmatrix4x4 zurück.

Gibt eine Matrix4x4 mit der angegebenen values zurück. values wird als JavaScript-Array mit 16 Einträgen erwartet.

Die Array-Indizes entsprechen den Positionen in der Matrix wie folgt:

Gibt eine Matrix4x4 mit den angegebenen Werten zurück.

Die Argumente entsprechen ihren Positionen in der Matrix:

Versucht, die angegebene target url in einer externen Anwendung zu öffnen, basierend auf den Desktop-Einstellungen des Benutzers. Gibt im Erfolgsfall true zurück, andernfalls false.

Gibt einen Punkt mit den angegebenen Koordinaten x und y zurück.

Gibt eine übersetzte Version von sourceText zurück, optional basierend auf einer disambiguation Zeichenfolge und dem Wert von n für Zeichenfolgen, die Pluralformen enthalten; andernfalls wird sourceText selbst zurückgegeben, wenn keine geeignete übersetzte Zeichenfolge verfügbar ist.

Beispiele mit sourceText und n:

    Text { text: qsTr("hello") }

    // Translates the source text into the correct
    // plural form and replaces %n with the value of total.
    Text {
        text: qsTr("%n message(s) saved", "", total)
    }

Wenn dieselbe sourceText in verschiedenen Rollen innerhalb desselben Übersetzungskontexts verwendet wird, kann eine zusätzliche Identifizierungszeichenfolge für disambiguation übergeben werden. Weitere Informationen und Beispiele finden Sie unter Disambiguate Identical Text.

Siehe auch qsTranslate(), Internationalisierung mit Qt, und Quellcode für die Übersetzung schreiben.

Gibt eine übersetzte Zeichenkette zurück, die durch id identifiziert wird. Wenn keine passende Zeichenkette gefunden wird, wird die id selbst zurückgegeben. Dies sollte unter normalen Bedingungen nicht passieren.

Wenn n >= 0 ist, werden alle Vorkommen von %n in der resultierenden Zeichenkette durch eine dezimale Darstellung von n ersetzt. Darüber hinaus kann der Übersetzungstext je nach dem Wert von n variieren.

Beispiel:

Text { text: qsTrId("hello_id") }

Es ist möglich, eine Quelltextvorlage wie folgt zu liefern:

//% <string>

    Text {
        //% "hello"
        text: qsTrId("hello_id")
    }

oder

/*% <string> */

    Text {
        /*% "hello" */
        text: qsTrId("hello_id")
    }

Um binäre Übersetzungsdateien (QM) zu erstellen, die für diese Funktion geeignet sind, muss die Option -idbased an das Tool lrelease übergeben werden.

Siehe auch QT_TRID_NOOP() und Internationalisierung mit Qt.

Gibt eine übersetzte Version von sourceText innerhalb der angegebenen context zurück, optional basierend auf einer disambiguation Zeichenkette und dem Wert von n für Zeichenketten, die Plurale enthalten; andernfalls wird sourceText selbst zurückgegeben, wenn keine passende übersetzte Zeichenkette verfügbar ist.

Wenn dieselbe sourceText in verschiedenen Rollen innerhalb derselben Übersetzung context verwendet wird, kann eine zusätzliche Identifizierungszeichenfolge für disambiguation übergeben werden.

Beispiel:

Text { text: qsTranslate("CustomContext", "hello") }

Verwenden Sie, wenn Sie eine Übersetzung context haben, die sich von der Datei context unterscheidet.

Siehe auch Internationalisierung mit Qt und qsTr().

Gibt ein Quaternion mit den angegebenen Werten scalar, x, y und z zurück.

Diese Funktion bewirkt, dass das Signal QQmlEngine::quit() ausgegeben wird. Innerhalb des qml-Werkzeugs führt dies zum Beenden der Launcher-Anwendung; um eine C++-Anwendung zu beenden, wenn diese Methode aufgerufen wird, verbinden Sie das Signal QQmlEngine::quit() mit dem Steckplatz QCoreApplication::quit().

Siehe auch exit().

Liefert ein Rect mit der linken oberen Ecke bei x, y und den angegebenen width und height.

Gibt url relativ zur URL des Aufrufers aufgelöst zurück.

Wenn es keinen Aufrufer gibt oder der Aufrufer nicht mit einem QML-Kontext verbunden ist, wird url relativ zur Basis-URL der QML-Engine aufgelöst zurückgegeben. Wenn die QML-Engine keine Basis-URL hat, wird einfach url zurückgegeben.

Siehe auch url().

Gibt url aufgelöst relativ zur URL des QML-Kontexts von context zurück. Wenn context nicht mit einem QML-Kontext verbunden ist, wird url aufgelöst relativ zur Basis-URL der QML-Engine zurückgegeben. Wenn die QML-Engine keine Basis-URL hat, wird nur url zurückgegeben.

Siehe auch url().

Gibt eine Farbe mit den angegebenen Komponenten red, green, blue und alpha zurück. Alle Komponenten sollten im Bereich 0-1 (einschließlich) liegen.

Gibt eine Größe mit den angegebenen width und height zurück.

Mit dieser Funktion kann eine Farbe (baseColor) mit einer anderen (tintColor) eingefärbt werden.

Die Tönungsfarbe sollte in der Regel weitgehend transparent sein, sonst kann man die darunter liegende Farbe nicht sehen. Im folgenden Beispiel wird ein leichter Rotstich erzeugt, indem die Tönungsfarbe ein reines Rot ist, das nur zu 1/16 deckend ist.

Item {
    Rectangle {
        x: 0; width: 80; height: 80
        color: "lightsteelblue"
    }
    Rectangle {
        x: 100; width: 80; height: 80
        color: Qt.tint("lightsteelblue", "#10FF0000")
    }
}

Die Tönung ist vor allem dann nützlich, wenn eine subtile Veränderung aufgrund eines Ereignisses vermittelt werden soll; dann können Sie die sichtbare Farbe mit Hilfe der Tönung besser abstimmen.

Gibt url wortwörtlich zurück. Dies kann verwendet werden, um eine Typ-Zwangsumwandlung zu url zu erzwingen. Im Gegensatz zu Qt.resolvedUrl() bleiben hier alle relativen URLs erhalten. Da Strings implizit in URLs umgewandelt werden, kann die Funktion mit einem String als Argument aufgerufen werden und gibt dann eine URL zurück.

Siehe auch resolvedUrl().

Gibt einen vector2d mit den angegebenen Werten x und y zurück.

Gibt einen vector3d mit den angegebenen Werten x, y und z zurück.

Gibt einen vector4d mit den angegebenen Werten x, y, z und w zurück.