PointLight QML Type

씬 내에 점광원을 정의합니다. 더 보기...

• 상속된 멤버를 포함한 모든 멤버 목록

속성

• constantFade : real
• linearFade : real
• quadraticFade : real

상세 설명

점광원은 광원의 중심에서 모든 방향으로 동일한 강도의 빛을 방출하는 구로 설명할 수 있습니다. 이는 전구가 빛을 방출하는 방식과 유사합니다.

점광원을 회전하거나 크기를 조정해도 아무런 효과가 없습니다. 점광원을 이동하면 빛이 방출되는 위치가 변경됩니다.

기본적으로 점광원의 강도는 제곱 반비례 법칙에 따라 감소합니다. 그러나 페이드 오프(및 범위)는 ` constantFade`, ` linearFade`, ` quadraticFade ` 속성을 통해 제어할 수 있습니다. 광원 감쇠는 다음 공식을 사용하여 계산됩니다: constantFade + distance * (linearFade * 0.01) + distance^2 * (quadraticFade * 0.0001)

간단한 예시: 구체에 세 가지 다른 방식으로 음영 처리하기

배경에 크기가 확대된 직사각형 앞에 구체가 있는 장면을 가정해 봅시다. 직사각형의 메쉬( PrincipledMaterial ) 기본 색상은 흰색입니다.

조명을 전혀 사용하지 않고 두 메시의 조명 관련 셰이딩을 비활성화하면 다음과 같은 결과가 나옵니다:

import QtQuick
import QtQuick3D
View3D {
    anchors.fill: parent

    PerspectiveCamera { z: 600 }

    Model {
        source: "#Rectangle"
        scale: Qt.vector3d(10, 10, 10)
        z: -100
        materials: PrincipledMaterial {
            lighting: PrincipledMaterial.NoLighting
        }
    }

    Model {
        source: "#Sphere"
        scale: Qt.vector3d(2, 2, 2)
        materials: PrincipledMaterial {
            lighting: PrincipledMaterial.NoLighting
            baseColor: "#40c060"
            roughness: 0.1
        }
    }
}

기본적으로 Z축을 따라 아래로 비추는 방향성 조명을 추가하면 다음과 같은 결과가 나타납니다:

import QtQuick
import QtQuick3D
View3D {
    anchors.fill: parent

    PerspectiveCamera { z: 600 }

    DirectionalLight { }

    Model {
        source: "#Rectangle"
        scale: Qt.vector3d(10, 10, 10)
        z: -100
        materials: PrincipledMaterial { }
    }

    Model {
        source: "#Sphere"
        scale: Qt.vector3d(2, 2, 2)
        materials: PrincipledMaterial {
            baseColor: "#40c060"
            roughness: 0.1
        }
    }
}

이제 DirectionalLight 를 다음과 같이 대체하면 어떻게 될까요?

PointLight {
    z: 300
}

여기서 흰색 PointLight는 카메라와 씬 중심 사이의 중간 지점에 오도록 Z축을 따라 이동되었습니다. DirectionalLight 와 달리 PointLight의 회전 각도는 중요하지 않지만, 위치는 중요합니다. 여기서는 특히 배경의 직사각형 메시에서 밝기가 점차 약해지는 현상이 눈에 띕니다.

더 많은 사용 예제는 Qt Quick 3D - Lights Example을 참조하십시오.

DirectionalLight, SpotLight 및 Shadow Mapping도 참조하십시오 .

속성 설명서

constantFade : real

이 속성은 빛의 감쇠 항에 대한 상수 계수입니다. 기본값은 1.0입니다.

linearFade : real

이 속성은 조명 효과에 의해 조명이 소등되는 속도를, 조명과의 거리에 비례하여 증가시킵니다. 기본값은 ` 0.0`이며, 이는 조명이 선형적으로 어두워지지 않음을 의미합니다. 여기서 사용된 값은 조명 감쇠를 계산하기 전에 ` 0.01 `로 곱해집니다.

quadraticFade : real

이 속성은 조명 효과가 역제곱 법칙에 비례하여 빛의 밝기를 줄이는 속도를 높입니다. 기본값은 1.0이며, 이는 점광원의 감쇠가 정확히 역제곱 법칙을 따름을 의미합니다. 즉, 물체까지의 거리가 두 배가 되면 광도가 1/4로 감소합니다. 여기서 사용된 값은 광도 감쇠를 계산하기 전에 0.0001 와 곱해집니다.