PropertyChanges QML Type

状態の新しいプロパティバインディングまたは値を記述します。詳細...

• 継承されたメンバを含む、すべてのメンバのリスト

プロパティ

• explicit : bool
• restoreEntryValues : bool
• target : QtObject

詳細説明

PropertyChanges は、State のプロパティ値またはバインディングを定義するために使用されます。 これにより、アイテムがステート間で変更されたときに、そのアイテムのプロパティ値を変更できるようになります。

PropertyChanges オブジェクトを作成するには、ローカル プロパティにバインドするように、ターゲット アイテムのプロパティにバインドします。こうすることで、新しいプロパティ値やバインディングを定義することができます。例えば

import QtQuick

Item {
    id: container
    width: 300; height: 300

    Rectangle {
        id: rect
        width: 100; height: 100
        color: "red"

        MouseArea {
           id: mouseArea
           anchors.fill: parent
        }

        states: State {
           name: "resized"; when: mouseArea.pressed
           PropertyChanges {
               rect {
                   color: "blue"
                   height: container.height
               }
           }
        }
    }
}

マウスが押されると、Rectangle はリサイズ状態に変わります。この状態では、PropertyChanges オブジェクトは矩形の色を青に設定し、height の値をcontainer.height の値に設定します。

これは自動的に、rect.height をリサイズ状態のcontainer.height にバインドすることに注意してください。プロパティ・バインディングを確立せず、状態変更時に高さをcontainer.height の値に設定するだけの場合は、explicit プロパティをtrue に設定します。

PropertyChanges オブジェクトは、オブジェクトのデフォルトシグナルハンドラをオーバーライドして、新しい状態に固有のシグナルハンドラを実装することもできます：

PropertyChanges {
    myMouseArea.onClicked: doSomethingDifferent()
}

プロパティ値のリセット

undefined 、ある状態のプロパティ値をリセットすることができます。次の例では、myText がwiderText状態に変わると、width プロパティがリセットされ、テキストが自然な幅になり、文字列全体が1行に表示されます。

Rectangle {
    width: 300; height: 200

    Text {
        id: myText
        width: 50
        wrapMode: Text.WordWrap
        text: "a text string that is longer than 50 pixels"

        states: State {
            name: "widerText"
            PropertyChanges { myText.width: undefined }
        }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: myText.state = "widerText"
    }
}

トランジションでの即時プロパティ変更

トランジションが状態変化のアニメーションに使用される場合、プロパティは現在の状態の値から新しい状態で定義された値（PropertyChangesオブジェクトで定義された値）にアニメーションされます。しかし、アニメーションなしで、Transition の間にプロパティ値を直ちに設定することが望ましい場合もあります。このような場合、PropertyAction タイプを使用して、プロパティを直ちに強制的に変更することができます。

詳しくはPropertyAction のドキュメントを参照してください。

States の例、Qt Quick States、Qt Qmlも参照してください 。

プロパティのドキュメント

PropertyChanges {
    target: myItem
    explicit: true
    width: parent.width
}