SceneEnvironment QML Type

씬이 렌더링되는 방식을 구성할 수 있습니다. 더 보기...

• 상속된 멤버를 포함한 모든 멤버 목록

속성

• antialiasingMode : enumeration
• antialiasingQuality : enumeration
• aoBias : real
• aoDistance : real
• aoDither : bool
• aoEnabled : bool (since 6.5)
• aoSampleRate : int
• aoSoftness : real
• aoStrength : real
• backgroundMode : enumeration
• clearColor : color
• debugSettings : QtQuick3D::DebugSettings (since 6.5)
• depthPrePassEnabled : bool
• depthTestEnabled : bool
• effects : List<QtQuick3D::Effect>
• fog : QtQuick3D::Fog (since 6.5)
• lightProbe : QtQuick3D::Texture
• lightmapper : Lightmapper
• oitMethod : enumeration (since 6.11)
• probeExposure : real
• probeHorizon : real
• probeOrientation : vector3d
• scissorRect : rect (since 6.5)
• skyBoxCubeMap : QtQuick3D::CubeMapTexture (since 6.4)
• skyMaterial : QtQuick3D::SkyMaterial (since 6.12)
• skyboxBlurAmount : real (since 6.4)
• specularAAEnabled : bool (since 6.4)
• temporalAAEnabled : bool
• temporalAAMode : enumeration (since 6.11)
• temporalAAStrength : real
• tonemapMode : enumeration (since 6.0)

상세 설명

SceneEnvironment는 씬이 어떻게 렌더링되어야 하는지에 대한 일련의 전역 속성을 정의합니다.

SceneEnvironment 또는 ExtendedSceneEnvironment 를 사용하려면, View3D 의 environment property 를 해당 유형의 인스턴스와 연결하십시오. 객체는 다음과 같이 인라인으로 선언할 수 있습니다:

View3D {
    environment: SceneEnvironment {
        antialiasingMode: SceneEnvironment.MSAA
        tonemapMode: SceneEnvironment.TonemapModeFilmic
        backgroundMode: SceneEnvironment.SkyBox
        lightProbe: Texture {
            source: "panoramic_hdri_background.hdr"
        }
    }
}

또는 환경 객체를 별도로 정의할 수도 있습니다. 그러면 하나 이상의 ` View3D ` 객체에서 해당 객체를 참조할 수 있습니다. 이번에는 ` ExtendedSceneEnvironment `을 사용한 예제 코드 조각은 다음과 같습니다:

ExtendedSceneEnvironment {
    id: myEnv
    vignetteEnabled: true
}

View3D {
    width: parent.width / 2
    environment: myEnv
}

View3D {
    width: parent.width / 2
    x: parent.width / 2
    environment: myEnv
}

기능 개요

• 앤티앨리어싱 설정. 이 주제에 대한 개요는 ‘앤티앨리어싱 모범 사례(Anti-Aliasing Best Practices )’를 참조하십시오. 관련 속성은 antialiasingMode, antialiasingQuality, specularAAEnabled, temporalAAEnabled, temporalAAStrength 입니다. 또한, ExtendedSceneEnvironment 를 사용하는 경우 fxaaEnabled 를 통해 또 다른 메서드를 사용할 수 있습니다.
• 스크린 스페이스 앰비언트 오클루전(Screen space ambient occlusion). 관련 속성은 aoEnabled, aoStrength, aoBias, aoDistance, aoDither, aoSampleRate, aoSoftness 입니다. SSGI 도 앰비언트 오클루전을 제공하며, 성능 소모가 더 클 수는 있지만 대개 더 나은 품질의 결과를 제공한다는 점에 유의하십시오. SceneEnvironment의 앰비언트 오클루전과 ExtendedSceneEnvironment 의 SSGI를 함께 활성화하지 마십시오.
• 클리어 컬러, 스카이박스, 이미지 기반 라이팅(IBL). IBL에 대한 자세한 내용은 ‘이미지 기반 라이팅 사용’을 참조하십시오. 관련 속성은 backgroundMode, clearColor, lightProbe, probeExposure, probeHorizon, probeOrientation, skyboxBlurAmount, skyBoxCubeMap 입니다.
• 톤 매핑. ` tonemapMode `는 그래픽 파이프라인의 마지막 단계에서 높은 동적 범위(HDR) 색상 값을 0~1 범위로 변환하는 데 사용되는 톤 매핑 방법을 구성합니다. ` ExtendedSceneEnvironment `는 톤 매핑 계산을 미세 조정하는 데 사용할 수 있는 ` whitePoint ` 및 ` sharpnessAmount `와 같은 몇 가지 추가 속성을 제공합니다.
• 깊이 버퍼 설정. 관련 속성은 depthPrePassEnabled 및 depthTestEnabled 입니다.
• 후처리 효과. ExtendedSceneEnvironment 에서 제공하는 기본 제공 후처리 효과 외에도, 애플리케이션은 Effect 유형을 통해 자체 사용자 정의 효과를 제공할 수 있습니다. effects 속성은 Effect 인스턴스의 목록입니다.
• 와이어프레임 모드나 머티리얼의 특정 색상 기여도만 렌더링하는 것과 같은 디버그 시각화 설정입니다. 이는 debugSettings 속성에서 참조되는 DebugSettings 객체에 의해 제어됩니다. 이러한 설정의 대부분은 DebugView 항목이 씬에 추가되었을 때 대화형으로 제어할 수도 있습니다.
• 안개 설정. 안개를 활성화하려면 fog 속성에 적절히 구성된 Fog 객체를 설정하십시오.
• 라이트맵 베이킹 설정. 씬 내 일부 모델에 미리 베이킹된 라이트맵이 사용되는 경우, lightmapper 속성에 설정된 Lightmapper 객체가 베이킹 과정에서 사용되는 설정을 정의합니다.
• 가위 변형 설정. 뷰포트와 다른 가위 변형을 적용하려면 scissorRect 속성을 설정합니다.

ExtendedSceneEnvironment도 참조하십시오 .

속성 설명서

antialiasingMode : enumeration

이 속성은 씬을 렌더링할 때 적용되는 앤티앨리어싱 모드를 제어합니다.

사용 가능한 값은 다음과 같습니다:

기본값은 SceneEnvironment.NoAA 입니다.

슈퍼샘플링

씬이 더 높은 해상도로 렌더링된 후 실제 해상도로 축소됩니다.

장점: 고화질. 지오메트리 실루엣뿐만 아니라 모든 장면 콘텐츠에 앤티앨리어싱을 적용합니다.

단점: 일반적으로 MSAA보다 비용이 더 많이 듭니다. 비디오 메모리 사용량이 증가합니다. View3D 항목에서 Inline을 제외한 모든 renderMode를 지원하는 기술이지만, 이 기술은 먼저 텍스처로 렌더링하는 과정을 수반하기 때문에 renderMode가 Underlay 또는 Overlay인 상태에서 SSAA를 활성화하면 일반적으로 필요하지 않은 중간 텍스처와 렌더 패스가 사용되어 성능 저하가 더 두드러질 수 있습니다. SSAA는 renderMode가 기본값인 Offscreen일 때만 사용하는 것이 권장됩니다.

멀티샘플링

지오메트리의 가장자리에 슈퍼샘플링이 적용되어 실루엣이 더 매끄러워집니다. 하지만 이 기법은 지오메트리 내부의 머티리얼에는 영향을 미치지 않습니다.

장점: 렌더 모드(renderMode)와 관계없이 모든 View3D 항목에서 작동합니다. 앨리어싱이 가장 두드러지기 쉬운 지오메트리 실루엣에서 좋은 결과를 보여주며, 빠른 애니메이션에서도 문제없이 작동합니다. 성능은 전적으로 시스템(GPU)의 성능에 달려 있습니다.

단점: 텍스처나 반사 문제 해결에는 도움이 되지 않습니다. 비디오 메모리 사용량이 증가합니다. 성능이 낮은 그래픽 하드웨어에서는 사용 시 부하가 클 수 있습니다. renderMode에 따라 창 단위 또는 개별 View3D 항목별로 제어할 수 있습니다. 효과가 적용된 Underlay/Overlay 또는 Offscreen을 사용할 경우, 각 View3D 항목별로 MSAA를 제어할 수 있습니다. 반면, 효과 없이 Underlay/Overlay를 사용하거나 Inline을 사용할 경우 MSAA는 창 단위로 제어됩니다.

프로그레시브 앤티앨리어싱

이 속성은 씬에 적용되는 프로그레시브 앤티앨리어싱을 활성화하고 그 수준을 설정합니다.

씬의 모든 콘텐츠가 움직임을 멈춘 상태에서, 프레임 사이마다 카메라가 아주 미세하게 흔들리며, 각 새로운 프레임의 결과가 이전 프레임들과 자연스럽게 혼합됩니다. 프레임이 쌓일수록 결과물의 화질이 더 좋아집니다.

장점: 장면 내 모든 콘텐츠가 정지해 있을 때 뛰어난 결과를 제공합니다.

단점: 시각적 변화가 발생하면 효과가 나타나지 않습니다. 프레임을 축적하고 블렌딩해야 하므로 처리 비용이 큽니다. 비디오 메모리 사용량이 증가합니다.

앤티앨리어싱 방법에 대한 자세한 내용은 ‘앤티앨리어싱 모범 사례’를 참조하십시오.

antialiasingQuality : enumeration

이 속성은 씬에 적용되는 앤티앨리어싱 수준을 설정합니다. 동작은 사용된 ‘ antialiasingMode ’에 따라 달라집니다. ‘ antialiasingMode ’ 속성이 ‘ NoAA ’로 설정된 경우, 이 속성은 아무런 영향을 미치지 않습니다.

사용 가능한 값은 다음과 같습니다.

기본값은 SceneEnvironment.High

aoBias : real

이 속성은 가까운 거리에서 오브젝트에 앰비언트 오클루전이 나타나지 않도록 하는 컷오프 거리를 정의합니다. 값을 높일수록 앰비언트 오클루전이 나타나기까지 오브젝트 간에 필요한 거리가 늘어납니다.

기본값은 0.0입니다.

aoDistance : real

이 속성은 앰비언트 오클루전 그림자가 오브젝트로부터 대략 얼마나 멀리 퍼져 나가는지를 정의합니다. 거리가 멀어질수록 성능에 미치는 영향이 커집니다.

기본값은 5.0입니다.

다음은 기본값인 aoSoftness 와 최대값인 aoStrength 를 적용한 예시입니다:

aoStrength 및 aoSoftness도 참조하십시오 .

aoDither : bool

이 속성을 활성화하면 앰비언트 오클루전 그림자 밴드의 가장자리를 분산시켜 부드러움을 향상시킵니다(때때로 뚜렷한 패턴의 아티팩트가 발생할 위험이 있습니다).

기본값은 false 입니다.

‘ PerspectiveCamera.clipFar ’ 및 ‘ OrthographicCamera.clipFar ’항목도 참조하십시오 .

aoEnabled : bool [since 6.5]

앰비언트 오클루전을 활성화하거나 비활성화합니다.

기본값은 false 이며, 이는 앰비언트 오클루전이 비활성화되었음을 의미합니다.

이 속성은 Qt 6.5에서 도입되었습니다.

aoStrength 및 aoDistance도 참조하십시오 .

aoSampleRate : int

이 속성은 성능을 희생하는 대신 앰비언트 오클루전 품질(회색 음영의 수 증가)을 결정합니다.

값은 2, 3 또는 4여야 합니다. 기본값은 2입니다.

aoSoftness : real

이 속성은 앰비언트 오클루전 셰이딩의 가장자리가 얼마나 부드럽게 표현될지를 결정합니다.

값은 0.0에서 50.0 사이여야 합니다. 기본값은 50.0입니다.

다음은 기본값인 aoDistance 와 최대값인 aoStrength 을 적용한 예시입니다:

aoStrength 및 aoDistance도 참조하십시오 .

aoStrength : real

이 속성은 적용되는 앰비언트 오클루전(Ambient Occlusion)의 강도를 정의합니다. 앰비언트 오클루전은 근사화된 전역 조명(global illumination)의 한 형태로, 물체들이 서로 가까이 있을 때 방향성을 갖지 않는 자체 그림자를 생성합니다. 값을 100으로 설정하면 완전히 어두운 그림자가 생성되며, 값을 낮추면 그림자가 더 밝게 나타납니다. 값을 0으로 설정하면 앰비언트 오클루전을 완전히 비활성화하여, 장면에서 렌더링되는 3D 오브젝트의 시각적 사실성은 다소 떨어지지만 성능은 향상됩니다.

0 이외의 모든 값은 성능에 동일한 영향을 미칩니다.

기본값은 0.0입니다. 최대값은 100.0입니다.

값을 0으로 설정하면 ‘ aoEnabled ’를 false로 설정하는 것과 동일합니다.

다음은 기본값인 ‘ aoSoftness ’ 및 ‘ aoDistance ’ 설정으로 렌더링된 화면입니다:

aoEnabled, aoDistance 및 aoSoftness도 참조하십시오 .

backgroundMode : enumeration

이 속성은 씬의 배경을 지울지 여부와 지우는 방식을 제어합니다.

기본값은 SceneEnvironment.Transparent

다음 예제를 살펴보겠습니다. Suzanne 모델은 balsam 도구로 사전 처리된 것으로 가정하며, glTF Sample Models 저장소에서 가져왔습니다.

import QtQuick
import QtQuick3D
import QtQuick3D.Helpers

Item {
    width: 1280
    height: 720

    View3D {
        id: v3d
        anchors.fill: parent

        environment: ExtendedSceneEnvironment {
            backgroundMode: SceneEnvironment.SkyBox
            lightProbe: Texture { source: "00455_OpenfootageNET_field_low.hdr" }

            glowEnabled: true
            glowStrength: 1.25
            glowBloom: 0.25
            glowBlendMode: ExtendedSceneEnvironment.GlowBlendMode.Additive
        }

        DirectionalLight {
        }

        Suzanne {
            scale: Qt.vector3d(50, 50, 50)
            z: -500
        }

        PerspectiveCamera {
            id: camera
        }

        WasdController {
            controlledObject: camera
        }
    }
}

DirectionalLight 외에도 이미지 기반 조명을 사용하고, 라이트 프로브 텍스처를 스카이박스로 설정하면 다음과 같은 결과가 나타납니다:

라이트 프로브가 없으면 어떻게 될까요?

backgroundMode: SceneEnvironment.Transparent

여기서 배경은 View3D 가 아닌, 2D 및 3D 씬을 호스팅하는 QQuickWindow 또는 QQuickView 에서 제공됩니다. 조명은 DirectionalLight 에만 기반합니다.

고정된 투명 색상을 사용하는 경우:

backgroundMode: SceneEnvironment.Color
clearColor: "green"

lightProbe, QQuickWindow::setColor(), Window::color, View3D도 참조하십시오 .

clearColor : color

이 속성은 ` backgroundMode ` 속성에 ` SceneEnvironment.Color `을 사용할 때 뷰포트를 지울 때 사용할 색상을 정의합니다.

기본값은 Qt::black

backgroundMode항목도 참조하십시오 .

debugSettings : QtQuick3D::DebugSettings [since 6.5]

이 속성은 렌더러의 디버깅 도구를 구성하는 데 사용되는 ` DebugSettings ` 객체를 지정합니다. 생성 과정에서 ` SceneEnvironment `는 자동으로 자신과 연관된 ` DebugSettings ` 객체를 생성하므로, 일반적으로 사용자 정의 ` DebugSettings `를 설정할 필요는 없습니다.

와이어프레임 모드를 활성화하여 씬을 렌더링하는 예시:

메시의 노멀 벡터 시각화:

스페큘러 조명의 기여도 시각화:

이 속성은 Qt 6.5에서 도입되었습니다.

DebugSettings도 참조하십시오 .

depthPrePassEnabled : bool

이 기능이 활성화되면 렌더러는 불투명 오브젝트에 대해 Z-프리패스를 수행합니다. 즉, 메인 렌더링 패스에 대한 드로우 호출을 발행하기 전에 깊이 버퍼를 미리 채우기 위해, 간단한 셰이더를 사용하고 색상 쓰기 기능을 비활성화한 상태로 해당 오브젝트를 렌더링합니다.

이는 씬의 구성 요소에 따라 성능을 향상시킬 수 있습니다. 일반적으로 객체가 많이 겹치고 프래그먼트 셰이딩 비용이 높은 씬에서 이 기능을 통해 이점을 얻을 수 있습니다. 한편, 렌더러가 불투명 객체에 대해 전후 정렬(front-to-back sorting)을 수행한다는 점은 주목할 만합니다. 이 정렬 자체만으로도 불필요한 프래그먼트 셰이딩을 줄이는 데 도움이 되므로, Z-프리패스가 항상 상당한 성능 향상을 가져오는 것은 아닙니다.

모바일 및 임베디드 시스템에서 흔히 볼 수 있는 타일형 렌더링 아키텍처를 사용하는 GPU의 경우, 이 값을 false 로 설정하는 것이 권장됩니다.

기본값은 ` false`입니다.

depthTestEnabled : bool

기본값은 ` true`입니다. 기본적으로 렌더러는 씬 내의 오브젝트를 ` opaque ` 또는 ` semi-transparent`로 분류합니다. ` opaque ` 목록에 포함된 오브젝트(관련 머티리얼이 적용된 서브메시)는 먼저 렌더링되며, 깊이 테스트와 깊이 쓰기가 활성화되어 반투명 영역이 없는 일반적인 3D 오브젝트에 대해 최적의 Z-컬링을 제공합니다. semi-transparent 목록에 있는 오브젝트는 깊이 쓰기(depth write)가 비활성화된 상태로 렌더링되지만, 불투명 오브젝트와의 비교를 위해 깊이 테스트(depth testing)는 여전히 활성화된 상태로, 뒤에서 앞으로의 순서(카메라로부터 중심점의 거리를 기준으로 정렬됨)로 렌더링됩니다. 이를 통해 node opacity 나 머티리얼의 색상 또는 텍스처 맵으로 인해 표면에 반투명 영역이 포함된 3D 오브젝트에 대해 올바른 블렌딩("투과")이 가능합니다.

이 속성이 ' false'로 설정되면 Z-버퍼에 쓰기 및 테스트가 수행되지 않고, 깊이 테스트가 건너뛰어지며, 완전히 불투명한 오브젝트를 포함한 모든 오브젝트가 뒤에서 앞으로 정렬된 순서대로 한 번에 렌더링됩니다.

이 속성을 ` false `로 설정해야 할 경우는 거의 없습니다. 불투명한 오브젝트가 매우 적거나, 단일의 뒤에서 앞으로 정렬된 패스가 더 나은 성능을 발휘하도록 변환된 경우 등, 2단계 방식이 별다른 이점을 주지 않는 것으로 알려진 장면에서 유용할 수 있습니다.

effects : List<QtQuick3D::Effect>

이 속성에는 전체 뷰포트에 적용될 후처리 효과 목록이 포함되어 있습니다. 각 효과의 결과가 다음 효과로 전달되므로 순서가 중요합니다.

fog : QtQuick3D::Fog [since 6.5]

이 속성이 유효한 Fog 객체로 설정되면, 렌더러의 내장 안개 기능을 구성하는 데 사용됩니다.

기본값은 null이며, 이는 안개가 없음을 의미합니다. 이는 enabled 가 false로 설정된 Fog 객체를 지정하는 것과 동일합니다.

이 속성은 Qt 6.5에서 도입되었습니다.

Fog항목도 참조하십시오 .

lightProbe : QtQuick3D::Texture

이 속성은 표준 조명을 대신하거나, 또는 표준 조명에 추가하여 씬에 조명을 비추는 데 사용되는 이미지를 정의합니다.

이 이미지는 가급적 고역동범위(HDR) 이미지나 미리 생성된 큐브맵이어야 합니다. 미리 베이킹을 수행하면 필터링 및 밉맵 생성에 시간이 소요되지 않으므로 런타임 성능이 크게 향상됩니다. 소스가 .hdr 또는 기타 이미지인 경우, GPU 기반 전처리는 이미지 파일을 로드한 후 런타임에 수행되며, 특히 임베디드 및 모바일 하드웨어에서 시간이 많이 소요될 수 있습니다. 따라서 여기에서 설명한 대로, 애플리케이션은 늦어도 빌드 시점에 .hdr 이미지를 전처리할 것을 강력히 권장합니다.

이미지 기반 조명에 대한 자세한 내용은 ‘이미지 기반 조명 사용’을 참조하십시오.

아래 예시는 다음 장면의 환경에서 ‘ backgroundMode ’를 다양하게 변경하여 생성되었습니다. 이 장면에는 ‘DirectionLight’, ‘ PointLight ’ 또는 ‘ SpotLight ’가 없습니다. 모든 조명은 파노라마 HDRI 이미지를 기반으로 합니다.

import QtQuick
import QtQuick3D
import QtQuick3D.Helpers

Item {
    width: 1280
    height: 720

    View3D {
        id: v3d
        anchors.fill: parent

        environment: ExtendedSceneEnvironment {
            backgroundMode: SceneEnvironment.SkyBox
            lightProbe: Texture { source: "00455_OpenfootageNET_field_low.hdr" }

            tonemapMode: SceneEnvironment.TonemapModeFilmic
            sharpnessAmount: 0.4

            glowEnabled: true
            glowStrength: 1.25
            glowBloom: 0.25
            glowBlendMode: ExtendedSceneEnvironment.GlowBlendMode.Additive
        }

        Node {
            scale: Qt.vector3d(100, 100, 100)

            Sponza {
            }

            Suzanne {
                y: 1
                scale: Qt.vector3d(0.5, 0.5, 0.5)
                eulerRotation.y: -90
            }
        }

        PerspectiveCamera {
            id: camera
            y: 100
        }

        WasdController {
            controlledObject: camera
        }
    }
}

위 환경에서 얻은 결과:

backgroundMode 를 SceneEnvironment.Transparent 로 변경하면 다음과 같은 결과가 나옵니다:

이 경우 3D 씬의 조명은 이전과 동일합니다. 즉, 머티리얼이 조명 계산 시 이전과 마찬가지로 라이트 프로브를 사용하지만, 스카이박스는 렌더링되지 않습니다. 2D 및 3D 씬을 호스팅하는 QQuickWindow 의 기본 투명 색상이 흰색이므로 배경도 흰색으로 표시됩니다.

lightProbe 속성 값을 기본값인 null로 다시 설정하는 것도 유효합니다. 이렇게 하면 이전에 연결된 텍스처가 해제됩니다. 예를 들어, Delete 키를 사용하여 스카이박스가 포함된 이미지 기반 조명과, 배경에 고정된 클리어 색상이 적용된 이미지 기반 조명이 없는 상태 사이를 동적으로 전환해 보겠습니다:

environment: ExtendedSceneEnvironment {
    id: env

    backgroundMode: SceneEnvironment.SkyBox
    lightProbe: iblTex

    tonemapMode: SceneEnvironment.TonemapModeFilmic
    sharpnessAmount: 0.4

    glowEnabled: true
    glowStrength: 1.25
    glowBloom: 0.25
    glowBlendMode: ExtendedSceneEnvironment.GlowBlendMode.Additive
}

Texture {
    id: iblTex
    source: "00455_OpenfootageNET_field_low.hdr"
}

focus: true
Keys.onDeletePressed: {
    if (env.backgroundMode == SceneEnvironment.SkyBox) {
        env.backgroundMode = SceneEnvironment.Color;
        env.clearColor = "green";
        env.lightProbe = null;
    } else {
        env.backgroundMode = SceneEnvironment.SkyBox;
        env.lightProbe = iblTex;
    }
}

Delete 키를 누르면 다음과 같은 결과가 나타납니다. 여기서 사용된 씬에는 조명이 없으므로 모든 3D 모델이 완전히 검은색으로 표시된다는 점을 기억하십시오.

lightProbe는 일반적으로 이미지 파일(대개 .hdr 또는 .ktx)에서 데이터를 가져오는 Texture 인스턴스와 함께 사용되지만, 메모리 내 데이터( procedurally generated image data)를 사용하는 Texture와 연결하는 것도 합리적일 수 있습니다. 이에 대한 대표적인 예는 QtQuick3D 의 Helpers 모듈에 있는 ProceduralSkyTextureData 을 통해 이미지 데이터가 생성되는 텍스처입니다:

backgroundMode: SceneEnvironment.SkyBox
lightProbe: Texture {
    textureData: ProceduralSkyTextureData {
    }
}

이를 통해 절차적으로 생성된 HDR 스카이박스 텍스처를 얻을 수 있으며, 이 텍스처는 이제 스카이박스 및 이미지 기반 라이팅(IBL) 모두에 사용됩니다:

backgroundMode, 이미지 기반 조명 사용, IBL 큐브맵 사전 생성, probeExposure, probeHorizon, probeOrientation 및 ProceduralSkyTextureData도 참조하십시오 .

lightmapper : Lightmapper

이 속성이 유효한 Lightmapper 객체로 설정되면, 라이트맵을 베이킹할 때 해당 객체에 지정된 설정이 반영됩니다.

기본값은 null이며, 이는 베이킹과 관련된 모든 설정에 대해 기본값을 사용함을 의미합니다.

라이트맵 베이킹 방법에 대한 자세한 내용은 Lightmapper 문서를 참조하십시오.

라이트맵이 애플리케이션과 관련이 없고 베이킹된 조명이 생성되지 않는 경우, 이 속성과 관련 객체는 실제로 아무런 용도도 없습니다.

Model::usedInBakedLighting, Model::bakedLightmap, Light::bakeMode 및 Lightmapper도 참조하십시오 .

oitMethod : enumeration [since 6.11]

이 속성은 순서 독립적 투명도(OIT) 방식을 지정합니다. 이 속성을 유효한 OIT 방식으로 설정하면 렌더러가 투명한 픽셀을 올바른 깊이 순서대로 렌더링합니다.

사용 가능한 값은 다음과 같습니다.

기본값은 ` None `이며, 순서 독립적 투명도가 비활성화되어 있습니다.

가중치 혼합

이는 순서 독립적 투명도를 근사적으로 구현한 것입니다. 투명한 프래그먼트는 오프스크린 버퍼에 렌더링되며, 각 프래그먼트에는 카메라와의 거리를 기준으로 가중치가 적용됩니다. 그런 다음 각 픽셀의 가중치를 제거한 후 이 버퍼를 백버퍼에 블렌딩합니다. 이 방법은 모든 프래그먼트에 대해 소스 오버(source-over) 합성 규칙을 따르지 않으므로 결과가 정확한 결과와 다르지만, 구형 하드웨어에서도 작동하며 다른 더 정밀한 방법보다 빠릅니다.

연결 리스트

이것은 정확한 순서 독립적 투명도(OIT) 방식입니다. 투명한 프래그먼트는 렌더링 단계에서 연결 리스트에 렌더링되고, 깊이 순으로 정렬된 후 합성 단계에서 블렌딩됩니다.

이 속성은 Qt 6.11에서 도입되었습니다.

probeExposure : real

이 속성은 라이트 프로브에서 방출되는 빛의 양을 조정합니다. 톤 매핑의 일부는 노출 매핑이며, 이 속성은 라이트 프로브의 빛 값이 톤 매핑되는 방식을 조정합니다.

기본적으로 노출 값은 1.0으로 설정되어 있습니다.

관련 항목: lightProbe, probeHorizon, probeOrientation.

probeHorizon : real

이 속성을 값이 증가하는 방향으로 정의하면 환경의 하단 절반에 어둠(검은색)이 더해져, 조명이 주로 이미지 상단에서 비추도록 하고(하단 절반의 특정 반사광을 제거하며) 합니다. 이 속성은 지면에서 반사되는 라이트 프로브의 반사광을 가리는 효과를 주는 지면 평면을 고려할 때 유용합니다. 이는 라이트 프로브의 기여도가 씬의 내용을 고려하지 않고 이미지에서 직접 비롯되기 때문에 필요합니다.

probeHorizon 속성의 예상 값 범위는 0.0에서 1.0 사이입니다. 이 범위 외의 값은 예상 범위로 제한됩니다.

기본적으로 probeHorizon은 0.0으로 설정되어 있어, 조정 없이 전체 라이트 프로브가 사용됩니다.

lightProbe, probeExposure 및 probeOrientation도 참조하십시오 .

probeOrientation : vector3d

이 속성은 라이트 프로브의 방향을 정의합니다. 방향은 x, y, z 축을 기준으로 한 도(°) 단위의 오일러 각도로 정의됩니다.

관련 항목: lightProbe, probeHorizon, probeExposure.

scissorRect : rect [since 6.5]

이 속성은 왼쪽 상단 모서리가 [0, 0]인 뷰 좌표계의 시저 사각형을 정의합니다.

이 속성은 Qt 6.5에서 도입되었습니다.

skyBoxCubeMap : QtQuick3D::CubeMapTexture [since 6.4]

이 속성은 배경 모드가 ‘ SkyBoxCubeMap ’일 때 스카이박스로 사용될 큐브맵을 정의합니다.

이 속성은 Qt 6.4에서 도입되었습니다.

skyMaterial : QtQuick3D::SkyMaterial [since 6.12]

이 속성은 IBL 및 씬의 배경으로 사용되는, 절차적이며 GPU 기반의 하늘 모델을 정의합니다.

이 속성은 Qt 6.12에서 도입되었습니다.

backgroundMode 및 lightProbe도 참조하십시오 .

skyboxBlurAmount : real [since 6.4]

이 속성은 ‘ backgroundMode ’ 속성에 ‘ SceneEnvironment.SkyBox ’을 사용할 때 스카이박스가 얼마나 흐릿하게 처리될지를 결정합니다. 기본값은 ‘ 0.0 ’이며, 이는 흐림 효과가 적용되지 않음을 의미합니다.

허용되는 값의 범위는 0.0에서 1.0 사이이며, 이 범위 외의 모든 값은 이 범위로 제한됩니다.

이 속성은 Qt 6.4에서 도입되었습니다.

specularAAEnabled : bool [since 6.4]

이 속성을 활성화하면 스페큘러 앨리어싱이 완화됩니다. 스페큘러 앨리어싱은 대개 밝은 점의 형태로 나타나며, 카메라를 움직일 때 깜빡일 수도 있습니다.

기본값은 false입니다.

이 속성은 Qt 6.4에서 도입되었습니다.

temporalAAEnabled : bool [default: false]

이 속성이 활성화되면 시간 기반 앤티앨리어싱이 사용됩니다.

프레임 사이에서 카메라가 아주 미세하게 흔들리며, 각 새로운 프레임의 결과가 이전 프레임과 자연스럽게 혼합됩니다.

장점: 흔들리는 카메라 덕분에 그렇지 않으면 놓쳤을 실제 디테일을 포착할 수 있으며, 성능에 미치는 영향이 적습니다.

단점: 빠르게 움직이는 물체에서 1프레임의 고스팅 현상이 발생합니다.

temporalAAMode : enumeration [since 6.11]

시간적 앤티앨리어싱 모드를 제어합니다. 시간적 앤티앨리어싱은 여러 프레임에 걸친 정보를 혼합하여 깜빡임과 앨리어싱을 줄여줍니다.

기본값은 ‘ SceneEnvironment.TAADefault ’입니다.

이 속성은 Qt 6.11에서 도입되었습니다.

temporalAAStrength : real [default: 0.3]

이 속성은 시간 이동량(앤티앨리어싱)을 조정합니다. 이 속성은 temporalAAEnabled 속성이 true일 때만 효과가 있습니다.

temporalAAEnabled도 참조하십시오 .

tonemapMode : enumeration [since 6.0]

이 속성은 렌더링 전에 색상이 톤 매핑되는 방식을 정의합니다. Qt Quick 3D 의 모든 렌더링은 선형 색상 공간에서 수행되며, 이로 인해 많은 경우 표시할 수 없는 색상 값이 생성될 수 있습니다. tonemapMode는 색상을 표시 가능한 범위로 재매핑하는 데 사용되는 기법을 결정합니다.

기본값은 SceneEnvironment.TonemapModeLinear

이러한 다양한 모드의 예시는 ExtendedSceneEnvironment 에서 확인할 수 있습니다.

이 속성은 Qt 6.0에서 도입되었습니다.