PointLight QML Type

シーン内のポイントライトを定義します。詳細...

• 継承されたメンバーを含む、すべてのメンバーの一覧

プロパティ

• constantFade : real
• linearFade : real
• quadraticFade : real

詳細な説明

点光源は、光源の中心から全方向に等しい強さで光を放つ球体として説明できます。これは、電球が光を放つ仕組みに似ています。

ポイントライトを回転させたり拡大縮小させたりしても、何の影響もありません。ポイントライトを移動させると、光が放出される位置が変わります。

デフォルトでは、ポイントライトの輝度は二乗反比例の法則に従って減衰します。ただし、フェードオフ（および範囲）は、constantFade 、linearFade 、およびquadraticFade プロパティで制御できます。光の減衰は、次の式を使用して計算されます。constantFade +distance * (linearFade * 0.01) +distance^2 * (quadraticFade * 0.0001)

簡単な例：球体を3通りの方法でシェーディングする

背景に拡大された長方形があり、その手前に球体があるシーンを考えます。長方形のPrincipledMaterial のデフォルトのベースカラーは白です。

ライトを一切使用せず、2つのメッシュのライト関連のシェーディングを無効にすると、次のような結果になります：

import QtQuick
import QtQuick3D
View3D {
    anchors.fill: parent

    PerspectiveCamera { z: 600 }

    Model {
        source: "#Rectangle"
        scale: Qt.vector3d(10, 10, 10)
        z: -100
        materials: PrincipledMaterial {
            lighting: PrincipledMaterial.NoLighting
        }
    }

    Model {
        source: "#Sphere"
        scale: Qt.vector3d(2, 2, 2)
        materials: PrincipledMaterial {
            lighting: PrincipledMaterial.NoLighting
            baseColor: "#40c060"
            roughness: 0.1
        }
    }
}

デフォルトでZ軸方向を下向きに照射する指向性ライトを追加すると、次のようになります：

import QtQuick
import QtQuick3D
View3D {
    anchors.fill: parent

    PerspectiveCamera { z: 600 }

    DirectionalLight { }

    Model {
        source: "#Rectangle"
        scale: Qt.vector3d(10, 10, 10)
        z: -100
        materials: PrincipledMaterial { }
    }

    Model {
        source: "#Sphere"
        scale: Qt.vector3d(2, 2, 2)
        materials: PrincipledMaterial {
            baseColor: "#40c060"
            roughness: 0.1
        }
    }
}

ここで、DirectionalLight を次のように置き換えてみるとどうなるでしょうか：

PointLight {
    z: 300
}

ここでの白色PointLightは、カメラとシーンの中心の中間点に位置するようにZ軸上で移動されています。DirectionalLight とは異なり、PointLightの回転は重要ではありませんが、その位置は重要です。ここでは、特に背景の矩形メッシュにおいて、光の強さが徐々に弱まっていく様子が確認できます。

その他の使用例については、「Qt Quick 3D - ライトの例」を参照してください。

DirectionalLight 、SpotLight 、およびShadow Mappingも参照してください 。

プロパティのドキュメント

constantFade : real

このプロパティは、光の減衰項の定数倍です。デフォルト値は 1.0 です。

linearFade : real

このプロパティは、光源までの距離に比例して照明効果が光を暗くする速度を高めます。デフォルト値は0.0 であり、これは光に線形フェードが適用されないことを意味します。ここで指定された値は、光の減衰を計算する前に0.01 で乗算されます。

quadraticFade : real

このプロパティは、照明効果が光量を「逆二乗の法則」に従って減衰させる速度を高めます。 デフォルト値は 1.0 であり、これはポイントライトの減光が正確に逆二乗則に従うことを意味します。つまり、オブジェクトまでの距離が 2 倍になると、光強度は 1/4 に減少します。ここで使用される値は、光の減衰を計算する前に、0.0001 で乗算されます。